AC_PREREQ(2.52)

dnl please read gstreamer/docs/random/autotools before changing this file

dnl initialize autoconf

dnl releases only do -Wall, cvs and prerelease does -Werror too

dnl use a three digit version number for releases, and four for cvs/prerelease

AC_INIT(GStreamer BufferClass Plug-in, 0.10.1.1,

    http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,

    gst-plugin-bc)

AG_GST_INIT

dnl initialize automake

AM_INIT_AUTOMAKE

dnl define PACKAGE_VERSION_* variables

AS_VERSION

dnl check if this is a release version

AS_NANO(GST_CVS="no", GST_CVS="yes")

dnl libtoolize complains about wrong macros

AC_CONFIG_MACRO_DIR([m4])

dnl can autoconf find the source ?

AC_CONFIG_SRCDIR([gst/bc/gstbc.c])

dnl define the output header for config

AM_CONFIG_HEADER([config.h])

dnl AM_MAINTAINER_MODE only provides the option to configure to enable it

AM_MAINTAINER_MODE

dnl sets host_* variables

AC_CANONICAL_HOST

dnl our libraries and install dirs use major.minor as a version

GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR

dnl we override it here if we need to for the release candidate of new series

GST_MAJORMINOR=0.10

AC_SUBST(GST_MAJORMINOR)

dnl CURRENT, REVISION, AGE

dnl - library source changed -> increment REVISION

dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0

dnl - interfaces added -> increment AGE

dnl - interfaces removed -> AGE = 0

dnl sets GST_LT_LDFLAGS

AS_LIBTOOL(GST, 0, 0, 0)

dnl FIXME: this macro doesn't actually work;

dnl the generated libtool script has no support for the listed tags.

dnl So this needs to be fixed first if we want to use this

dnl AS_LIBTOOL_TAGS

AC_LIBTOOL_WIN32_DLL

AM_PROG_LIBTOOL

AS_PROG_OBJC

dnl *** required versions of GStreamer stuff ***

GST_REQ=0.10.23

GSTPB_REQ=0.10.23

dnl *** autotools stuff ****

dnl allow for different autotools

AS_AUTOTOOLS_ALTERNATE

dnl Add parameters for aclocal

AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")

dnl set up gettext

dnl the version check needs to stay here because autopoint greps for it

AM_GNU_GETTEXT_VERSION([0.11.5])

AM_GNU_GETTEXT([external])

AG_GST_GETTEXT([gst-plugin-bt-$GST_MAJORMINOR])

dnl *** check for arguments to configure ***

AG_GST_ARG_DEBUG

AG_GST_ARG_PROFILING

AG_GST_ARG_VALGRIND

AG_GST_ARG_GCOV

AG_GST_ARG_EXAMPLES

AG_GST_ARG_WITH_PKG_CONFIG_PATH

AG_GST_ARG_WITH_PACKAGE_NAME

AG_GST_ARG_WITH_PACKAGE_ORIGIN

AG_GST_ARG_WITH_PLUGINS

dnl *** checks for platform ***

dnl * hardware/architecture *

AC_CHECK_SIZEOF(void *)

dnl common/m4/gst-arch.m4

dnl check CPU type

AG_GST_ARCH

dnl check for large file support

dnl affected plugins must include config.h

AC_SYS_LARGEFILE

dnl *** checks for programs ***

dnl find a compiler

AC_PROG_CC

AC_PROG_CXX

dnl check if the compiler supports '-c' and '-o' options

AM_PROG_CC_C_O

AC_PATH_PROG(VALGRIND_PATH, valgrind, no)

AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")

dnl check for documentation tools

GTK_DOC_CHECK([1.3])

AS_PATH_PYTHON([2.1])

AG_GST_PLUGIN_DOCS([1.3],[2.1])

dnl *** checks for libraries ***

dnl For interactive UNIX (a Sun thing)

dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS

AC_ISC_POSIX

dnl libm, for sin() etc.

AC_CHECK_LIBM

AC_SUBST(LIBM)

dnl *** checks for header files ***

dnl check if we have ANSI C header files

AC_HEADER_STDC

dnl *** checks for types/defines ***

dnl *** checks for structures ***

dnl *** checks for compiler characteristics ***

dnl make sure we can use "inline" from C code

AC_C_INLINE

dnl *** checks for library functions ***

dnl Check for a way to display the function name in debug output

AG_GST_CHECK_FUNCTION

dnl *** checks for dependency libraries ***

dnl GLib is required

AG_GST_GLIB_CHECK([2.6])

dnl checks for gstreamer

dnl uninstalled is selected preferentially -- see pkg-config(1)

AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)

AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)

AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)

AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)

AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")

dnl Check for documentation xrefs

GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"

GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"

GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"

AC_SUBST(GLIB_PREFIX)

AC_SUBST(GST_PREFIX)

AC_SUBST(GSTPB_PREFIX)

dnl *** set variables based on configure arguments ***

AC_ARG_WITH(kpath,[  --with-kpath            specify the path to the kernel modules],[

  kpath="$withval"

])

AC_SUBST(kpath)

AC_ARG_WITH(gsdk,[  --with-gsdk             specify the path to the GFX DDK],[

  gsdk="$withval"

])

AC_SUBST(gsdk)

AC_ARG_ENABLE(module-only,

  AC_HELP_STRING([--enable-module-only], [Build only kernel module  (default: disabled)]),

  [case "${enableval}" in

    yes) enable_module_only=true ;;

    no)  enable_module_only=false ;;

    *) AC_MSG_ERROR(bad value ${enableval} for --enable-module-only) ;;

  esac], [enable_module_only=false])

if test "x$enable_module_only" = "xtrue"; then

  if ! test -n "$kpath"; then

    AC_MSG_ERROR(if --enable-module-only is given, --with-kpath must also be used)

    enable_module_only=false

  fi

  if ! test -n "$gsdk"; then

    AC_MSG_ERROR(if --enable-module-only is given, --with-gsdk must also be used)

    enable_module_only=false

  fi

fi

AM_CONDITIONAL([BUILD_MODULE], test -n "$kpath" && test -n "$gsdk")

AM_CONDITIONAL([BUILD_GST], test "x$enable_module_only" != "xtrue")

AC_ARG_ENABLE(gles1-example,

  AC_HELP_STRING([--enable-gles1-example], [Enable OpenGLES 1.x example  (default: disabled)]),

  [case "${enableval}" in

    yes) enable_gles1_example=true ;;

    no)  enable_gles1_example=false ;;

    *) AC_MSG_ERROR(bad value ${enableval} for --enable-gles1-example) ;;

  esac], [enable_gles1_example=false])

if test "x$enable_gles1_example" = "xtrue"; then

  gllibs="$gllibs -lGLES_CM -lEGL"

  AC_DEFINE(ENABLE_GLES1_EXAMPLE, [], [Enable OpenGLES 1.x example  (default: disabled)])

fi

AC_ARG_ENABLE(gles2-example,

  AC_HELP_STRING([--enable-gles2-example], [Enable OpenGLES 2.x example  (default: disabled)]),

  [case "${enableval}" in

    yes) enable_gles2_example=true ;;

    no)  enable_gles2_example=false ;;

    *) AC_MSG_ERROR(bad value ${enableval} for --enable-gles2-example) ;;

  esac], [enable_gles2_example=false])

if test "x$enable_gles2_example" = "xtrue"; then

  gllibs="$gllibs -lGLESv2 -lEGL"

  AC_DEFINE(ENABLE_GLES2_EXAMPLE, [], [Enable OpenGLES 2.x example  (default: disabled)])

fi

AC_SUBST(gllibs)

dnl set license and copyright notice

GST_LICENSE="LGPL"

AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])

AC_SUBST(GST_LICENSE)

dnl set location of plugin directory

AG_GST_SET_PLUGINDIR

dnl define an ERROR_CFLAGS Makefile variable

AG_GST_SET_ERROR_CFLAGS($GST_CVS)

AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)

dnl define correct level for debugging messages

AG_GST_SET_LEVEL_DEFAULT($GST_CVS)

dnl used in examples

AG_GST_DEFAULT_ELEMENTS

dnl *** plugins to includes ***

dnl *** sys plug-ins ***

echo

AC_MSG_NOTICE([Checking libraries for plugins in sys/])

echo

dnl *** finalize CFLAGS, LDFLAGS, LIBS

dnl Overview:

dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...

dnl GST_*:              flags shared by built objects to link against GStreamer

dnl GST_ALL_LDFLAGS:    linker flags shared by all

dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries

dnl GST_LT_LDFLAGS:     library versioning of our libraries

dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins

dnl GST_OPTION_CFLAGS

if test "x$USE_DEBUG" = xyes; then

   PROFILE_CFLAGS="-g"

fi

AC_SUBST(PROFILE_CFLAGS)

if test "x$GST_CVS" = "xyes"; then

  DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"

else

  DEPRECATED_CFLAGS=""

fi

AC_SUBST(DEPRECATED_CFLAGS)

dnl every flag in GST_OPTION_CFLAGS can be overridden at make time

GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"

GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"

AC_SUBST(GST_OPTION_CFLAGS)

AC_SUBST(GST_OPTION_CXXFLAGS)

dnl our libraries need to be versioned correctly

AC_SUBST(GST_LT_LDFLAGS)

dnl FIXME: do we want to rename to GST_ALL_* ?

dnl add GST_OPTION_CFLAGS, but overridable

GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"

GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"

AC_SUBST(GST_CFLAGS)

AC_SUBST(GST_CXXFLAGS)

dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage

GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"

AC_SUBST(GST_LIBS)

dnl LDFLAGS really should only contain flags, not libs - they get added before

dnl whatevertarget_LIBS and -L flags here affect the rest of the linking

GST_ALL_LDFLAGS="-no-undefined"

AC_SUBST(GST_ALL_LDFLAGS)

dnl GST_LIB_LDFLAGS

dnl linker flags shared by all libraries

dnl LDFLAGS modifier defining exported symbols from built libraries

dnl (export _gst_foo but not __gst_foo)

GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"

AC_SUBST(GST_LIB_LDFLAGS)

dnl this really should only contain flags, not libs - they get added before

dnl whatevertarget_LIBS and -L flags here affect the rest of the linking

GST_PLUGIN_LDFLAGS="-module -avoid-version $GST_ALL_LDFLAGS"

AC_SUBST(GST_PLUGIN_LDFLAGS)

dnl *** output files ***

AC_CONFIG_FILES(

Makefile

gst/Makefile

gst/bc/Makefile

bc-app/Makefile

module/Makefile

module/Kbuild

po/Makefile.in

common/Makefile

common/m4/Makefile

)

AC_OUTPUT

AG_GST_OUTPUT_PLUGINS