#!/usr/bin/perl

use utf8;

use strict;

use warnings;

use feature 'say';

use WWW::Mechanize;

use File::Basename;

use Term::ANSIColor;

use Getopt::Std;

use constant SCRIPTURL => 'http://www.colivre.coop.br';

# Getopt::Std method for --version and --help

sub VERSION_MESSAGE {

   our $VERSION = '0.02';

   say basename($0) . " [-q] [VERSION]\n";

   say "check if all actionitems have at least one commit message on git repository";

   say "if version not specified then will try read version from lib/<project_name>.rb file.\n";

   say basename($0), " v$VERSION by Joenio Costa";

   exit 0;

}

sub get_project_version {

   my $project_name = shift;

   open my $VERSION_FILE, '<', "lib/$project_name.rb" or return undef;

   local $/ = undef;

   my $version_file_content = <$VERSION_FILE>;

   my ($version) = $version_file_content =~ m/VERSION = '(\d+\.\d+\.\d+)'/;

   return $version;

}

sub get_version_topic {

   my $name = $_[0];

   my $version = sprintf "%02dx%02dx%02d", split(/\./, $_[1]);

   my $mech = WWW::Mechanize->new(agent => 'colivre-robot', autocheck => 1 ) or die $!;

   my $topic = "$name.${name}Version$version";

   $mech->get(SCRIPTURL . "/$topic");

   return $mech->response->decoded_content;

}

sub find_missing_action_items {

   my $html_topic = shift;

   my $pre_block_for_each_commit = shift;

   my $pos_block_for_each_commit = shift;

   my @missing_action_item = ();

   while($html_topic =~ m{<a href="/[\d\w]+/(ActionItem\d+)" class="twikiLink">\#\d+</a>}sigo) {

      my $action_item = $1;

      &$pre_block_for_each_commit($action_item);

      open my $GIT_LOG, '-|', 'git', 'log', "--grep=$action_item", '--oneline';

      my $git_log_result = <$GIT_LOG>;

      close $GIT_LOG;

      $git_log_result = $git_log_result ? chomp $git_log_result : undef;

      &$pos_block_for_each_commit($git_log_result);

      unless($git_log_result) {

         push @missing_action_item, $action_item;

      }

   }

   return @missing_action_item;

}

sub get_current_branch {

   open my $GIT_STATUS, '-|', 'git', 'status';

   my $git_status = <$GIT_STATUS>;

   close $GIT_STATUS;

   return $git_status =~ m/# On branch (.+)\n/s ? $1 : undef;

}

#---- main

our $opt_q;

getopts('q');

close STDERR if $opt_q;

my $project_name = basename($ENV{PWD});

my $version = $#ARGV < 0 ? get_project_version($project_name) : $ARGV[0];

die "please, inform version!" unless $version;

print STDERR "accessing topic for $project_name v$version... ";

my $html_topic = get_version_topic(ucfirst $project_name, $version);

say STDERR "ok";

my $current_git_branch = get_current_branch;

say STDERR "checking '$current_git_branch' branch... ";

my @missing_action_item = find_missing_action_items(

   $html_topic,

   sub { print STDERR $_[0], "\t" },

   sub { say STDERR $_[0] ? colored('ok', 'green') : colored('nok', 'red') }

);

print ucfirst $project_name, " v$version ";

say @missing_action_item ? ('has ', colored('missing', 'red'), ' ActionItems!') : ('was ', colored('ok!', 'green'));