#!/usr/bin/perl

use strict;

use warnings;

use feature 'say';

use DateTime;

use GD;

use GD::Graph::bars;

use Getopt::Euclid;

sub calc_delta {

   my ($hour_start, $min_start) = split /:/, $_[0];

   my ($hour_end, $min_end) = split /:/, $_[1];

   my $start = DateTime->new(year => 2000, hour => $hour_start, minute => $min_start);

   my $end = DateTime->new(year => 2000, hour => $hour_end, minute => $min_end);

   my $duration = $end - $start;

   $duration->delta_minutes;

}

sub parse_timelog {

   my %tasks_by_date;

   open LOG, '<', $_[0] or die $!;

   while (<LOG>) {

      next if /^\s*$/; chomp;

      my ($date, $time, @task) = split /\s/;

      $time =~ s/:$//;

      my $duration = exists($tasks_by_date{$date}) ? calc_delta($tasks_by_date{$date}->[-1]{time}, $time) : 0;

      (my $group, @task) = split /:\s*/, "@task";

      push @{$tasks_by_date{$date}}, {group => $group, task => "@task", time => $time, minutes => $duration};

   }

   close LOG;

   return %tasks_by_date;

}

sub build_graph {

   my ($title, $x_label, $y_label) = @_;

   my $graph = GD::Graph::bars->new(700, 500);

   $graph->set(

      transparent => 0,

      x_label => $x_label,

      y_label => $y_label,

      title => $title,

      bar_spacing => 5,

      cycle_clrs => 1,

      overwrite => 1,

   ) or die $graph->error;

   return $graph;

}

sub plot_graph {

   my ($graph, $filename, @data) = @_;

   my $gd = $graph->plot(\@data) or die $graph->error;

   open IMG, '>', "$filename.png" or die $!;

   binmode IMG;

   print IMG $gd->png;

   close IMG;

   say "grafico salvo em: $filename.png";

}

sub default_graph {

   my ($date, %data) = @_;

   my %duration_by_group;

   foreach (@{$data{$date}}) {

      $duration_by_group{$_->{group}} += $_->{minutes};

   }

   my @data = (

      [ map { my $d = DateTime::Duration->new(minutes => $duration_by_group{$_}); sprintf("%s: %d:%02d", $_, $d->hours, $d->minutes) } keys %duration_by_group ],

      [ map { $duration_by_group{$_} / 60 } keys %duration_by_group ],

   );

   plot_graph(build_graph("Horas trabalhadas por grupo em $date", 'Grupo', 'Horas'), "$date", @data);

}

sub detailed_graph {

   my ($date, $group, %data) = @_;

   my @tasks = map { [$_->{task}, $_->{minutes}] } grep { $_->{group} eq $group } @{$data{$date}};

   my %duration_by_task;

   foreach (@tasks) {

      $duration_by_task{$_->[0]} += $_->[1];

   }

   my @data = (

      [ map { my $d = DateTime::Duration->new(minutes => $duration_by_task{$_}); sprintf("%d:%02d", $d->hours, $d->minutes) } keys %duration_by_task ],

      #[ map { $duration_by_task{$_} / 60 } keys %duration_by_task ],

   );

   foreach (keys %duration_by_task) {

      push @data, [ map { $duration_by_task{$_} / 60 } keys %duration_by_task ],

   }

   my $graph = build_graph("Detalhe de horas trabalhadas do grupo $group em $date", 'Tarefas', 'Horas');

   $graph->set_legend(keys %duration_by_task);

   plot_graph($graph, $date .'-'. lc($group), @data);

}

my $today = DateTime->now;

$today->add(days => -$ARGV{-d});

my %tasks_by_date = parse_timelog('/home/joenio/.gtimelog/timelog.txt');

if (exists $tasks_by_date{$today->ymd}) {

   if ($ARGV{-g}) {

      detailed_graph($today->ymd, $ARGV{-g}, %tasks_by_date);

   }

   else {

      default_graph($today->ymd, %tasks_by_date);

   }

}

else {

   warn "nao existem registros no dia: " . $today->ymd;

}

__END__

=head1 NAME

timelog-graph - Cria gráfico de barras a partir dos registros do gtimelog

=head1 VERSION

0.1

=head1 USAGE

    timelog-graph [options]

=head1 OPTIONS

=over

=item -d <d>

Gerar grafico de <d> dias atras.

=for Euclid:

    d.type: int >= 0

    d.default: 0

=item -g <g>

Gerar grafico detalhado do grupo <g>.

=item --version

=item --usage

=item --help

=item --man

Print the usual program information

=back

=head1 DEPENDENCIES

=over

=item L<DateTime>

=item L<GD::Graph>

=item L<Getopt::Euclid>

=back

=head1 TODO

=over

=item Calcular total de horas trabalho e nao trabalho

=item Corrigir data atual sendo gerada como dia seguinte

=item Gerar grafico de pizza com 24H

=item Corrigir problemas de codificação

=item Acessar arquivo timelog.txt usando uma intreface SQL

http://search.cpan.org/~jzucker/DBD-AnyData-0.09/AnyData.pm

http://search.cpan.org/~jzucker/DBD-CSV-0.22/lib/DBD/CSV.pm

http://search.cpan.org/~timb/DBI-1.607/lib/DBD/File.pm

=back

=head1 AUTHOR

Joenio Costa

=head1 COPYRIGHT

Copyright (c) 2009, Joenio Costa. All Rights Reserved.

This module is free software. It may be used, redistributed

and/or modified under the terms of the Perl Artistic License

(see http://www.perl.com/perl/misc/Artistic.html)