#  Copyright (c) 2009 Nokia Corporation

#  All rights reserved.

# 

#  Redistribution and use in source and binary forms, with or without

#  modification, are permitted provided that the following conditions are

#  met:

# 

#  * Redistributions of source code must retain the above copyright

#    notice, this list of conditions and the following disclaimer.

#  * Redistributions in binary form must reproduce the above copyright

#    notice, this list of conditions and the following disclaimer in the

#    documentation and/or other materials provided with the distribution.

#  * Neither the name of the Nokia Corporation nor the names of its

#    contributors may be used to endorse or promote products derived from

#    this software without specific prior written permission.

# 

#  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS

#  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED

#  TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A

#  PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER

#  OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,

#  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,

#  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR

#  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF

#  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING

#  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS

#  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

#           

#

AC_INIT([OpenMAX IL Proxy], [0.0], [], [libilproxy])

# tar-ustar used in AM_INIT_AUTOMAKE for long filename support

AM_INIT_AUTOMAKE([1.9 tar-ustar])

# Prerequisite autoconf version

AC_PREREQ([2.59])

# Check if the omx_adapter.c file is present

AC_CONFIG_SRCDIR([src/proxyloader/omx_adapter.c])

# Set to 'm4' the directory where the extra autoconf macros are stored

AC_CONFIG_MACRO_DIR([m4])

AC_CONFIG_FILES([

    Makefile

    m4/Makefile

    include/Makefile

    src/Makefile

    src/core/Makefile

    src/proxyloader/Makefile

    src/proxyservice/Makefile

    test/Makefile

    test/standardstructs/Makefile

    test/standardstructs/core/Makefile

    test/standardstructs/app/Makefile

    test/simpletest/Makefile

    libilproxy.pc

    libilproxyloader.pc

])

# Check for a working C compiler

AC_PROG_CC

AM_PROG_CC_C_O

# Check for libtool

AM_PROG_LIBTOOL

# require pkg-config

AC_PATH_PROG([PKG_CONFIG], [pkg-config], [no]) 

if test "$PKG_CONFIG" = "no"; then

   AC_MSG_ERROR([

   *** The pkg-config script could not be found. Make sure it is

   *** in your path, or set the PKG_CONFIG environment variable

   *** to the full path to pkg-config.])

fi

# libtool versioning

# REVISION gets incremented for non-ABI/API-break changes

# CURRENT/AGE get incremented for API/ABI-breaks; REVISION goes back to 0 

LTVERSION_CURRENT=0

LTVERSION_REVISION=0

# count of old, supported interfaces

LTVERSION_AGE=0

LIBILPROXY_LTVERSION=${LTVERSION_CURRENT}:${LTVERSION_REVISION}:${LTVERSION_AGE}

AC_SUBST([LIBILPROXY_LTVERSION])

dnl sem_timedwait hack is an trick to prevent deadlocks when there are

dnl error on the network level; it's useful for NoTA connections

dnl see omxProxySemWait in src/proxyloader/omx_proxy_common_functions.c

AC_ARG_ENABLE(

    [sem-timedwait-hack],

    [AC_HELP_STRING(

        [--enable-sem-timedwait-hack],

        [whether to enable the sem_timedwait hack])],

    [sem_timedwait_hack="-DSEM_TIMEDWAIT_HACK=1"],

    [sem_timedwait_hack=""])

dnl

dnl note, you can set user flags with

dnl ./configure CFLAGS=....

AM_CFLAGS="-Wall -DOMX_SKIP64BIT -DIGNORE_CMIMETYPE -D_REENTRANT \

 -DNOTAOMXIL_SPECVERSIONMAJOR=1 -DNOTAOMXIL_SPECVERSIONMINOR=1 \

 -DNOTAOMXIL_SPECREVISION=2 -DNOTAOMXIL_SPECSTEP=0 ${sem_timedwait_hack}"      

AC_SUBST(AM_CFLAGS)

AC_CHECK_HEADERS(pthread.h)

# Check whether TCP proxy is requested

AC_ARG_ENABLE(

    [tcpproxy],

    [AC_HELP_STRING(

        [--enable-tcpproxy],

        [whether to use direct tcp transport in libilproxy])],

    [with_tcpproxy=yes],

    [with_tcpproxy=no])

AC_ARG_ENABLE(

    [hin3proxy],

    [AC_HELP_STRING(

        [--enable-hin3proxy],

        [whether to use hin3 library as transport in libilproxy])],

    [with_hin3proxy=yes],

    [with_hin3proxy=no])

AC_ARG_ENABLE(

    [hin3spproxy],

    [AC_HELP_STRING(

        [--enable-hin3spproxy],

        [whether to use hin3 single process library as transport in libilproxy])],

    [with_hin3spproxy=yes],

    [with_hin3spproxy=no])

AC_ARG_ENABLE(

    [ilservice],

    [AC_HELP_STRING(

        [--enable-ilservice],

        [whether to build the OpenMAX IL service])],

    [with_ilservice=yes],

    [with_ilservice=no])

# this makes tcpproxy the default

if test "x$with_hin3proxy" == "xno" -a "x$with_hin3spproxy" == "xno"; then

   with_tcpproxy=yes

else

   with_tcpproxy=no

fi

AM_CONDITIONAL([WITH_TCPPROXY], [test "x$with_tcpproxy" = "xyes"])

AM_CONDITIONAL([WITH_HIN3PROXY], [test "x$with_hin3proxy" = "xyes"])

AM_CONDITIONAL([WITH_HIN3SPPROXY], [test "x$with_hin3spproxy" = "xyes"])

AM_CONDITIONAL([WITH_ILSERVICE], [test "x$with_ilservice" = "xyes"])

PKG_CHECK_MODULES(NOTA_H_IN,nota-h_in-3.0,hin3found=yes,hin3found=no)

PKG_CHECK_MODULES(NOTA_H_IN_SP,nota-h_in-sp-3.0,hin3spfound=yes,hin3spfound=no)

PKG_CHECK_MODULES(BELLAGIO,libomxil-bellagio,bellagiofound=yes,bellagiofound=no)

if test "x$bellagiofound" == "xno" -a "x$with_ilservice" == "xyes"; then

   AC_MSG_ERROR([Couldn't find Bellagio, you requested building the il proxy service that uses it. This is fatal. Check your PKG_CONFIG_PATH.])

fi

AM_CONDITIONAL([FOUND_HIN3], [test "x$hin3found" = "xyes"])

if test "x$hin3found" == "xno" -a "x$with_hin3proxy" == "xyes"; then

   AC_MSG_ERROR([Couldn't find HIN3, you requested for it. This is fatal. Check your PKG_CONFIG_PATH.])

fi

if test "x$hin3spfound" == "xno" -a "x$with_hin3spproxy" == "xyes"; then

   AC_MSG_ERROR([Couldn't find HIN3 sigle process, you requested for it. This is fatal. Check your PKG_CONFIG_PATH.])

fi

AC_SUBST(NOTA_H_IN_LIBS)

AC_SUBST(NOTA_H_IN_CFLAGS)

AC_SUBST(NOTA_H_IN_SP_LIBS)

AC_SUBST(NOTA_H_IN_SP_CFLAGS)

AC_SUBST(BELLAGIO_LIBS)

AC_SUBST(BELLAGIO_CFLAGS)

AC_OUTPUT

echo

echo "OpenMAX Proxy configure results"

echo "-----------------------------------"

echo "Prefix            : ${prefix}"

echo "CFLAGS            : $AM_CFLAGS $CFLAGS"

if test "x$with_ilservice" == "xyes"; then

echo "ilservice         : will be built"

else

echo "ilservice         : no (try --enable-ilservice)"

fi

echo "Only one transport should be selected below:"

echo "TCP transport     : $with_tcpproxy"

echo "HIN3 transport    : $with_hin3proxy"

echo "HIN3 SP transport : $with_hin3spproxy"

echo ""