#  Copyright (c) 2009 Nokia Corporation

#  All rights reserved.

# 

#  Redistribution and use in source and binary forms, with or without

#  modification, are permitted provided that the following conditions are

#  met:

# 

#  * Redistributions of source code must retain the above copyright

#    notice, this list of conditions and the following disclaimer.

#  * Redistributions in binary form must reproduce the above copyright

#    notice, this list of conditions and the following disclaimer in the

#    documentation and/or other materials provided with the distribution.

#  * Neither the name of the Nokia Corporation nor the names of its

#    contributors may be used to endorse or promote products derived from

#    this software without specific prior written permission.

# 

#  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS

#  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED

#  TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A

#  PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER

#  OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,

#  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,

#  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR

#  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF

#  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING

#  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS

#  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

#

#

#

AC_INIT([nota-stubgen],[3.0-2010.01],[http://notaworld.org])

AC_CONFIG_HEADERS([config.h])

AC_CONFIG_SRCDIR(adapter/hin3_stubadapter.c)

AC_CONFIG_MACRO_DIR([platform/m4])

AM_INIT_AUTOMAKE([dist-bzip2])

if test x$prefix = xNONE; then

   prefix=/usr/local

fi

AC_SUBST(prefix)

AC_PROG_CC

AM_PROG_CC_STDC

AC_HEADER_STDC

AC_PROG_LIBTOOL

# require pkg-config

AC_PATH_PROG([PKG_CONFIG], [pkg-config], [no]) 

if test "x$PKG_CONFIG" = "xno"; then

   AC_MSG_ERROR([

   *** The pkg-config script could not be found. Make sure it is

   *** in your path, or set the PKG_CONFIG environment variable

   *** to the full path to pkg-config.]) 

fi

dnl check for perl and perl-xml

AC_PATH_PROG([NOTA_PERL_PATH],[perl],

	AC_MSG_ERROR([The stubgenerator requires 'perl' in your PATH]))

AC_SUBST(NOTA_PERL_PATH)

AC_MSG_CHECKING([XML::LibXML])

have_libxml="yes"

${NOTA_PERL_PATH} -e 'use XML::LibXML;' 2>/dev/null || have_libxml="no"

if test "x$have_libxml" = "xno"; then		  

   AC_MSG_WARN([not found]

     [Please install the required the XML::LibXML perl module]

     [On Debian/Ubuntu, the package name is 'libxml-libxml-perl'])

fi

echo $have_libxml

AM_CONDITIONAL(NOTA_HAVE_LIBXML_PERL, test "x$have_libxml" = "xyes")

#

# optionally, use an uninstalled l_in

AC_ARG_WITH([h_in_builddir],AC_HELP_STRING([--with-h-in-builddir[=PFX]],[Prefix for h_in]),

   [h_in_builddir="$withval"], [h_in_builddir="none"])

if test "x$h_in_builddir" != "xnone"; then

   test -e $withval/daemon/libh_in3.la || 

   	AC_MSG_ERROR($withval/daemon/libh_in3.la not found)

   test -d $withval/inc/h_in || 

   	AC_MSG_ERROR($withval/inc/h_in not found)

   NOTA_H_IN_LIBS=$withval/daemon/libh_in3.la

   NOTA_H_IN_CFLAGS=-I$withval/inc/

   NOTA_H_IN_SP_LIBS=$withval/sp/libh_in3_sp.la

   NOTA_H_IN_SP_CFLAGS=-I$withval/inc/

else

   PKG_CHECK_MODULES(NOTA_H_IN,nota-h_in-3.0)  		

   PKG_CHECK_MODULES(NOTA_H_IN_SP,nota-h_in-sp-3.0)

fi

AC_SUBST(NOTA_H_IN_LIBS)

AC_SUBST(NOTA_H_IN_CFLAGS)

AC_SUBST(NOTA_H_IN_SP_LIBS)

AC_SUBST(NOTA_H_IN_SP_CFLAGS)

dnl what kind of threadlib to use?

ACX_PTHREAD

LIBS="$PTHREAD_LIBS $LIBS"

CFLAGS="$CFLAGS $PTHREAD_CFLAGS"

CC="$PTHREAD_CC"

AC_ARG_WITH(platform, [AC_HELP_STRING([--with-platform],

	[platform to build for: posix, symbian32, t-kernel])],

[case "${with_platform}" in

      posix)      NOTA_PLATFORM=${with_platform};;

      symbian32)  NOTA_PLATFORM=${with_platform};;

      t-kernel)   NOTA_PLATFORM=${with_platform};;

      *)          AC_MSG_ERROR([unsupported platform]);;

 esac], [NOTA_PLATFORM=posix])

NOTA_PLATFORM_DIR=platform/${NOTA_PLATFORM}

AC_SUBST(NOTA_PLATFORM_DIR)

AC_SUBST(NOTA_PLATFORM)

AC_OUTPUT([

Makefile

stubgen/Makefile

platform/posix/Makefile

platform/symbian32/Makefile

platform/t-kernel/Makefile

platform/m4/Makefile

platform/Makefile

adapter/Makefile

adapter/stubgen/Makefile

test/Makefile

man/Makefile

nota-stubgen-sp-3.0.pc

nota-stubgen-3.0.pc])

echo

echo "Stubgen configure results"

echo "-----------------------------------"

echo "Prefix            : ${prefix}"

echo "CFLAGS            : $CFLAGS"

echo "Platform          : $NOTA_PLATFORM"

echo ""

echo "Working stubgen   : $have_libxml"