www.gitorious.org Git - gnutls:gnutls.git/blob

1 dnl Process this file with autoconf to produce a configure script.

3 #

4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson

5 #

6 # This file is part of GnuTLS.

7 #

8 # This program is free software; you can redistribute it and/or modify

9 # it under the terms of the GNU General Public License as published by

10 # the Free Software Foundation; either version 3 of the License, or

11 # (at your option) any later version.

12 #

13 # This program is distributed in the hope that it will be useful, but

14 # WITHOUT ANY WARRANTY; without even the implied warranty of

15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU

16 # General Public License for more details.

17 #

18 # You should have received a copy of the GNU General Public License

19 # along with this program; if not, write to the Free Software

20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301

21 # USA

23 AC_PREREQ(2.61)

24 AC_INIT([GnuTLS], [3.3.0], [bugs@gnutls.org])

25 AC_CONFIG_AUX_DIR([build-aux])

26 AC_CONFIG_MACRO_DIR([m4])

27 AC_CANONICAL_HOST

29 AM_INIT_AUTOMAKE([1.12.2 no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])

30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

31 AC_CONFIG_HEADERS([config.h])

33 AC_MSG_RESULT([***

34 *** Checking for compilation programs...

35 ])

37 dnl Checks for programs.

38 AC_PROG_CC

39 gl_EARLY

40 ggl_EARLY

41 AM_PROG_AS

42 AM_PROG_AR

43 AC_PROG_CXX

44 AM_PROG_CC_C_O

45 AC_PROG_YACC

46 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])

48 if test x"$AUTOGEN" = "x/bin/true"; then

49 AC_MSG_WARN([[

50 ***

51 *** autogen not found. Will not link against libopts.

52 *** ]])

53 enable_local_libopts=yes

54 fi

56 # For includes/gnutls/gnutls.h.in.

57 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/$.*$\..*\..*/\1/g'`)

58 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.$.*$\..*/\1/g'`)

59 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.$.*$/\1/g'`)

60 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)

62 touch suppressions.valgrind

63 dnl C and C++ capabilities

64 AC_C_INLINE

65 AC_HEADER_STDC

67 # For the C++ code

68 AC_ARG_ENABLE(cxx,

69 AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),

70 use_cxx=$enableval, use_cxx=yes)

71 if test "$use_cxx" != "no"; then

72 AC_LANG_PUSH(C++)

73 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)

74 AC_LANG_POP(C++)

75 fi

76 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")

77 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])

79 dnl Detect windows build

80 case "$host" in

81 *mingw32* | *mingw64*)

82 have_win=yes

83 ;;

84 *darwin*)

85 have_macosx=yes

86 ;;

87 *)

88 have_elf=yes

89 ;;

90 esac

92 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)

93 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)

94 AM_CONDITIONAL(ELF, test "$have_elf" = yes)

96 dnl Hardware Acceleration

97 AC_ARG_ENABLE(hardware-acceleration,

98 AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),

99 use_accel=$enableval, use_accel=yes)

100 hw_accel=none

101

102

103 if test "$use_accel" != "no"; then

104 case $host_cpu in

105 i?86 | x86_64 | amd64)

106 AC_CHECK_HEADERS(cpuid.h)

107 if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then

108 hw_accel="x86-64"

109 else

110 hw_accel="x86"

111 fi

112 ;;

113 *)

114 ;;

115 esac

116

117 fi

118

119 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")

120 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")

121 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")

122 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])

123 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")

124

125 AC_ARG_ENABLE(self-checks,

126 AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),

127 enable_self_checks=$enableval, enable_self_checks=no)

128

129 AC_ARG_ENABLE(fips140-mode,

130 AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),

131 enable_fips=$enableval, enable_fips=no)

132 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")

133 if [ test "$enable_fips" = "yes" ];then

134 AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])

135 if test "x$HAVE_LIBDL" = "xyes";then

136 enable_self_checks=yes

137 AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])

138

139 AC_SUBST([FIPS140_LIBS], $LIBDL)

140 else

141 enable_fips=no

142 AC_MSG_WARN([[

143 ***

144 *** This system is not supported in FIPS140 mode.

145 *** libdl and dladdr() are required.

146 *** ]])

147 fi

148 fi

149

150 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")

151 if [ test "$enable_self_checks" = "yes" ];then

152 AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])

153 fi

154

155 dnl Try the hooks.m4

156 LIBGNUTLS_HOOKS

157 LIBGNUTLS_EXTRA_HOOKS

158

159 AC_ARG_ENABLE(doc,

160 AS_HELP_STRING([--disable-doc], [don't generate any documentation]),

161 enable_doc=$enableval, enable_doc=yes)

162 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")

163

164 AC_ARG_ENABLE(tests,

165 AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),

166 enable_tests=$enableval, enable_tests=yes)

167 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")

168

169 GTK_DOC_CHECK(1.1)

170 AM_GNU_GETTEXT([external])

171 AM_GNU_GETTEXT_VERSION([0.18])

172

173 AC_C_BIGENDIAN

174

175 gl_INIT

176 ggl_INIT

177

178 dnl GCC warnings to enable

179

180 AC_ARG_ENABLE([gcc-warnings],

181 [AS_HELP_STRING([--enable-gcc-warnings],

182 [turn on lots of GCC warnings (for developers)])],

183 [case $enableval in

184 yes|no) ;;

185 *) AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;

186 esac

187 gl_gcc_warnings=$enableval],

188 [gl_gcc_warnings=no]

189 )

190

191 if test "$gl_gcc_warnings" = yes; then

192 gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])

193

194 nw="$nw -Wsystem-headers" # Don't let system headers trigger warnings

195 nw="$nw -Wc++-compat" # We don't care about C++ compilers

196 nw="$nw -Wundef" # Warns on '#if GNULIB_FOO' etc in gnulib

197 nw="$nw -Wtraditional" # Warns on #elif which we use often

198 nw="$nw -Wlogical-op" # Too many false positives

199 nw="$nw -Wold-style-definition" #

200 nw="$nw -Wpadded" # Our structs are not padded

201 nw="$nw -Wunreachable-code" # Too many false positives

202 nw="$nw -Wtraditional-conversion" # Too many warnings for now

203 nw="$nw -Wcast-qual" # Too many warnings for now

204 nw="$nw -Waggregate-return" # Too many warnings for now

205 nw="$nw -Wshadow" # Too many warnings for now

206 nw="$nw -Wswitch-default" # Too many warnings for now

207 nw="$nw -Wswitch-enum" # Too many warnings for now

208 nw="$nw -Wconversion" # Too many warnings for now

209 nw="$nw -Wsign-conversion" # Too many warnings for now

210 nw="$nw -Wformat-y2k" # Too many warnings for now

211 nw="$nw -Woverlength-strings" # We use some in tests/

212 nw="$nw -Wvla" # There is no point to avoid C99 variable length arrays

213 nw="$nw -Wformat-nonliteral" # Incompatible with gettext _()

214 nw="$nw -Wunsafe-loop-optimizations"

215 nw="$nw -Wstrict-overflow"

216 nw="$nw -Wmissing-noreturn"

217 nw="$nw -Winline" # Too compiler dependent

218 nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?

219 nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?

220 nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?

221 nw="$nw -Wstack-protector" # Some functions cannot be protected

222 nw="$nw -Wredundant-decls" # Some files cannot be compiled with that (gl_fd_to_handle)

223

224 gl_MANYWARN_ALL_GCC([ws])

225 gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])

226 for w in $ws; do

227 gl_WARN_ADD([$w])

228 done

229

230 gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one

231 gl_WARN_ADD([-Wno-format-y2k]) # Too many warnings for now

232 gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get

233 gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get

234 gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now

235 gl_WARN_ADD([-Wno-stack-protector]) # Some functions cannot be protected

236 gl_WARN_ADD([-Wno-int-to-pointer-cast]) # Some files cannot be compiled with that (gl_fd_to_handle)

237 gl_WARN_ADD([-fdiagnostics-show-option])

238 fi

239

240 AC_SUBST([WERROR_CFLAGS])

241 AC_SUBST([WSTACK_CFLAGS])

242 AC_SUBST([WARN_CFLAGS])

243

244 dnl Programs for compilation or development

245 AC_PROG_LN_S

246 AC_LIBTOOL_WIN32_DLL

247 AC_PROG_LIBTOOL

248

249

250 dnl No fork on MinGW, disable some self-tests until we fix them.

251 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)

252 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)

253 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")

254

255 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>

256 #include <signal.h>

257 ], [timer_create (0,0,0);])

258

259 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then

260 AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])

261 fi

262

263 if test "$ac_cv_func_nanosleep" != "yes";then

264 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])

265 gnutls_needs_librt=yes

266 fi

267

268 ac_have_unicode=no

269 if test "$ac_cv_func_iconv" != "yes";then

270 AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])

271 if test "$HAVE_LIBICONV" = "yes";then

272 ac_have_unicode=yes

273 fi

274 else

275 ac_have_unicode=yes

276 fi

277

278 if test "$ac_have_unicode" != "yes";then

279 if test "$have_win" = "yes";then

280 ac_have_unicode=yes

281 fi

282 fi

283

284 AC_MSG_CHECKING([whether to build libdane])

285 AC_ARG_ENABLE(libdane,

286 AS_HELP_STRING([--disable-libdane],

287 [disable the built of libdane]),

288 enable_dane=$enableval, enable_dane=yes)

289 AC_MSG_RESULT($enable_dane)

290

291 if test "$enable_dane" != "no"; then

292 LIBS="$oldlibs -lunbound"

293 AC_MSG_CHECKING([for unbound library])

294 AC_LINK_IFELSE([AC_LANG_PROGRAM([

295 #include <unbound.h>],[

296 struct ub_ctx* ctx;

297 ctx = ub_ctx_create();])],

298 [AC_MSG_RESULT(yes)

299 AC_SUBST([UNBOUND_LIBS], [-lunbound])

300 AC_SUBST([UNBOUND_CFLAGS], [])

301 AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])

302 enable_dane=yes],

303 [AC_MSG_RESULT(no)

304 AC_MSG_WARN([[

305 ***

306 *** libunbound was not found. Libdane will not be built.

307 *** ]])

308 enable_dane=no])

309 LIBS="$oldlibs"

310 fi

311

312 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")

313

314 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],

315 [specify the unbound root key file]),

316 unbound_root_key_file="$withval",

317 if test "$have_win" = yes; then

318 unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"

319 else

320 if test -f /var/lib/unbound/root.key;then

321 unbound_root_key_file="/var/lib/unbound/root.key"

322 else

323 unbound_root_key_file="/etc/unbound/root.key"

324 fi

325 fi

326 )

327

328 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],

329 ["$unbound_root_key_file"], [The DNSSEC root key file])

330

331 dnl Check for p11-kit

332 P11_KIT_MINIMUM=0.19.1

333 AC_ARG_WITH(p11-kit,

334 AS_HELP_STRING([--without-p11-kit],

335 [Build without p11-kit and PKCS#11 support]))

336 if test "$with_p11_kit" != "no"; then

337 PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])

338 if test "$with_p11_kit" != "no";then

339 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])

340 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then

341 GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"

342 else

343 GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"

344 fi

345 else

346 with_p11_kit=no

347 AC_MSG_WARN([[

348 ***

349 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.

350 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html

351 *** ]])

352 fi

353 fi

354

355 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")

356

357 AC_ARG_WITH(tpm,

358 AS_HELP_STRING([--without-tpm],

359 [Disable TPM (trousers) support.]),

360 [with_tpm=$withval], [with_tpm=yes])

361 if test "$with_tpm" != "no"; then

362 LIBS="$oldlibs -ltspi"

363 AC_MSG_CHECKING([for tss library])

364 AC_LINK_IFELSE([AC_LANG_PROGRAM([

365 #include <trousers/tss.h>

366 #include <trousers/trousers.h>],[

367 int err = Tspi_Context_Create((void *)0);

368 Trspi_Error_String(err);])],

369 [AC_MSG_RESULT(yes)

370 AC_SUBST([TSS_LIBS], [-ltspi])

371 AC_SUBST([TSS_CFLAGS], [])

372 AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])

373 with_tpm=yes],

374 [AC_MSG_RESULT(no)

375 AC_MSG_WARN([[

376 ***

377 *** trousers was not found. TPM support will be disabled.

378 *** ]])

379 with_tpm=no])

380 LIBS="$oldlibs"

381 fi

382

383 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")

384

385 LIBOPTS_CHECK([src/libopts])

386 if test "$NEED_LIBOPTS_DIR" == "true";then

387 dnl delete libopts-generated files

388 for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do

389 nam=`echo $i|sed 's/.bak//g'`

390 if test -f $i;then

391 cp -f $i $nam

392 fi

393 done

394 AC_SUBST([AUTOGEN], [/bin/true])

395 enable_local_libopts=yes

396 else

397 enable_local_libopts=no

398 fi

399 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")

400

401 AC_CHECK_TYPE(ssize_t,

402 [

403 DEFINE_SSIZE_T="#include <sys/types.h>"

404 AC_SUBST(DEFINE_SSIZE_T)

405 ], [

406 AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])

407 DEFINE_SSIZE_T="typedef int ssize_t;"

408 AC_SUBST(DEFINE_SSIZE_T)

409 ], [

410 #include <sys/types.h>

411 ])

412

413 # For minitasn1.

414 AC_CHECK_SIZEOF(unsigned long int, 4)

415 AC_CHECK_SIZEOF(unsigned int, 4)

416

417 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],

418 [disable zlib compression support]),

419 ac_zlib=$withval, ac_zlib=yes)

420 AC_MSG_CHECKING([whether to include zlib compression support])

421 if test x$ac_zlib != xno; then

422 AC_MSG_RESULT(yes)

423 AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])

424 if test x$ac_cv_libz != xyes; then

425 AC_MSG_WARN(

426 ***

427 *** ZLIB was not found. You will not be able to use ZLIB compression.)

428 fi

429 else

430 AC_MSG_RESULT(no)

431 fi

432

433 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)

434

435 if test x$ac_zlib != xno; then

436 if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then

437 if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then

438 GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"

439 else

440 GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"

441 fi

442 fi

443 fi

444 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)

445

446

447

448 AC_ARG_WITH([default-trust-store-pkcs11],

449 [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],

450 [use the given pkcs11 uri as default trust store])])

451

452 if test "x$with_default_trust_store_pkcs11" != x; then

453 if test "x$with_p11_kit" = xno; then

454 AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])

455 fi

456 AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],

457 ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])

458 fi

459

460 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html

461 AC_ARG_WITH([default-trust-store-file],

462 [AS_HELP_STRING([--with-default-trust-store-file=FILE],

463 [use the given file default trust store])], with_default_trust_store_file="$withval",

464 [if test "$build" = "$host";then

465 for i in \

466 /etc/ssl/ca-bundle.pem \

467 /etc/ssl/certs/ca-certificates.crt \

468 /etc/pki/tls/cert.pem \

469 /usr/local/share/certs/ca-root-nss.crt \

470 /etc/ssl/cert.pem

471 do

472 if test -e $i; then

473 with_default_trust_store_file="$i"

474 break

475 fi

476 done

477 fi]

478 )

479

480 if test "$with_default_trust_store_file" = "no";then

481 with_default_trust_store_file=""

482 fi

483

484 AC_ARG_WITH([default-crl-file],

485 [AS_HELP_STRING([--with-default-crl-file=FILE],

486 [use the given CRL file as default])])

487

488 if test "x$with_default_trust_store_file" != x; then

489 AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],

490 ["$with_default_trust_store_file"], [use the given file default trust store])

491 fi

492

493 if test "x$with_default_crl_file" != x; then

494 AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],

495 ["$with_default_crl_file"], [use the given CRL file])

496 fi

497

498 dnl Guile bindings.

499 opt_guile_bindings=yes

500 AC_MSG_CHECKING([whether building Guile bindings])

501 AC_ARG_ENABLE(guile,

502 AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),

503 opt_guile_bindings=$enableval)

504 AC_MSG_RESULT($opt_guile_bindings)

505

506 AC_ARG_WITH([guile-site-dir],

507 [AS_HELP_STRING([--with-guile-site-dir],

508 [use the given directory as the Guile site (use with care)])])

509

510 if test "$opt_guile_bindings" = "yes"; then

511 AC_MSG_RESULT([***

512 *** Detecting GNU Guile...

513 ])

514

515 AC_PATH_PROG([guile_snarf], [guile-snarf])

516 if test "x$guile_snarf" = "x"; then

517 AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found. Guile bindings not built.])

518 opt_guile_bindings=no

519 else

520 GUILE_PROGS

521 GUILE_FLAGS

522

523 save_CFLAGS="$CFLAGS"

524 save_LIBS="$LIBS"

525 CFLAGS="$CFLAGS $GUILE_CFLAGS"

526 LIBS="$LIBS $GUILE_LDFLAGS"

527 AC_MSG_CHECKING([whether GNU Guile is recent enough])

528 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],

529 [], [opt_guile_bindings=no])

530 CFLAGS="$save_CFLAGS"

531 LIBS="$save_LIBS"

532

533 if test "$opt_guile_bindings" = "yes"; then

534 AC_MSG_RESULT([yes])

535 case "x$with_guile_site_dir" in

536 xno)

537 # Use the default $(GUILE_SITE).

538 GUILE_SITE_DIR

539 ;;

540 x|xyes)

541 # Automatically derive $(GUILE_SITE) from $(pkgdatadir). This

542 # hack is used to allow `distcheck' to work (see

543 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').

544 GUILE_SITE="\$(datadir)/guile/site"

545 AC_SUBST(GUILE_SITE)

546 ;;

547 *)

548 # Use the user-specified directory as $(GUILE_SITE).

549 GUILE_SITE="$with_guile_site_dir"

550 AC_SUBST(GUILE_SITE)

551 ;;

552 esac

553 AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])

554 _gcc_cflags_save="$CFLAGS"

555 CFLAGS="${CFLAGS} -fgnu89-inline"

556 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],

557 gnu89_inline=yes, gnu89_inline=no)

558 AC_MSG_RESULT($gnu89_inline)

559 CFLAGS="$_gcc_cflags_save"

560

561 # Optional Guile functions.

562 save_CFLAGS="$CFLAGS"

563 save_LIBS="$LIBS"

564 CFLAGS="$CFLAGS $GUILE_CFLAGS"

565 LIBS="$LIBS $GUILE_LDFLAGS"

566 AC_CHECK_FUNCS([scm_gc_malloc_pointerless])

567 CFLAGS="$save_CFLAGS"

568 LIBS="$save_LIBS"

569

570 # The place where guile-gnutls.la will go.

571 AC_MSG_CHECKING([the Guile effective version])

572 guile_effective_version="`$GUILE -c '(display (effective-version))'`"

573 AC_MSG_RESULT([$guile_effective_version])

574 guileextensiondir="$libdir/guile/$guile_effective_version"

575 AC_SUBST([guileextensiondir])

576 else

577 AC_MSG_RESULT([no])

578 AC_MSG_WARN([A sufficiently recent GNU Guile not found. Guile bindings not built.])

579 opt_guile_bindings=no

580 fi

581 fi

582 fi

583 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")

584

585 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"

586 LIBGNUTLS_CFLAGS="-I${includedir}"

587 AC_SUBST(LIBGNUTLS_LIBS)

588 AC_SUBST(LIBGNUTLS_CFLAGS)

589

590 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")

591

592 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])

593 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])

594

595 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])

596 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])

597 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])

598

599 dnl Crywrap dependencies

600 AC_MSG_RESULT([***

601 *** Checking dependencies for crywrap...

602 ])

603

604 crywrap=no

605

606 if test "$have_win" != "yes"; then

607

608 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])

609

610 dnl **********************

611 dnl * Typedefs & co

612 dnl **********************

613 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(

614 [AC_LANG_PROGRAM([#include <sys/types.h>

615 #include <signal.h>

616 ],

617 [return *(signal (0, 0)) (0) == 1;])],

618 [ac_cv_type_signal=int],

619 [ac_cv_type_signal=void])])

620 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers

621 (`int' or `void').])

622

623 AC_FUNC_SELECT_ARGTYPES

624 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \

625 putenv regcomp scandir select socket strcasecmp strchr \

626 strdup strerror strncasecmp strrchr strstr strtoul uname])

627

628 AC_ARG_ENABLE(crywrap,

629 AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))

630

631 libidn=no

632

633 if test "x$enable_crywrap" != "xno" ; then

634 PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])

635 AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])

636 fi

637

638 if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then

639 crywrap=yes

640 fi

641

642 fi

643

644 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")

645

646 dnl end of crywrap requirements

647

648 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])

649 AC_CONFIG_FILES([

650 Makefile

651 doc/Makefile

652 doc/credentials/Makefile

653 doc/credentials/openpgp/Makefile

654 doc/credentials/srp/Makefile

655 doc/credentials/x509/Makefile

656 doc/cyclo/Makefile

657 doc/doxygen/Doxyfile

658 doc/examples/Makefile

659 doc/latex/Makefile

660 doc/manpages/Makefile

661 doc/reference/Makefile

662 doc/reference/version.xml

663 doc/scripts/Makefile

664 extra/Makefile

665 extra/includes/Makefile

666 libdane/Makefile

667 libdane/includes/Makefile

668 libdane/gnutls-dane.pc

669 gl/Makefile

670 gl/tests/Makefile

671 guile/Makefile

672 guile/modules/Makefile

673 guile/src/Makefile

674 guile/tests/Makefile

675 lib/Makefile

676 lib/accelerated/Makefile

677 lib/accelerated/x86/Makefile

678 lib/algorithms/Makefile

679 lib/auth/Makefile

680 lib/ext/Makefile

681 lib/extras/Makefile

682 lib/gnutls.pc

683 lib/includes/Makefile

684 lib/includes/gnutls/gnutls.h

685 lib/minitasn1/Makefile

686 lib/nettle/Makefile

687 lib/opencdk/Makefile

688 lib/openpgp/Makefile

689 lib/x509/Makefile

690 po/Makefile.in

691 src/Makefile

692 src/crywrap/Makefile

693 src/gl/Makefile

694 tests/Makefile

695 tests/cert-tests/Makefile

696 tests/dsa/Makefile

697 tests/dtls/Makefile

698 tests/srp/Makefile

699 tests/ecdsa/Makefile

700 tests/key-id/Makefile

701 tests/openpgp-certs/Makefile

702 tests/pkcs1-padding/Makefile

703 tests/pkcs12-decode/Makefile

704 tests/pkcs8-decode/Makefile

705 tests/rsa-md5-collision/Makefile

706 tests/safe-renegotiation/Makefile

707 tests/scripts/Makefile

708 tests/sha2/Makefile

709 tests/slow/Makefile

710 tests/suite/Makefile

711 tests/userid/Makefile

712 ])

713

714 AC_OUTPUT

715

716 dnl Warning flags: errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}

717 dnl Valgrind: $opt_valgrind_tests ${VALGRIND}

718 AC_MSG_NOTICE([summary of build options:

719

720 version: ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE

721 Host/Target system: ${host}

722 Build system: ${build}

723 Install prefix: ${prefix}

724 Compiler: ${CC}

725 CFlags: ${CFLAGS}

726 Library types: Shared=${enable_shared}, Static=${enable_static}

727 ])

728

729 AC_MSG_NOTICE([External hardware support:

730

731 /dev/crypto: $enable_cryptodev

732 Hardware accel: $hw_accel

733 PKCS#11 support: $with_p11_kit

734 TPM support: $with_tpm

735 ])

736

737 AC_MSG_NOTICE([Optional features:

738 (note that included applications might not compile properly

739 if features are disabled)

740

741 DTLS-SRTP support: $ac_enable_srtp

742 ALPN support: $ac_enable_alpn

743 OCSP support: $ac_enable_ocsp

744 OpenPGP support: $ac_enable_openpgp

745 SRP support: $ac_enable_srp

746 PSK support: $ac_enable_psk

747 DHE support: $ac_enable_dhe

748 ECDHE support: $ac_enable_ecdhe

749 Anon auth support: $ac_enable_anon

750 Heartbeat support: $ac_enable_heartbeat

751 RSA-EXPORT compat: $ac_enable_rsa_export

752 Unicode support: $ac_have_unicode

753 Self checks: $enable_self_checks

754 FIPS140 mode: $enable_fips

755 ])

756

757 AC_MSG_NOTICE([Optional applications:

758

759 crywrap app: $libidn

760 local libopts: ${enable_local_libopts}

761 local libtasn1: ${included_libtasn1}

762 ])

763

764 AC_MSG_NOTICE([Optional libraries:

765

766 Guile wrappers: $opt_guile_bindings

767 C++ library: $use_cxx

768 DANE library: $enable_dane

769 OpenSSL compat: $enable_openssl

770 ])

771

772 AC_MSG_NOTICE([System files:

773

774 Trust store pkcs: $with_default_trust_store_pkcs11

775 Trust store file: $with_default_trust_store_file

776 CRL file: $with_default_crl_file

777 DNSSEC root key file: $unbound_root_key_file

778 ])

779

780 if test ! -f "$unbound_root_key_file"; then

781 AC_MSG_WARN([[

782 ***

783 *** The DNSSEC root key file in $unbound_root_key_file was not found.

784 *** This file is needed for the verification of DNSSEC responses.

785 *** Use the command: unbound-anchor -a "$unbound_root_key_file"

786 *** to generate or update it.

787 *** ]])

788 fi