check for sed in configure.ac and use the output variable in Makefiles
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.3.6], [bugs@gnutls.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 subdir-objects no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 ggl_EARLY
41 AM_PROG_AS
42 AM_PROG_AR
43 AC_PROG_CXX
44 AM_PROG_CC_C_O
45 AC_PROG_YACC
46 AC_PROG_SED
47 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
48
49 if test x"$AUTOGEN" = "x/bin/true"; then
50   AC_MSG_WARN([[
51 ***
52 *** autogen not found. Will not link against libopts.
53 *** ]])
54 enable_local_libopts=yes
55 fi
56
57 # For includes/gnutls/gnutls.h.in.
58 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
59 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
60 AC_SUBST(PATCH_VERSION, [[`echo $PACKAGE_VERSION | sed 's/.*\..*\.\([0-9]*\).*/\1/g'`]])
61 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
62
63 touch suppressions.valgrind
64 dnl C and C++ capabilities
65 AC_C_INLINE
66 AC_HEADER_STDC
67
68 # For the C++ code
69 AC_ARG_ENABLE(cxx,
70   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
71     use_cxx=$enableval, use_cxx=yes)
72 if test "$use_cxx" != "no"; then
73   AC_LANG_PUSH(C++)
74   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
75   AC_LANG_POP(C++)
76 fi
77 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
78 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
79
80 dnl Detect windows build
81 case "$host" in
82   *mingw32* | *mingw64*)
83     have_win=yes
84   ;;
85   *darwin*)
86     have_macosx=yes
87   ;;
88   *)
89     have_elf=yes
90   ;;
91 esac
92
93 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
94 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
95 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
96
97 dnl Hardware Acceleration
98 AC_ARG_ENABLE(hardware-acceleration,
99   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
100     use_accel=$enableval, use_accel=yes)
101 hw_accel=none
102
103
104 if test "$use_accel" != "no"; then
105 case $host_cpu in
106   i?86 | x86_64 | amd64)
107       AC_CHECK_HEADERS(cpuid.h)
108       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
109         hw_accel="x86-64"
110       else
111         hw_accel="x86"
112       fi
113   ;;
114   *)
115   ;;
116 esac
117
118 fi
119
120 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
121 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
122 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
123 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
124 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
125
126
127 dnl Try the hooks.m4
128 LIBGNUTLS_HOOKS
129 LIBGNUTLS_EXTRA_HOOKS
130
131 AC_ARG_ENABLE(doc,
132   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
133     enable_doc=$enableval, enable_doc=yes)
134 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
135
136 AC_ARG_ENABLE(tests,
137   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
138     enable_tests=$enableval, enable_tests=yes)
139 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
140
141 GTK_DOC_CHECK(1.1)
142 AM_GNU_GETTEXT([external])
143 AM_GNU_GETTEXT_VERSION([0.18])
144
145 AC_C_BIGENDIAN
146
147 dnl No fork on MinGW, disable some self-tests until we fix them.
148 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
149 AC_CHECK_FUNCS([fork inet_ntop inet_pton getrusage getpwuid_r nanosleep daemon getpid clock_gettime iconv localtime vasprintf],,)
150 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
151
152 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
153 #include <signal.h>
154 ], [timer_create (0,0,0);])
155
156 if test "$have_win" != "yes";then
157   AC_CHECK_FUNCS([pthread_mutex_lock],,)
158   if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
159     AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
160   fi
161 fi
162
163 if test "$ac_cv_func_nanosleep" != "yes";then
164   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
165   gnutls_needs_librt=yes
166 fi
167
168 if test "$ac_cv_func_clock_gettime" != "yes";then
169   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [clock_gettime (0, 0);])
170   gnutls_needs_librt=yes
171 fi
172
173 ac_have_unicode=no
174 if test "$ac_cv_func_iconv" != "yes";then
175   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
176   if test "$HAVE_LIBICONV" = "yes";then
177     ac_have_unicode=yes
178   fi
179 else
180   ac_have_unicode=yes
181 fi
182
183 if test "$ac_have_unicode" != "yes";then
184   if test "$have_win" = "yes";then
185     ac_have_unicode=yes
186   fi
187 fi
188
189 dnl Note that g*l_INIT are run after we check for library capabilities,
190 dnl to prevent issues from caching lib dependencies. See discussion
191 dnl in https://bugs.gentoo.org/show_bug.cgi?id=494940 and
192 dnl http://gnu-autoconf.7623.n7.nabble.com/Correct-way-to-check-for-clock-gettime-td12276.html
193 gl_INIT
194 ggl_INIT
195
196 dnl GCC warnings to enable
197
198 AC_ARG_ENABLE([gcc-warnings],
199   [AS_HELP_STRING([--enable-gcc-warnings],
200                   [turn on lots of GCC warnings (for developers)])],
201   [case $enableval in
202      yes|no) ;;
203      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
204    esac
205    gl_gcc_warnings=$enableval],
206   [gl_gcc_warnings=no]
207 )
208
209 if test "$gl_gcc_warnings" = yes; then
210   gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])
211
212   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
213   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
214   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
215   nw="$nw -Wtraditional"            # Warns on #elif which we use often
216   nw="$nw -Wlogical-op"             # Too many false positives
217   nw="$nw -Wold-style-definition"   # 
218   nw="$nw -Wpadded"                 # Our structs are not padded
219   nw="$nw -Wunreachable-code"       # Too many false positives
220   nw="$nw -Wtraditional-conversion" # Too many warnings for now
221   nw="$nw -Wcast-qual"              # Too many warnings for now
222   nw="$nw -Waggregate-return"       # Too many warnings for now
223   nw="$nw -Wshadow"                 # Too many warnings for now
224   nw="$nw -Wswitch-default"         # Too many warnings for now
225   nw="$nw -Wswitch-enum"            # Too many warnings for now
226   nw="$nw -Wconversion"             # Too many warnings for now
227   nw="$nw -Wsign-conversion"        # Too many warnings for now
228   nw="$nw -Wformat-y2k"             # Too many warnings for now
229   nw="$nw -Woverlength-strings"     # We use some in tests/
230   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
231   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
232   nw="$nw -Wunsafe-loop-optimizations"
233   nw="$nw -Wstrict-overflow"
234   nw="$nw -Wmissing-noreturn"
235   nw="$nw -Winline"                 # Too compiler dependent
236   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
237   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
238   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
239   nw="$nw -Wstack-protector"        # Some functions cannot be protected
240   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
241
242   gl_MANYWARN_ALL_GCC([ws])
243   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
244   for w in $ws; do
245     gl_WARN_ADD([$w])
246   done
247
248   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
249   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
250   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
251   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
252   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
253   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
254   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
255   gl_WARN_ADD([-fdiagnostics-show-option])
256 fi
257
258 AC_SUBST([WERROR_CFLAGS])
259 AC_SUBST([WSTACK_CFLAGS])
260 AC_SUBST([WARN_CFLAGS])
261
262 dnl Programs for compilation or development
263 AC_PROG_LN_S
264 LT_INIT([disable-static,win32-dll,shared])
265
266
267
268 AC_ARG_ENABLE(self-checks,
269   AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),
270     enable_self_checks=$enableval, enable_self_checks=no)
271
272 AC_ARG_ENABLE(fips140-mode,
273   AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),
274     enable_fips=$enableval, enable_fips=no)
275 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")
276 if [ test "$enable_fips" = "yes" ];then
277   AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])
278   if test "x$HAVE_LIBDL" = "xyes";then
279     enable_self_checks=yes
280
281     AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])
282
283     AC_SUBST([FIPS140_LIBS], $LIBDL)
284   else
285     enable_fips=no
286     AC_MSG_WARN([[
287 *** 
288 *** This system is not supported in FIPS140 mode.
289 *** libdl and dladdr() are required.
290 *** ]])
291   fi
292 fi
293
294 AC_ARG_ENABLE(non-suiteb-curves,
295   AS_HELP_STRING([--disable-non-suiteb-curves], [disable curves not in SuiteB]),
296     enable_non_suiteb=$enableval, enable_non_suiteb=yes)
297 if [ test "$enable_non_suiteb" = "yes" ];then
298   AC_DEFINE([ENABLE_NON_SUITEB_CURVES], 1, [Enable all curves])
299 fi
300
301 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")
302 if [ test "$enable_self_checks" = "yes" ];then
303    AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])
304 fi
305
306 AC_MSG_CHECKING([whether to build libdane])
307 AC_ARG_ENABLE(libdane,
308     AS_HELP_STRING([--disable-libdane],
309                    [disable the built of libdane]),
310     enable_dane=$enableval, enable_dane=yes)
311 AC_MSG_RESULT($enable_dane)
312
313 if test "$enable_dane" != "no"; then
314     LIBS="$oldlibs -lunbound"
315     AC_MSG_CHECKING([for unbound library])
316     AC_LINK_IFELSE([AC_LANG_PROGRAM([
317                    #include <unbound.h>],[
318                    struct ub_ctx* ctx;
319                    ctx = ub_ctx_create();])],
320                   [AC_MSG_RESULT(yes)
321                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
322                    AC_SUBST([UNBOUND_CFLAGS], [])
323                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
324                    enable_dane=yes],
325                   [AC_MSG_RESULT(no)
326                    AC_MSG_WARN([[
327 *** 
328 *** libunbound was not found. Libdane will not be built.
329 *** ]])
330                   enable_dane=no])
331     LIBS="$oldlibs"
332 fi
333
334 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
335
336 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
337                                  [specify the unbound root key file]),
338             unbound_root_key_file="$withval", 
339 if test "$have_win" = yes; then
340     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
341 else
342     if test -f /var/lib/unbound/root.key;then
343         unbound_root_key_file="/var/lib/unbound/root.key"
344     else
345         unbound_root_key_file="/etc/unbound/root.key"
346     fi
347 fi
348 )
349
350 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
351   ["$unbound_root_key_file"], [The DNSSEC root key file])
352
353 AC_ARG_WITH(system-priority-file, AS_HELP_STRING([--with-system-priority-file],
354                                  [specify the system priority file]),
355             system_priority_file="$withval", 
356 system_priority_file="/etc/gnutls/default-priorities"
357 )
358
359 AC_DEFINE_UNQUOTED([SYSTEM_PRIORITY_FILE],
360   ["$system_priority_file"], [The system priority file])
361
362 dnl Check for p11-kit
363 P11_KIT_MINIMUM=0.20.0
364 AC_ARG_WITH(p11-kit,
365         AS_HELP_STRING([--without-p11-kit],
366                 [Build without p11-kit and PKCS#11 support]))
367 if test "$with_p11_kit" != "no"; then
368         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
369         if test "$with_p11_kit" != "no";then
370                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
371                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
372                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
373                 else
374                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
375                 fi
376         else
377                 with_p11_kit=no
378                 AC_MSG_WARN([[
379 *** 
380 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
381 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
382 *** ]])
383         fi
384 fi
385
386 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
387
388 AC_ARG_WITH(tpm,
389         AS_HELP_STRING([--without-tpm],
390                 [Disable TPM (trousers) support.]),
391                 [with_tpm=$withval], [with_tpm=yes])
392 if test "$with_tpm" != "no"; then
393     LIBS="$oldlibs -ltspi"
394     AC_MSG_CHECKING([for tss library])
395     AC_LINK_IFELSE([AC_LANG_PROGRAM([
396                    #include <trousers/tss.h>
397                    #include <trousers/trousers.h>],[
398                    int err = Tspi_Context_Create((void *)0);
399                    Trspi_Error_String(err);])],
400                   [AC_MSG_RESULT(yes)
401                    AC_SUBST([TSS_LIBS], [-ltspi])
402                    AC_SUBST([TSS_CFLAGS], [])
403                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
404                    with_tpm=yes],
405                   [AC_MSG_RESULT(no)
406                    AC_MSG_WARN([[
407 *** 
408 *** trousers was not found. TPM support will be disabled.
409 *** ]])
410                   with_tpm=no])
411     LIBS="$oldlibs"
412 fi
413
414 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
415
416 LIBOPTS_CHECK([src/libopts])
417 if test "$NEED_LIBOPTS_DIR" = "true";then
418         dnl replace libopts-generated files with distributed backups, if present
419         missing_baks=
420         for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do
421                 nam=`echo $i|sed 's/.bak//g'`
422                 if test -f $i;then
423                         cp -f $i $nam
424                 else
425                         missing_baks=true
426                 fi
427         done
428         if test -z "$missing_baks"; then
429                 AC_SUBST([AUTOGEN], [/bin/true])
430         fi
431         enable_local_libopts=yes
432 else
433         enable_local_libopts=no
434 fi
435 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")
436
437 AC_CHECK_TYPE(ssize_t,
438   [
439     DEFINE_SSIZE_T="#include <sys/types.h>"
440     AC_SUBST(DEFINE_SSIZE_T)
441   ], [
442     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
443     DEFINE_SSIZE_T="typedef int ssize_t;"
444     AC_SUBST(DEFINE_SSIZE_T)
445   ], [
446     #include <sys/types.h>
447   ])
448
449 # For minitasn1.
450 AC_CHECK_SIZEOF(unsigned long int, 4)
451 AC_CHECK_SIZEOF(unsigned int, 4)
452
453 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
454                                  [disable zlib compression support]),
455             ac_zlib=$withval, ac_zlib=yes)
456 AC_MSG_CHECKING([whether to include zlib compression support])
457 if test x$ac_zlib != xno; then
458  AC_MSG_RESULT(yes)
459  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
460  if test x$ac_cv_libz != xyes; then
461    AC_MSG_WARN(
462 *** 
463 *** ZLIB was not found. You will not be able to use ZLIB compression.)
464  fi
465 else
466  AC_MSG_RESULT(no)
467 fi
468
469 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
470
471 if test x$ac_zlib != xno; then
472   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
473     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
474       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
475     else
476       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
477     fi
478   fi
479 fi
480 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
481
482
483
484 AC_ARG_WITH([default-trust-store-pkcs11],
485   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
486     [use the given pkcs11 uri as default trust store])])
487
488 if test "x$with_default_trust_store_pkcs11" != x; then
489   if test "x$with_p11_kit" = xno; then
490     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
491   fi
492   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
493     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
494 fi
495
496 AC_ARG_WITH([default-trust-store-dir],
497   [AS_HELP_STRING([--with-default-trust-store-dir=DIR],
498     [use the given directory as default trust store])])
499
500 if test "x$with_default_trust_store_dir" != x; then
501   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_DIR],
502     ["$with_default_trust_store_dir"], [use the given directory as default trust store])
503 fi
504
505 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
506 AC_ARG_WITH([default-trust-store-file],
507   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
508     [use the given file default trust store])], with_default_trust_store_file="$withval",
509   [if test "$build" = "$host" && test x$with_default_trust_store_pkcs11 = x && test x$with_default_trust_store_dir = x;then
510   for i in \
511     /etc/ssl/ca-bundle.pem \
512     /etc/ssl/certs/ca-certificates.crt \
513     /etc/pki/tls/cert.pem \
514     /usr/local/share/certs/ca-root-nss.crt \
515     /etc/ssl/cert.pem
516     do
517     if test -e "$i"; then
518       with_default_trust_store_file="$i"
519       break
520     fi
521   done
522   fi]
523 )
524
525 if test "$with_default_trust_store_file" = "no";then
526   with_default_trust_store_file=""
527 fi
528
529 AC_ARG_WITH([default-crl-file],
530   [AS_HELP_STRING([--with-default-crl-file=FILE],
531     [use the given CRL file as default])])
532
533 AC_ARG_WITH([default-blacklist-file],
534   [AS_HELP_STRING([--with-default-blacklist-file=FILE],
535     [use the given certificate blacklist file as default])])
536
537 if test "x$with_default_trust_store_file" != x; then
538   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
539     ["$with_default_trust_store_file"], [use the given file default trust store])
540 fi
541
542 if test "x$with_default_crl_file" != x; then
543   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
544     ["$with_default_crl_file"], [use the given CRL file])
545 fi
546
547 if test "x$with_default_blacklist_file" != x; then
548   AC_DEFINE_UNQUOTED([DEFAULT_BLACKLIST_FILE],
549     ["$with_default_blacklist_file"], [use the given certificate blacklist file])
550 fi
551
552 dnl Guile bindings.
553 opt_guile_bindings=yes
554 AC_MSG_CHECKING([whether building Guile bindings])
555 AC_ARG_ENABLE(guile,
556         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
557 opt_guile_bindings=$enableval)
558 AC_MSG_RESULT($opt_guile_bindings)
559
560 AC_ARG_WITH([guile-site-dir],
561   [AS_HELP_STRING([--with-guile-site-dir],
562      [use the given directory as the Guile site (use with care)])])
563
564 if test "$opt_guile_bindings" = "yes"; then
565    AC_MSG_RESULT([***
566 *** Detecting GNU Guile...
567 ])
568
569    AC_PATH_PROG([guile_snarf], [guile-snarf])
570    if test "x$guile_snarf" = "x"; then
571       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
572       opt_guile_bindings=no
573    else
574       GUILE_PROGS
575       GUILE_FLAGS
576
577       save_CFLAGS="$CFLAGS"
578       save_LIBS="$LIBS"
579       CFLAGS="$CFLAGS $GUILE_CFLAGS"
580       LIBS="$LIBS $GUILE_LDFLAGS"
581       AC_MSG_CHECKING([whether GNU Guile is recent enough])
582       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
583         [], [opt_guile_bindings=no])
584       CFLAGS="$save_CFLAGS"
585       LIBS="$save_LIBS"
586
587       if test "$opt_guile_bindings" = "yes"; then
588         AC_MSG_RESULT([yes])
589         case "x$with_guile_site_dir" in 
590              xno)
591                 # Use the default $(GUILE_SITE).
592                 GUILE_SITE_DIR
593                 ;;
594              x|xyes)
595                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
596                 # hack is used to allow `distcheck' to work (see
597                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
598                 GUILE_SITE="\$(datadir)/guile/site"
599                 AC_SUBST(GUILE_SITE)
600                 ;;
601              *)
602                 # Use the user-specified directory as $(GUILE_SITE).
603                 GUILE_SITE="$with_guile_site_dir"
604                 AC_SUBST(GUILE_SITE)
605                 ;;
606         esac
607         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
608         _gcc_cflags_save="$CFLAGS"
609         CFLAGS="${CFLAGS} -fgnu89-inline"
610         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
611                           gnu89_inline=yes, gnu89_inline=no)
612         AC_MSG_RESULT($gnu89_inline)
613         CFLAGS="$_gcc_cflags_save"
614
615         # Optional Guile functions.
616         save_CFLAGS="$CFLAGS"
617         save_LIBS="$LIBS"
618         CFLAGS="$CFLAGS $GUILE_CFLAGS"
619         LIBS="$LIBS $GUILE_LDFLAGS"
620         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
621         CFLAGS="$save_CFLAGS"
622         LIBS="$save_LIBS"
623
624         # The place where guile-gnutls.la will go.
625         AC_MSG_CHECKING([the Guile effective version])
626         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
627         AC_MSG_RESULT([$guile_effective_version])
628         guileextensiondir="$libdir/guile/$guile_effective_version"
629         AC_SUBST([guileextensiondir])
630       else
631         AC_MSG_RESULT([no])
632         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
633         opt_guile_bindings=no
634       fi
635    fi
636 fi
637 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
638
639 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
640 LIBGNUTLS_CFLAGS="-I${includedir}"
641 AC_SUBST(LIBGNUTLS_LIBS)
642 AC_SUBST(LIBGNUTLS_CFLAGS)
643
644 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")
645
646 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
647 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
648
649 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
650 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
651 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
652
653 dnl Crywrap dependencies
654    AC_MSG_RESULT([***
655 *** Checking dependencies for crywrap...
656 ])
657
658 crywrap=no
659
660 if test "$have_win" != "yes"; then
661
662 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
663
664 dnl **********************
665 dnl * Typedefs & co
666 dnl **********************
667 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
668 [AC_LANG_PROGRAM([#include <sys/types.h>
669 #include <signal.h>
670 ],
671                  [return *(signal (0, 0)) (0) == 1;])],
672                    [ac_cv_type_signal=int],
673                    [ac_cv_type_signal=void])])
674 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
675                     (`int' or `void').])
676
677 AC_FUNC_SELECT_ARGTYPES
678 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
679                 putenv regcomp scandir select socket strcasecmp strchr \
680                 strdup strerror strncasecmp strrchr strstr strtoul uname])
681
682 AC_ARG_ENABLE(crywrap,
683         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
684
685  libidn=no
686
687  if test "x$enable_crywrap" != "xno" ; then
688         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
689         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
690  fi
691
692  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
693   crywrap=yes
694  fi
695
696 fi
697
698 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
699
700 dnl end of crywrap requirements
701
702 dnl Some variables needed in makefiles
703 YEAR=`date +%Y`
704 AC_SUBST([YEAR], $YEAR)
705
706 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
707 AC_CONFIG_FILES([
708   Makefile
709   doc/Makefile
710   doc/credentials/Makefile
711   doc/credentials/openpgp/Makefile
712   doc/credentials/srp/Makefile
713   doc/credentials/x509/Makefile
714   doc/cyclo/Makefile
715   doc/doxygen/Doxyfile
716   doc/examples/Makefile
717   doc/latex/Makefile
718   doc/manpages/Makefile
719   doc/reference/Makefile
720   doc/reference/version.xml
721   doc/scripts/Makefile
722   extra/Makefile
723   extra/includes/Makefile
724   libdane/Makefile
725   libdane/includes/Makefile
726   libdane/gnutls-dane.pc
727   gl/Makefile
728   gl/tests/Makefile
729   guile/Makefile
730   guile/modules/Makefile
731   guile/src/Makefile
732   guile/tests/Makefile
733   lib/Makefile
734   lib/accelerated/Makefile
735   lib/accelerated/x86/Makefile
736   lib/algorithms/Makefile
737   lib/auth/Makefile
738   lib/ext/Makefile
739   lib/extras/Makefile
740   lib/gnutls.pc
741   lib/includes/Makefile
742   lib/includes/gnutls/gnutls.h
743   lib/minitasn1/Makefile
744   lib/nettle/Makefile
745   lib/opencdk/Makefile
746   lib/openpgp/Makefile
747   lib/x509/Makefile
748   po/Makefile.in
749   src/Makefile
750   src/crywrap/Makefile
751   src/gl/Makefile
752   tests/Makefile
753   tests/cert-tests/Makefile
754   tests/dsa/Makefile
755   tests/dtls/Makefile
756   tests/srp/Makefile
757   tests/ecdsa/Makefile
758   tests/key-tests/Makefile
759   tests/openpgp-certs/Makefile
760   tests/pkcs1-padding/Makefile
761   tests/pkcs12-decode/Makefile
762   tests/pkcs8-decode/Makefile
763   tests/rsa-md5-collision/Makefile
764   tests/safe-renegotiation/Makefile
765   tests/scripts/Makefile
766   tests/sha2/Makefile
767   tests/slow/Makefile
768   tests/suite/Makefile
769   tests/userid/Makefile
770 ])
771
772 AC_OUTPUT
773
774 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
775 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
776 AC_MSG_NOTICE([summary of build options:
777
778   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
779   Host/Target system:   ${host}
780   Build system:         ${build}
781   Install prefix:       ${prefix}
782   Compiler:             ${CC}
783   CFlags:               ${CFLAGS}
784   Library types:        Shared=${enable_shared}, Static=${enable_static}
785   Local libopts:        ${enable_local_libopts}
786   Local libtasn1:       ${included_libtasn1}
787   Use nettle-mini:      ${mini_nettle}
788 ])
789
790 AC_MSG_NOTICE([External hardware support:
791
792   /dev/crypto:          $enable_cryptodev
793   Hardware accel:       $hw_accel
794   PKCS#11 support:      $with_p11_kit
795   TPM support:          $with_tpm
796 ])
797
798 AC_MSG_NOTICE([Optional features:
799 (note that included applications might not compile properly
800 if features are disabled)
801
802   DTLS-SRTP support:    $ac_enable_srtp
803   ALPN support:         $ac_enable_alpn
804   OCSP support:         $ac_enable_ocsp
805   Ses. ticket support:  $ac_enable_session_tickets
806   OpenPGP support:      $ac_enable_openpgp
807   SRP support:          $ac_enable_srp
808   PSK support:          $ac_enable_psk
809   DHE support:          $ac_enable_dhe
810   ECDHE support:        $ac_enable_ecdhe
811   RSA-EXPORT support:   $ac_enable_rsa_export
812   Anon auth support:    $ac_enable_anon
813   Heartbeat support:    $ac_enable_heartbeat
814   Unicode support:      $ac_have_unicode
815   Self checks:          $enable_self_checks
816   Non-SuiteB curves:    $enable_non_suiteb
817   FIPS140 mode:         $enable_fips
818 ])
819
820 AC_MSG_NOTICE([Optional applications:
821
822   crywrap app:          $libidn
823 ])
824
825 AC_MSG_NOTICE([Optional libraries:
826
827   Guile wrappers:       $opt_guile_bindings
828   C++ library:          $use_cxx
829   DANE library:         $enable_dane
830   OpenSSL compat:       $enable_openssl
831 ])
832
833 AC_MSG_NOTICE([System files:
834
835   Trust store pkcs11:   $with_default_trust_store_pkcs11
836   Trust store dir:      $with_default_trust_store_dir
837   Trust store file:     $with_default_trust_store_file
838   Blacklist file:       $with_default_blacklist_file
839   CRL file:             $with_default_crl_file
840   Priority file:        $system_priority_file
841   DNSSEC root key file: $unbound_root_key_file
842 ])
843
844 if test ! -f "$unbound_root_key_file"; then
845 AC_MSG_WARN([[
846 *** 
847 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
848 *** This file is needed for the verification of DNSSEC responses.
849 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
850 *** to generate or update it.
851 *** ]])
852 fi