removed unneeded command
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.2.6], [bug-gnutls@gnu.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 AM_PROG_AS
41 AM_PROG_AR
42 AC_PROG_CXX
43 AM_PROG_CC_C_O
44 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
45
46 if test x"$AUTOGEN" = "x/bin/true"; then
47   AC_MSG_WARN([[
48 ***
49 *** autogen not found. Will not link against libopts.
50 *** ]])
51 NEED_LIBOPTS_DIR=true
52 fi
53
54 # For includes/gnutls/gnutls.h.in.
55 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
56 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
57 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
58 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
59
60 touch suppressions.valgrind
61 dnl C and C++ capabilities
62 AC_C_INLINE
63 AC_HEADER_STDC
64
65 # For the C++ code
66 AC_ARG_ENABLE(cxx,
67   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
68     use_cxx=$enableval, use_cxx=yes)
69 if test "$use_cxx" != "no"; then
70   AC_LANG_PUSH(C++)
71   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
72   AC_LANG_POP(C++)
73 fi
74 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
75 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
76
77 dnl Detect windows build
78 case "$host" in
79   *mingw32* | *mingw64*)
80     have_win=yes
81   ;;
82   *darwin*)
83     have_macosx=yes
84   ;;
85   *)
86     have_elf=yes
87   ;;
88 esac
89
90 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
91 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
92 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
93
94 dnl Hardware Acceleration
95 AC_ARG_ENABLE(hardware-acceleration,
96   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
97     use_accel=$enableval, use_accel=yes)
98 hw_accel=none
99
100
101 if test "$use_accel" != "no"; then
102 case $host_cpu in
103   i?86 | x86_64 | amd64)
104       AC_CHECK_HEADERS(cpuid.h)
105       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
106         hw_accel="x86-64"
107       else
108         hw_accel="x86"
109       fi
110   ;;
111   *)
112   ;;
113 esac
114
115 fi
116
117 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
118 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
119 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
120 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
121 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
122
123 dnl Try the hooks.m4
124 LIBGNUTLS_HOOKS
125 LIBGNUTLS_EXTRA_HOOKS
126
127 AC_ARG_ENABLE(doc,
128   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
129     enable_doc=$enableval, enable_doc=yes)
130 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
131
132 AC_ARG_ENABLE(tests,
133   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
134     enable_tests=$enableval, enable_tests=yes)
135 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
136
137 GTK_DOC_CHECK(1.1)
138 AM_GNU_GETTEXT([external])
139 AM_GNU_GETTEXT_VERSION([0.18])
140
141 AC_C_BIGENDIAN
142
143 gl_INIT
144
145 dnl GCC warnings to enable
146
147 AC_ARG_ENABLE([gcc-warnings],
148   [AS_HELP_STRING([--enable-gcc-warnings],
149                   [turn on lots of GCC warnings (for developers)])],
150   [case $enableval in
151      yes|no) ;;
152      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
153    esac
154    gl_gcc_warnings=$enableval],
155   [gl_gcc_warnings=no]
156 )
157
158 if test "$gl_gcc_warnings" = yes; then
159   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
160
161   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
162   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
163   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
164   nw="$nw -Wtraditional"            # Warns on #elif which we use often
165   nw="$nw -Wlogical-op"             # Too many false positives
166   nw="$nw -Wold-style-definition"   # 
167   nw="$nw -Wpadded"                 # Our structs are not padded
168   nw="$nw -Wunreachable-code"       # Too many false positives
169   nw="$nw -Wtraditional-conversion" # Too many warnings for now
170   nw="$nw -Wcast-qual"              # Too many warnings for now
171   nw="$nw -Waggregate-return"       # Too many warnings for now
172   nw="$nw -Wshadow"                 # Too many warnings for now
173   nw="$nw -Wswitch-default"         # Too many warnings for now
174   nw="$nw -Wswitch-enum"            # Too many warnings for now
175   nw="$nw -Wconversion"             # Too many warnings for now
176   nw="$nw -Wsign-conversion"        # Too many warnings for now
177   nw="$nw -Wformat-y2k"             # Too many warnings for now
178   nw="$nw -Woverlength-strings"     # We use some in tests/
179   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
180   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
181   nw="$nw -Wunsafe-loop-optimizations"
182   nw="$nw -Wstrict-overflow"
183   nw="$nw -Wmissing-noreturn"
184   nw="$nw -Winline"                 # Too compiler dependent
185   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
186   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
187   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
188   nw="$nw -Wstack-protector"        # Some functions cannot be protected
189   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
190
191   gl_MANYWARN_ALL_GCC([ws])
192   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
193   for w in $ws; do
194     gl_WARN_ADD([$w])
195   done
196
197   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
198   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
199   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
200   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
201   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
202   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
203   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
204   gl_WARN_ADD([-fdiagnostics-show-option])
205 fi
206
207 AC_SUBST([WERROR_CFLAGS])
208 AC_SUBST([WSTACK_CFLAGS])
209 AC_SUBST([WARN_CFLAGS])
210
211 dnl Programs for compilation or development
212 AC_PROG_LN_S
213 AC_LIBTOOL_WIN32_DLL
214 AC_PROG_LIBTOOL
215
216
217 dnl No fork on MinGW, disable some self-tests until we fix them.
218 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
219 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)
220 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
221
222 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
223 #include <signal.h>
224 ], [timer_create (0,0,0);])
225
226 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
227   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
228 fi
229
230 if test "$ac_cv_func_nanosleep" != "yes";then
231   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
232 fi
233
234 ac_have_unicode=no
235 if test "$ac_cv_func_iconv" != "yes";then
236   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
237   if test "$HAVE_LIBICONV" = "yes";then
238     ac_have_unicode=yes
239   fi
240 else
241   ac_have_unicode=yes
242 fi
243
244 if test "$ac_have_unicode" != "yes";then
245   if test "$have_win" = "yes";then
246     ac_have_unicode=yes
247   fi
248 fi
249
250 AC_MSG_CHECKING([whether to build libdane])
251 AC_ARG_ENABLE(libdane,
252     AS_HELP_STRING([--disable-libdane],
253                    [disable the built of libdane]),
254     enable_dane=$enableval, enable_dane=yes)
255 AC_MSG_RESULT($enable_dane)
256
257 if test "$enable_dane" != "no"; then
258     LIBS="$oldlibs -lunbound"
259     AC_MSG_CHECKING([for unbound library])
260     AC_LINK_IFELSE([AC_LANG_PROGRAM([
261                    #include <unbound.h>],[
262                    struct ub_ctx* ctx;
263                    ctx = ub_ctx_create();])],
264                   [AC_MSG_RESULT(yes)
265                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
266                    AC_SUBST([UNBOUND_CFLAGS], [])
267                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
268                    enable_dane=yes],
269                   [AC_MSG_RESULT(no)
270                    AC_MSG_WARN([[
271 *** 
272 *** libunbound was not found. Libdane will not be built.
273 *** ]])
274                   enable_dane=no])
275     LIBS="$oldlibs"
276 fi
277
278 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
279
280 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
281                                  [specify the unbound root key file]),
282             unbound_root_key_file="$withval", 
283 if test "$have_win" = yes; then
284     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
285 else
286     unbound_root_key_file="/etc/unbound/root.key"
287 fi
288 )
289
290 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
291   ["$unbound_root_key_file"], [The DNSSEC root key file])
292
293 dnl Check for p11-kit
294 P11_KIT_MINIMUM=0.19.1
295 AC_ARG_WITH(p11-kit,
296         AS_HELP_STRING([--without-p11-kit],
297                 [Build without p11-kit and PKCS#11 support]))
298 if test "$with_p11_kit" != "no"; then
299         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
300         if test "$with_p11_kit" != "no";then
301                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
302                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
303                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
304                 else
305                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
306                 fi
307         else
308                 with_p11_kit=no
309                 AC_MSG_WARN([[
310 *** 
311 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
312 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
313 *** ]])
314         fi
315 fi
316
317 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
318
319 AC_ARG_WITH(tpm,
320         AS_HELP_STRING([--without-tpm],
321                 [Disable TPM (trousers) support.]),
322                 [with_tpm=$withval], [with_tpm=yes])
323 if test "$with_tpm" != "no"; then
324     LIBS="$oldlibs -ltspi"
325     AC_MSG_CHECKING([for tss library])
326     AC_LINK_IFELSE([AC_LANG_PROGRAM([
327                    #include <trousers/tss.h>
328                    #include <trousers/trousers.h>],[
329                    int err = Tspi_Context_Create((void *)0);
330                    Trspi_Error_String(err);])],
331                   [AC_MSG_RESULT(yes)
332                    AC_SUBST([TSS_LIBS], [-ltspi])
333                    AC_SUBST([TSS_CFLAGS], [])
334                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
335                    with_tpm=yes],
336                   [AC_MSG_RESULT(no)
337                    AC_MSG_WARN([[
338 *** 
339 *** trousers was not found. TPM support will be disabled.
340 *** ]])
341                   with_tpm=no])
342     LIBS="$oldlibs"
343 fi
344
345 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
346
347 LIBOPTS_CHECK([src/libopts])
348 if [ test "$NEED_LIBOPTS_DIR" != "true" ];then
349         dnl delete libopts-generated files
350         rm -f src/*-args.c src/*-args.h
351 fi
352
353 AC_CHECK_TYPE(ssize_t,
354   [
355     DEFINE_SSIZE_T="#include <sys/types.h>"
356     AC_SUBST(DEFINE_SSIZE_T)
357   ], [
358     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
359     DEFINE_SSIZE_T="typedef int ssize_t;"
360     AC_SUBST(DEFINE_SSIZE_T)
361   ], [
362     #include <sys/types.h>
363   ])
364
365 # For minitasn1.
366 AC_CHECK_SIZEOF(unsigned long int, 4)
367 AC_CHECK_SIZEOF(unsigned int, 4)
368
369 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
370                                  [disable zlib compression support]),
371             ac_zlib=$withval, ac_zlib=yes)
372 AC_MSG_CHECKING([whether to include zlib compression support])
373 if test x$ac_zlib != xno; then
374  AC_MSG_RESULT(yes)
375  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
376  if test x$ac_cv_libz != xyes; then
377    AC_MSG_WARN(
378 *** 
379 *** ZLIB was not found. You will not be able to use ZLIB compression.)
380  fi
381 else
382  AC_MSG_RESULT(no)
383 fi
384
385 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
386
387 if test x$ac_zlib != xno; then
388   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
389     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
390       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
391     else
392       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
393     fi
394   fi
395 fi
396 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
397
398
399
400 AC_ARG_WITH([default-trust-store-pkcs11],
401   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
402     [use the given pkcs11 uri as default trust store])])
403
404 if test "x$with_default_trust_store_pkcs11" != x; then
405   if test "x$with_p11_kit" = xno; then
406     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
407   fi
408   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
409     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
410 fi
411
412 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
413 AC_ARG_WITH([default-trust-store-file],
414   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
415     [use the given file default trust store])], with_default_trust_store_file="$withval",
416   [if test "$build" = "$host";then
417   for i in \
418     /etc/ssl/ca-bundle.pem \
419     /etc/ssl/certs/ca-certificates.crt \
420     /etc/pki/tls/cert.pem \
421     /usr/local/share/certs/ca-root-nss.crt \
422     /etc/ssl/cert.pem
423     do
424     if test -e $i; then
425       with_default_trust_store_file="$i"
426       break
427     fi
428   done
429   fi]
430 )
431
432 if test "$with_default_trust_store_file" = "no";then
433   with_default_trust_store_file=""
434 fi
435
436 AC_ARG_WITH([default-crl-file],
437   [AS_HELP_STRING([--with-default-crl-file=FILE],
438     [use the given CRL file as default])])
439
440 if test "x$with_default_trust_store_file" != x; then
441   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
442     ["$with_default_trust_store_file"], [use the given file default trust store])
443 fi
444
445 if test "x$with_default_crl_file" != x; then
446   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
447     ["$with_default_crl_file"], [use the given CRL file])
448 fi
449
450 dnl Guile bindings.
451 opt_guile_bindings=yes
452 AC_MSG_CHECKING([whether building Guile bindings])
453 AC_ARG_ENABLE(guile,
454         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
455 opt_guile_bindings=$enableval)
456 AC_MSG_RESULT($opt_guile_bindings)
457
458 AC_ARG_WITH([guile-site-dir],
459   [AS_HELP_STRING([--with-guile-site-dir],
460      [use the given directory as the Guile site (use with care)])])
461
462 if test "$opt_guile_bindings" = "yes"; then
463    AC_MSG_RESULT([***
464 *** Detecting GNU Guile...
465 ])
466
467    AC_PATH_PROG([guile_snarf], [guile-snarf])
468    if test "x$guile_snarf" = "x"; then
469       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
470       opt_guile_bindings=no
471    else
472       GUILE_PROGS
473       GUILE_FLAGS
474
475       save_CFLAGS="$CFLAGS"
476       save_LIBS="$LIBS"
477       CFLAGS="$CFLAGS $GUILE_CFLAGS"
478       LIBS="$LIBS $GUILE_LDFLAGS"
479       AC_MSG_CHECKING([whether GNU Guile is recent enough])
480       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
481         [], [opt_guile_bindings=no])
482       CFLAGS="$save_CFLAGS"
483       LIBS="$save_LIBS"
484
485       if test "$opt_guile_bindings" = "yes"; then
486         AC_MSG_RESULT([yes])
487         case "x$with_guile_site_dir" in 
488              xno)
489                 # Use the default $(GUILE_SITE).
490                 GUILE_SITE_DIR
491                 ;;
492              x|xyes)
493                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
494                 # hack is used to allow `distcheck' to work (see
495                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
496                 GUILE_SITE="\$(datadir)/guile/site"
497                 AC_SUBST(GUILE_SITE)
498                 ;;
499              *)
500                 # Use the user-specified directory as $(GUILE_SITE).
501                 GUILE_SITE="$with_guile_site_dir"
502                 AC_SUBST(GUILE_SITE)
503                 ;;
504         esac
505         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
506         _gcc_cflags_save="$CFLAGS"
507         CFLAGS="${CFLAGS} -fgnu89-inline"
508         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
509                           gnu89_inline=yes, gnu89_inline=no)
510         AC_MSG_RESULT($gnu89_inline)
511         CFLAGS="$_gcc_cflags_save"
512
513         # Optional Guile functions.
514         save_CFLAGS="$CFLAGS"
515         save_LIBS="$LIBS"
516         CFLAGS="$CFLAGS $GUILE_CFLAGS"
517         LIBS="$LIBS $GUILE_LDFLAGS"
518         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
519         CFLAGS="$save_CFLAGS"
520         LIBS="$save_LIBS"
521
522         # The place where guile-gnutls.la will go.
523         AC_MSG_CHECKING([the Guile effective version])
524         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
525         AC_MSG_RESULT([$guile_effective_version])
526         guileextensiondir="$libdir/guile/$guile_effective_version"
527         AC_SUBST([guileextensiondir])
528       else
529         AC_MSG_RESULT([no])
530         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
531         opt_guile_bindings=no
532       fi
533    fi
534 fi
535 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
536
537 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
538 LIBGNUTLS_CFLAGS="-I${includedir}"
539 AC_SUBST(LIBGNUTLS_LIBS)
540 AC_SUBST(LIBGNUTLS_CFLAGS)
541
542
543 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
544 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
545
546 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
547 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
548 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
549
550 dnl Crywrap dependencies
551    AC_MSG_RESULT([***
552 *** Checking dependencies for crywrap...
553 ])
554
555 crywrap=no
556
557 if test "$have_win" != "yes"; then
558
559 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
560
561 dnl **********************
562 dnl * Typedefs & co
563 dnl **********************
564 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
565 [AC_LANG_PROGRAM([#include <sys/types.h>
566 #include <signal.h>
567 ],
568                  [return *(signal (0, 0)) (0) == 1;])],
569                    [ac_cv_type_signal=int],
570                    [ac_cv_type_signal=void])])
571 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
572                     (`int' or `void').])
573
574 AC_FUNC_SELECT_ARGTYPES
575 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
576                 putenv regcomp scandir select socket strcasecmp strchr \
577                 strdup strerror strncasecmp strrchr strstr strtoul uname])
578
579 AC_ARG_ENABLE(crywrap,
580         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
581
582  libidn=no
583
584  if test "x$enable_crywrap" != "xno" ; then
585         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
586         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
587  fi
588
589  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
590   crywrap=yes
591  fi
592
593 fi
594
595 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
596
597 dnl end of crywrap requirements
598
599 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
600 AC_CONFIG_FILES([
601   Makefile
602   doc/Makefile
603   doc/credentials/Makefile
604   doc/credentials/openpgp/Makefile
605   doc/credentials/srp/Makefile
606   doc/credentials/x509/Makefile
607   doc/cyclo/Makefile
608   doc/doxygen/Doxyfile
609   doc/examples/Makefile
610   doc/latex/Makefile
611   doc/manpages/Makefile
612   doc/reference/Makefile
613   doc/reference/version.xml
614   doc/scripts/Makefile
615   extra/Makefile
616   extra/includes/Makefile
617   libdane/Makefile
618   libdane/includes/Makefile
619   libdane/gnutls-dane.pc
620   gl/Makefile
621   gl/tests/Makefile
622   guile/Makefile
623   guile/modules/Makefile
624   guile/src/Makefile
625   guile/tests/Makefile
626   lib/Makefile
627   lib/accelerated/Makefile
628   lib/accelerated/x86/Makefile
629   lib/algorithms/Makefile
630   lib/auth/Makefile
631   lib/ext/Makefile
632   lib/extras/Makefile
633   lib/gnutls.pc
634   lib/includes/Makefile
635   lib/includes/gnutls/gnutls.h
636   lib/minitasn1/Makefile
637   lib/nettle/Makefile
638   lib/opencdk/Makefile
639   lib/openpgp/Makefile
640   lib/x509/Makefile
641   po/Makefile.in
642   src/Makefile
643   src/crywrap/Makefile
644   tests/Makefile
645   tests/cert-tests/Makefile
646   tests/dsa/Makefile
647   tests/dtls/Makefile
648   tests/srp/Makefile
649   tests/ecdsa/Makefile
650   tests/key-id/Makefile
651   tests/openpgp-certs/Makefile
652   tests/pkcs1-padding/Makefile
653   tests/pkcs12-decode/Makefile
654   tests/pkcs8-decode/Makefile
655   tests/rsa-md5-collision/Makefile
656   tests/safe-renegotiation/Makefile
657   tests/scripts/Makefile
658   tests/sha2/Makefile
659   tests/slow/Makefile
660   tests/suite/Makefile
661   tests/userid/Makefile
662 ])
663
664 AC_OUTPUT
665
666 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
667 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
668 AC_MSG_NOTICE([summary of build options:
669
670   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
671   Host/Target system:   ${host}
672   Build system:         ${build}
673   Install prefix:       ${prefix}
674   Compiler:             ${CC}
675   CFlags:               ${CFLAGS}
676   Library types:        Shared=${enable_shared}, Static=${enable_static}
677 ])
678
679 AC_MSG_NOTICE([External hardware support:
680
681   /dev/crypto:          $enable_cryptodev
682   Hardware accel:       $hw_accel
683   PKCS#11 support:      $with_p11_kit
684   TPM support:          $with_tpm
685 ])
686
687 AC_MSG_NOTICE([Optional features:
688 (note that included applications might not compile properly
689 if features are disabled)
690
691   DTLS-SRTP support:    $ac_enable_srtp
692   ALPN support:         $ac_enable_alpn
693   OCSP support:         $ac_enable_ocsp
694   OpenPGP support:      $ac_enable_openpgp
695   SRP support:          $ac_enable_srp
696   PSK support:          $ac_enable_psk
697   DHE support:          $ac_enable_dhe
698   ECDHE support:        $ac_enable_ecdhe
699   Anon auth support:    $ac_enable_anon
700   Heartbeat support:    $ac_enable_heartbeat
701   RSA-EXPORT compat:    $ac_enable_rsa_export
702   Unicode support:      $ac_have_unicode
703 ])
704
705 AC_MSG_NOTICE([Optional applications:
706
707   crywrap app:          $libidn
708   libopts flags:        ${LIBOPTS_LDADD}
709 ])
710
711 AC_MSG_NOTICE([Optional libraries:
712
713   Guile wrappers:       $opt_guile_bindings
714   C++ library:          $use_cxx
715   DANE library:         $enable_dane
716   OpenSSL compat:       $enable_openssl
717 ])
718
719 AC_MSG_NOTICE([System files:
720
721   Trust store pkcs:     $with_default_trust_store_pkcs11
722   Trust store file:     $with_default_trust_store_file
723   CRL file:             $with_default_crl_file
724   DNSSEC root key file: $unbound_root_key_file
725 ])
726
727 if test ! -f "$unbound_root_key_file"; then
728 AC_MSG_WARN([[
729 *** 
730 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
731 *** This file is needed for the verification of DNSSEC responses.
732 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
733 *** to generate or update it.
734 *** ]])
735 fi