Added support for getentropy() and reworked getrandom support
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.4.0], [bugs@gnutls.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 subdir-objects no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 PKG_PROG_PKG_CONFIG
39 AC_PROG_CC
40 gl_EARLY
41 ggl_EARLY
42 AM_PROG_AS
43 AM_PROG_AR
44 AC_PROG_CXX
45 AM_PROG_CC_C_O
46 AC_PROG_YACC
47 AC_PROG_SED
48 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
49
50 if test x"$AUTOGEN" = "x/bin/true"; then
51   AC_MSG_WARN([[
52 ***
53 *** autogen not found. Will not link against libopts.
54 *** ]])
55 enable_local_libopts=yes
56 fi
57
58 # For includes/gnutls/gnutls.h.in.
59 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
60 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
61 AC_SUBST(PATCH_VERSION, [[`echo $PACKAGE_VERSION | sed 's/.*\..*\.\([0-9]*\).*/\1/g'`]])
62 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
63
64 touch suppressions.valgrind
65 dnl C and C++ capabilities
66 AC_C_INLINE
67 AC_HEADER_STDC
68
69 # For the C++ code
70 AC_ARG_ENABLE(cxx,
71   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
72     use_cxx=$enableval, use_cxx=yes)
73 if test "$use_cxx" != "no"; then
74   AC_LANG_PUSH(C++)
75   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
76   AC_LANG_POP(C++)
77 fi
78 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
79 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
80
81 dnl Detect windows build
82 use_accel=yes
83 case "$host" in
84   *mingw32* | *mingw64*)
85     have_win=yes
86   ;;
87   *darwin*)
88     have_macosx=yes
89   ;;
90   *solaris*)
91     use_accel=no
92     AC_MSG_WARN([[
93 ***
94 *** In solaris hardware acceleration is disabled by default due to issues
95 *** with the assembler. Use --enable-hardware-acceleration to enable it.
96 *** ]])
97   ;;
98   *)
99     have_elf=yes
100   ;;
101 esac
102
103 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
104 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
105 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
106
107 dnl Hardware Acceleration
108 AC_ARG_ENABLE(hardware-acceleration,
109   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
110     use_accel=$enableval)
111 hw_accel=none
112
113
114 use_padlock=no
115 if test "$use_accel" != "no"; then
116 case $host_cpu in
117   i?86 | x86_64 | amd64)
118       AC_CHECK_HEADERS(cpuid.h)
119       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
120         hw_accel="x86-64"
121       else
122         hw_accel="x86"
123       fi
124       use_padlock=yes
125   ;;
126   *)
127   ;;
128 esac
129
130 fi
131
132 AC_ARG_ENABLE(padlock,
133   AS_HELP_STRING([--disable-padlock], [unconditionally disable padlock acceleration]),
134     use_padlock=$enableval)
135
136 if test "$use_padlock" != "no"; then
137     AC_DEFINE([ENABLE_PADLOCK], 1, [Enable padlock acceleration])
138     AC_SUBST([ENABLE_PADLOCK])
139 fi
140 AM_CONDITIONAL(ENABLE_PADLOCK, test "$use_padlock" = "yes")
141 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
142 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
143 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
144 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
145 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
146
147 dnl check for getrandom()
148 enable_getrandom=no
149 AC_MSG_CHECKING([for getrandom])
150 AC_LINK_IFELSE([AC_LANG_PROGRAM([
151            #include <linux/random.h>],[
152                    getrandom(0, 0, 0);
153                   ])],
154                   [AC_MSG_RESULT(yes)
155                    AC_DEFINE([HAVE_LINUX_GETRANDOM], 1, [Enable the Linux getrandom function])
156                    enable_getrandom=getrandom],
157                   [AC_MSG_RESULT(no)])
158
159 AC_MSG_CHECKING([for getentropy])
160 AC_LINK_IFELSE([AC_LANG_PROGRAM([
161            #include <unistd.h>],[
162                    getentropy(0, 0);
163                   ])],
164                   [AC_MSG_RESULT(yes)
165                    AC_DEFINE([HAVE_GETENTROPY], 1, [Enable the OpenBSD getentropy function])
166                    enable_getrandom=getentropy],
167                   [AC_MSG_RESULT(no)])
168
169 dnl Try the hooks.m4
170 LIBGNUTLS_HOOKS
171 LIBGNUTLS_EXTRA_HOOKS
172
173 AC_ARG_ENABLE(doc,
174   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
175     enable_doc=$enableval, enable_doc=yes)
176 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
177
178 AC_ARG_ENABLE(tests,
179   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
180     enable_tests=$enableval, enable_tests=yes)
181 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
182
183 GTK_DOC_CHECK(1.1)
184 AM_GNU_GETTEXT([external])
185 AM_GNU_GETTEXT_VERSION([0.18])
186
187 AC_C_BIGENDIAN
188
189 dnl No fork on MinGW, disable some self-tests until we fix them.
190 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
191 AC_CHECK_FUNCS([fork inet_ntop inet_pton getrusage getpwuid_r nanosleep daemon getpid clock_gettime iconv localtime vasprintf],,)
192 if test "$ac_cv_func_vasprintf" != "yes";then
193   AC_MSG_CHECKING([for va_copy])
194   AC_LINK_IFELSE([AC_LANG_PROGRAM([
195         #include <stdarg.h>
196         va_list a;],[
197         va_list b;
198         va_copy(b,a);
199         va_end(b);])],
200         [AC_DEFINE(HAVE_VA_COPY, 1, [Have va_copy()])
201         AC_MSG_RESULT(va_copy)],
202         [AC_LINK_IFELSE([AC_LANG_PROGRAM([
203                 #include <stdarg.h>
204                 va_list a;],[
205                 va_list b;
206                 __va_copy(b,a);
207                 va_end(b);])],
208                 [AC_DEFINE(HAVE___VA_COPY, 1, [Have __va_copy()])
209                 AC_MSG_RESULT(__va_copy)],
210                 [AC_MSG_RESULT(no)
211                 AC_MSG_ERROR([Your system lacks vasprintf() and va_copy()])])
212         ])
213 fi
214
215 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
216
217 AC_CHECK_FUNCS([pthread_atfork __register_atfork],,)
218
219 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
220 #include <signal.h>
221 ], [timer_create (0,0,0);])
222
223 if test "$have_win" != "yes";then
224   AC_CHECK_FUNCS([pthread_mutex_lock],,)
225   if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
226     AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
227   fi
228 fi
229
230 if test "$ac_cv_func_nanosleep" != "yes";then
231   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
232   gnutls_needs_librt=yes
233 fi
234
235 if test "$ac_cv_func_inet_pton" != "yes";then
236   AC_LIB_HAVE_LINKFLAGS(nsl,, [#include <arpa/inet.h>], [inet_pton(0,0,0);])
237 fi
238
239 if test "$ac_cv_func_clock_gettime" != "yes";then
240   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [clock_gettime (0, 0);])
241   gnutls_needs_librt=yes
242 fi
243
244 ac_have_unicode=no
245 if test "$ac_cv_func_iconv" != "yes";then
246   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
247   if test "$HAVE_LIBICONV" = "yes";then
248     ac_have_unicode=yes
249   fi
250 else
251   ac_have_unicode=yes
252 fi
253
254 if test "$ac_have_unicode" != "yes";then
255   if test "$have_win" = "yes";then
256     ac_have_unicode=yes
257   fi
258 fi
259
260 dnl Note that g*l_INIT are run after we check for library capabilities,
261 dnl to prevent issues from caching lib dependencies. See discussion
262 dnl in https://bugs.gentoo.org/show_bug.cgi?id=494940 and
263 dnl http://gnu-autoconf.7623.n7.nabble.com/Correct-way-to-check-for-clock-gettime-td12276.html
264 gl_INIT
265 ggl_INIT
266
267 dnl GCC warnings to enable
268
269 AC_ARG_ENABLE([gcc-warnings],
270   [AS_HELP_STRING([--disable-gcc-warnings],
271                   [turn off lots of GCC warnings (for developers)])],
272   [case $enableval in
273      yes|no) ;;
274      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
275    esac
276    gl_gcc_warnings=$enableval],
277   [gl_gcc_warnings=yes]
278 )
279
280 if test "$gl_gcc_warnings" = yes; then
281   gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])
282
283   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
284   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
285   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
286   nw="$nw -Wtraditional"            # Warns on #elif which we use often
287   nw="$nw -Wpadded"                 # Our structs are not padded
288   nw="$nw -Wtraditional-conversion" # Too many warnings for now
289   nw="$nw -Wswitch-default"         # Too many warnings for now
290   nw="$nw -Wformat-y2k"             # Too many warnings for now
291   nw="$nw -Woverlength-strings"     # We use some in tests/
292   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
293   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
294   nw="$nw -Wstrict-overflow"
295   nw="$nw -Wmissing-noreturn"
296   nw="$nw -Winline"                 # Too compiler dependent
297   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
298   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
299   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
300   nw="$nw -Wstack-protector"        # Some functions cannot be protected
301   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
302
303   gl_MANYWARN_ALL_GCC([ws])
304   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
305   for w in $ws; do
306     gl_WARN_ADD([$w])
307   done
308
309   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
310   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
311   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
312   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
313   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
314   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
315   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
316   gl_WARN_ADD([-fdiagnostics-show-option])
317 fi
318
319 AC_SUBST([WERROR_CFLAGS])
320 AC_SUBST([WSTACK_CFLAGS])
321 AC_SUBST([WARN_CFLAGS])
322
323 dnl Programs for compilation or development
324 AC_PROG_LN_S
325 LT_INIT([disable-static,win32-dll,shared])
326
327
328
329 AC_ARG_ENABLE(self-checks,
330   AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),
331     enable_self_checks=$enableval, enable_self_checks=no)
332
333 AC_ARG_ENABLE(fips140-mode,
334   AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),
335     enable_fips=$enableval, enable_fips=no)
336 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")
337 if [ test "$enable_fips" = "yes" ];then
338   AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])
339   if test "x$HAVE_LIBDL" = "xyes";then
340     enable_self_checks=yes
341
342     AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])
343
344     AC_SUBST([FIPS140_LIBS], $LIBDL)
345   else
346     enable_fips=no
347     AC_MSG_WARN([[
348 *** 
349 *** This system is not supported in FIPS140 mode.
350 *** libdl and dladdr() are required.
351 *** ]])
352   fi
353 fi
354
355 PKG_CHECK_MODULES(LIBIDN, libidn >= 0.5.6, [with_libidn=yes], [with_libidn=no])
356 if test "$with_libidn" != "no";then
357         AC_DEFINE([HAVE_LIBIDN], 1, [Build IDNA support])
358         if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
359                 GNUTLS_REQUIRES_PRIVATE="Requires.private: libidn"
360         else
361                 GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, libidn"
362         fi
363 else
364         with_libidn=no
365         AC_MSG_WARN([[
366 *** 
367 *** libidn was not found. IDNA support will be disabled.
368 *** ]])
369 fi
370
371 AM_CONDITIONAL(HAVE_LIBIDN, test "$with_libidn" != "no")
372
373 AC_ARG_ENABLE(non-suiteb-curves,
374   AS_HELP_STRING([--disable-non-suiteb-curves], [disable curves not in SuiteB]),
375     enable_non_suiteb=$enableval, enable_non_suiteb=yes)
376 if [ test "$enable_non_suiteb" = "yes" ];then
377   AC_DEFINE([ENABLE_NON_SUITEB_CURVES], 1, [Enable all curves])
378 fi
379
380 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")
381 if [ test "$enable_self_checks" = "yes" ];then
382    AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])
383 fi
384
385 AC_MSG_CHECKING([whether to build libdane])
386 AC_ARG_ENABLE(libdane,
387     AS_HELP_STRING([--disable-libdane],
388                    [disable the built of libdane]),
389     enable_dane=$enableval, enable_dane=yes)
390 AC_MSG_RESULT($enable_dane)
391
392 if test "$enable_dane" != "no"; then
393     LIBS="$oldlibs -lunbound"
394     AC_MSG_CHECKING([for unbound library])
395     AC_LINK_IFELSE([AC_LANG_PROGRAM([
396                    #include <unbound.h>],[
397                    struct ub_ctx* ctx;
398                    ctx = ub_ctx_create();])],
399                   [AC_MSG_RESULT(yes)
400                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
401                    AC_SUBST([UNBOUND_CFLAGS], [])
402                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
403                    enable_dane=yes],
404                   [AC_MSG_RESULT(no)
405                    AC_MSG_WARN([[
406 *** 
407 *** libunbound was not found. Libdane will not be built.
408 *** ]])
409                   enable_dane=no])
410     LIBS="$oldlibs"
411 fi
412
413 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
414
415 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
416                                  [specify the unbound root key file]),
417             unbound_root_key_file="$withval", 
418 if test "$have_win" = yes; then
419     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
420 else
421     if test -f /var/lib/unbound/root.key;then
422         unbound_root_key_file="/var/lib/unbound/root.key"
423     else
424         unbound_root_key_file="/etc/unbound/root.key"
425     fi
426 fi
427 )
428
429 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
430   ["$unbound_root_key_file"], [The DNSSEC root key file])
431
432 AC_ARG_WITH(system-priority-file, AS_HELP_STRING([--with-system-priority-file],
433                                  [specify the system priority file]),
434             system_priority_file="$withval", 
435 system_priority_file="/etc/gnutls/default-priorities"
436 )
437
438 AC_DEFINE_UNQUOTED([SYSTEM_PRIORITY_FILE],
439   ["$system_priority_file"], [The system priority file])
440
441
442 dnl Check for p11-kit
443 P11_KIT_MINIMUM=0.20.7
444 AC_ARG_WITH(p11-kit,
445         AS_HELP_STRING([--without-p11-kit],
446                 [Build without p11-kit and PKCS#11 support]))
447 if test "$with_p11_kit" != "no"; then
448         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
449         if test "$with_p11_kit" != "no";then
450                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
451                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
452                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
453                 else
454                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
455                 fi
456         else
457                 with_p11_kit=no
458                 AC_MSG_ERROR([[
459 *** 
460 *** p11-kit >= $P11_KIT_MINIMUM was not found. To disable PKCS #11 support 
461 *** use --without-p11-kit, otherwise you may get p11-kit from
462 *** http://p11-glue.freedesktop.org/p11-kit.html
463 *** ]])
464         fi
465 fi
466
467 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
468
469 AC_ARG_WITH(tpm,
470         AS_HELP_STRING([--without-tpm],
471                 [Disable TPM (trousers) support.]),
472                 [with_tpm=$withval], [with_tpm=yes])
473 if test "$with_tpm" != "no"; then
474     LIBS="$oldlibs -ltspi"
475     AC_MSG_CHECKING([for tss library])
476     AC_LINK_IFELSE([AC_LANG_PROGRAM([
477                    #include <trousers/tss.h>
478                    #include <trousers/trousers.h>],[
479                    int err = Tspi_Context_Create((void *)0);
480                    Trspi_Error_String(err);])],
481                   [AC_MSG_RESULT(yes)
482                    AC_SUBST([TSS_LIBS], [-ltspi])
483                    AC_SUBST([TSS_CFLAGS], [])
484                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
485                    with_tpm=yes],
486                   [AC_MSG_RESULT(no)
487                    AC_MSG_WARN([[
488 *** 
489 *** trousers was not found. TPM support will be disabled.
490 *** ]])
491                   with_tpm=no])
492     LIBS="$oldlibs"
493 fi
494
495 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
496
497 LIBOPTS_CHECK([src/libopts])
498 if test "$NEED_LIBOPTS_DIR" = "true";then
499         dnl replace libopts-generated files with distributed backups, if present
500         missing_baks=
501         for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do
502                 nam=`echo $i|sed 's/.bak//g'`
503                 if test -f $i;then
504                         cp -f $i $nam
505                 else
506                         missing_baks=true
507                 fi
508         done
509         if test -z "$missing_baks"; then
510                 AC_SUBST([AUTOGEN], [/bin/true])
511         fi
512         enable_local_libopts=yes
513 else
514         enable_local_libopts=no
515 fi
516 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")
517
518 AC_CHECK_TYPE(ssize_t,
519   [
520     DEFINE_SSIZE_T="#include <sys/types.h>"
521     AC_SUBST(DEFINE_SSIZE_T)
522   ], [
523     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
524     DEFINE_SSIZE_T="typedef int ssize_t;"
525     AC_SUBST(DEFINE_SSIZE_T)
526   ], [
527     #include <sys/types.h>
528   ])
529
530 # For minitasn1.
531 AC_CHECK_SIZEOF(unsigned long int, 4)
532 AC_CHECK_SIZEOF(unsigned int, 4)
533
534 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
535                                  [disable zlib compression support]),
536             ac_zlib=$withval, ac_zlib=yes)
537 AC_MSG_CHECKING([whether to include zlib compression support])
538 if test x$ac_zlib != xno; then
539  AC_MSG_RESULT(yes)
540  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
541  if test x$ac_cv_libz != xyes; then
542    AC_MSG_WARN(
543 *** 
544 *** ZLIB was not found. You will not be able to use ZLIB compression.)
545  fi
546 else
547  AC_MSG_RESULT(no)
548 fi
549
550 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
551
552 if test x$ac_zlib != xno; then
553   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
554     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
555       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
556     else
557       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
558     fi
559   fi
560 fi
561 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
562
563
564
565 AC_ARG_WITH([default-trust-store-pkcs11],
566   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
567     [use the given pkcs11 uri as default trust store])])
568
569 if test "x$with_default_trust_store_pkcs11" != x; then
570   if test "x$with_p11_kit" = xno; then
571     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
572   fi
573   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
574     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
575 fi
576
577 AC_ARG_WITH([default-trust-store-dir],
578   [AS_HELP_STRING([--with-default-trust-store-dir=DIR],
579     [use the given directory as default trust store])])
580
581 if test "x$with_default_trust_store_dir" != x; then
582   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_DIR],
583     ["$with_default_trust_store_dir"], [use the given directory as default trust store])
584 fi
585
586 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
587 AC_ARG_WITH([default-trust-store-file],
588   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
589     [use the given file default trust store])], with_default_trust_store_file="$withval",
590   [if test "$build" = "$host" && test x$with_default_trust_store_pkcs11 = x && test x$with_default_trust_store_dir = x;then
591   for i in \
592     /etc/ssl/ca-bundle.pem \
593     /etc/ssl/certs/ca-certificates.crt \
594     /etc/pki/tls/cert.pem \
595     /usr/local/share/certs/ca-root-nss.crt \
596     /etc/ssl/cert.pem
597     do
598     if test -e "$i"; then
599       with_default_trust_store_file="$i"
600       break
601     fi
602   done
603   fi]
604 )
605
606 if test "$with_default_trust_store_file" = "no";then
607   with_default_trust_store_file=""
608 fi
609
610 AC_ARG_WITH([default-crl-file],
611   [AS_HELP_STRING([--with-default-crl-file=FILE],
612     [use the given CRL file as default])])
613
614 AC_ARG_WITH([default-blacklist-file],
615   [AS_HELP_STRING([--with-default-blacklist-file=FILE],
616     [use the given certificate blacklist file as default])])
617
618 if test "x$with_default_trust_store_file" != x; then
619   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
620     ["$with_default_trust_store_file"], [use the given file default trust store])
621 fi
622
623 if test "x$with_default_crl_file" != x; then
624   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
625     ["$with_default_crl_file"], [use the given CRL file])
626 fi
627
628 if test "x$with_default_blacklist_file" != x; then
629   AC_DEFINE_UNQUOTED([DEFAULT_BLACKLIST_FILE],
630     ["$with_default_blacklist_file"], [use the given certificate blacklist file])
631 fi
632
633 dnl Guile bindings.
634 opt_guile_bindings=yes
635 AC_MSG_CHECKING([whether building Guile bindings])
636 AC_ARG_ENABLE(guile,
637         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
638 opt_guile_bindings=$enableval)
639 AC_MSG_RESULT($opt_guile_bindings)
640
641 AC_ARG_WITH([guile-site-dir],
642   [AS_HELP_STRING([--with-guile-site-dir],
643      [use the given directory as the Guile site (use with care)])])
644
645 if test "$opt_guile_bindings" = "yes"; then
646    AC_MSG_RESULT([***
647 *** Detecting GNU Guile...
648 ])
649
650    AC_PATH_PROG([guile_snarf], [guile-snarf])
651    if test "x$guile_snarf" = "x"; then
652       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
653       opt_guile_bindings=no
654    else
655       GUILE_PROGS
656       GUILE_FLAGS
657
658       save_CFLAGS="$CFLAGS"
659       save_LIBS="$LIBS"
660       CFLAGS="$CFLAGS $GUILE_CFLAGS"
661       LIBS="$LIBS $GUILE_LDFLAGS"
662       AC_MSG_CHECKING([whether GNU Guile is recent enough])
663       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
664         [], [opt_guile_bindings=no])
665       CFLAGS="$save_CFLAGS"
666       LIBS="$save_LIBS"
667
668       if test "$opt_guile_bindings" = "yes"; then
669         AC_MSG_RESULT([yes])
670         case "x$with_guile_site_dir" in 
671              xno)
672                 # Use the default $(GUILE_SITE).
673                 GUILE_SITE_DIR
674                 ;;
675              x|xyes)
676                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
677                 # hack is used to allow `distcheck' to work (see
678                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
679                 GUILE_SITE="\$(datadir)/guile/site"
680                 AC_SUBST(GUILE_SITE)
681                 ;;
682              *)
683                 # Use the user-specified directory as $(GUILE_SITE).
684                 GUILE_SITE="$with_guile_site_dir"
685                 AC_SUBST(GUILE_SITE)
686                 ;;
687         esac
688         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
689         _gcc_cflags_save="$CFLAGS"
690         CFLAGS="${CFLAGS} -fgnu89-inline"
691         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
692                           gnu89_inline=yes, gnu89_inline=no)
693         AC_MSG_RESULT($gnu89_inline)
694         CFLAGS="$_gcc_cflags_save"
695
696         # Optional Guile functions.
697         save_CFLAGS="$CFLAGS"
698         save_LIBS="$LIBS"
699         CFLAGS="$CFLAGS $GUILE_CFLAGS"
700         LIBS="$LIBS $GUILE_LDFLAGS"
701         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
702         CFLAGS="$save_CFLAGS"
703         LIBS="$save_LIBS"
704
705         # The place where guile-gnutls.la will go.
706         AC_MSG_CHECKING([the Guile effective version])
707         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
708         AC_MSG_RESULT([$guile_effective_version])
709         guileextensiondir="$libdir/guile/$guile_effective_version"
710         AC_SUBST([guileextensiondir])
711       else
712         AC_MSG_RESULT([no])
713         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
714         opt_guile_bindings=no
715       fi
716    fi
717 fi
718 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
719
720 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
721 LIBGNUTLS_CFLAGS="-I${includedir}"
722 AC_SUBST(LIBGNUTLS_LIBS)
723 AC_SUBST(LIBGNUTLS_CFLAGS)
724
725 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")
726
727 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
728 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
729
730 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
731 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
732 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
733
734 dnl Crywrap dependencies
735    AC_MSG_RESULT([***
736 *** Checking dependencies for crywrap...
737 ])
738
739 crywrap=no
740
741 if test "$have_win" != "yes"; then
742
743 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
744
745 dnl **********************
746 dnl * Typedefs & co
747 dnl **********************
748 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
749 [AC_LANG_PROGRAM([#include <sys/types.h>
750 #include <signal.h>
751 ],
752                  [return *(signal (0, 0)) (0) == 1;])],
753                    [ac_cv_type_signal=int],
754                    [ac_cv_type_signal=void])])
755 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
756                     (`int' or `void').])
757
758 AC_FUNC_SELECT_ARGTYPES
759 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
760                 putenv regcomp scandir select socket strcasecmp strchr \
761                 strdup strerror strncasecmp strrchr strstr strtoul uname])
762
763 AC_ARG_ENABLE(crywrap,
764         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
765
766
767  if test "x$enable_crywrap" != "xno" ; then
768         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
769  fi
770
771  if test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no" && test "$with_libidn" != "no";then
772   crywrap=yes
773  fi
774
775 fi
776
777 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
778
779 dnl end of crywrap requirements
780
781 dnl Some variables needed in makefiles
782 YEAR=`date +%Y`
783 AC_SUBST([YEAR], $YEAR)
784
785 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
786 AC_CONFIG_FILES([
787   Makefile
788   doc/Makefile
789   doc/credentials/Makefile
790   doc/credentials/openpgp/Makefile
791   doc/credentials/srp/Makefile
792   doc/credentials/x509/Makefile
793   doc/cyclo/Makefile
794   doc/doxygen/Doxyfile
795   doc/examples/Makefile
796   doc/latex/Makefile
797   doc/manpages/Makefile
798   doc/reference/Makefile
799   doc/reference/version.xml
800   doc/scripts/Makefile
801   extra/Makefile
802   extra/includes/Makefile
803   libdane/Makefile
804   libdane/includes/Makefile
805   libdane/gnutls-dane.pc
806   gl/Makefile
807   gl/tests/Makefile
808   guile/Makefile
809   guile/modules/Makefile
810   guile/src/Makefile
811   guile/tests/Makefile
812   lib/Makefile
813   lib/accelerated/Makefile
814   lib/accelerated/x86/Makefile
815   lib/algorithms/Makefile
816   lib/auth/Makefile
817   lib/ext/Makefile
818   lib/extras/Makefile
819   lib/gnutls.pc
820   lib/includes/Makefile
821   lib/includes/gnutls/gnutls.h
822   lib/minitasn1/Makefile
823   lib/nettle/Makefile
824   lib/opencdk/Makefile
825   lib/openpgp/Makefile
826   lib/x509/Makefile
827   po/Makefile.in
828   src/Makefile
829   src/crywrap/Makefile
830   src/gl/Makefile
831   tests/Makefile
832   tests/cert-tests/Makefile
833   tests/dsa/Makefile
834   tests/dtls/Makefile
835   tests/srp/Makefile
836   tests/ecdsa/Makefile
837   tests/key-tests/Makefile
838   tests/openpgp-certs/Makefile
839   tests/pkcs1-padding/Makefile
840   tests/pkcs12-decode/Makefile
841   tests/pkcs8-decode/Makefile
842   tests/rsa-md5-collision/Makefile
843   tests/safe-renegotiation/Makefile
844   tests/scripts/Makefile
845   tests/sha2/Makefile
846   tests/slow/Makefile
847   tests/suite/Makefile
848   tests/userid/Makefile
849 ])
850
851 AC_OUTPUT
852
853 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
854 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
855 AC_MSG_NOTICE([summary of build options:
856
857   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
858   Host/Target system:   ${host}
859   Build system:         ${build}
860   Install prefix:       ${prefix}
861   Compiler:             ${CC}
862   CFlags:               ${CFLAGS}
863   Library types:        Shared=${enable_shared}, Static=${enable_static}
864   Local libopts:        ${enable_local_libopts}
865   Local libtasn1:       ${included_libtasn1}
866   Use nettle-mini:      ${mini_nettle}
867 ])
868
869 AC_MSG_NOTICE([External hardware support:
870
871   /dev/crypto:          $enable_cryptodev
872   Hardware accel:       $hw_accel
873   Padlock accel:        $use_padlock
874   getrandom variant:    $enable_getrandom
875   PKCS#11 support:      $with_p11_kit
876   TPM support:          $with_tpm
877 ])
878
879 AC_MSG_NOTICE([Optional features:
880 (note that included applications might not compile properly
881 if features are disabled)
882
883   DTLS-SRTP support:    $ac_enable_srtp
884   ALPN support:         $ac_enable_alpn
885   OCSP support:         $ac_enable_ocsp
886   Ses. ticket support:  $ac_enable_session_tickets
887   OpenPGP support:      $ac_enable_openpgp
888   SRP support:          $ac_enable_srp
889   PSK support:          $ac_enable_psk
890   DHE support:          $ac_enable_dhe
891   ECDHE support:        $ac_enable_ecdhe
892   RSA-EXPORT support:   $ac_enable_rsa_export
893   Anon auth support:    $ac_enable_anon
894   Heartbeat support:    $ac_enable_heartbeat
895   IDNA support:         $libidn
896   Unicode support:      $ac_have_unicode
897   Self checks:          $enable_self_checks
898   Non-SuiteB curves:    $enable_non_suiteb
899   FIPS140 mode:         $enable_fips
900 ])
901
902 AC_MSG_NOTICE([Optional applications:
903
904   crywrap app:          $crywrap
905 ])
906
907 AC_MSG_NOTICE([Optional libraries:
908
909   Guile wrappers:       $opt_guile_bindings
910   C++ library:          $use_cxx
911   DANE library:         $enable_dane
912   OpenSSL compat:       $enable_openssl
913 ])
914
915 AC_MSG_NOTICE([System files:
916
917   Trust store pkcs11:   $with_default_trust_store_pkcs11
918   Trust store dir:      $with_default_trust_store_dir
919   Trust store file:     $with_default_trust_store_file
920   Blacklist file:       $with_default_blacklist_file
921   CRL file:             $with_default_crl_file
922   Priority file:        $system_priority_file
923   DNSSEC root key file: $unbound_root_key_file
924 ])
925
926 if test ! -f "$unbound_root_key_file"; then
927 AC_MSG_WARN([[
928 *** 
929 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
930 *** This file is needed for the verification of DNSSEC responses.
931 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
932 *** to generate or update it.
933 *** ]])
934 fi