steal openconnect's vasprintf() implementation
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.4.0], [bugs@gnutls.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 subdir-objects no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 ggl_EARLY
41 AM_PROG_AS
42 AM_PROG_AR
43 AC_PROG_CXX
44 AM_PROG_CC_C_O
45 AC_PROG_YACC
46 AC_PROG_SED
47 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
48
49 if test x"$AUTOGEN" = "x/bin/true"; then
50   AC_MSG_WARN([[
51 ***
52 *** autogen not found. Will not link against libopts.
53 *** ]])
54 enable_local_libopts=yes
55 fi
56
57 # For includes/gnutls/gnutls.h.in.
58 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
59 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
60 AC_SUBST(PATCH_VERSION, [[`echo $PACKAGE_VERSION | sed 's/.*\..*\.\([0-9]*\).*/\1/g'`]])
61 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
62
63 touch suppressions.valgrind
64 dnl C and C++ capabilities
65 AC_C_INLINE
66 AC_HEADER_STDC
67
68 # For the C++ code
69 AC_ARG_ENABLE(cxx,
70   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
71     use_cxx=$enableval, use_cxx=yes)
72 if test "$use_cxx" != "no"; then
73   AC_LANG_PUSH(C++)
74   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
75   AC_LANG_POP(C++)
76 fi
77 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
78 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
79
80 dnl Detect windows build
81 case "$host" in
82   *mingw32* | *mingw64*)
83     have_win=yes
84   ;;
85   *darwin*)
86     have_macosx=yes
87   ;;
88   *)
89     have_elf=yes
90   ;;
91 esac
92
93 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
94 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
95 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
96
97 dnl Hardware Acceleration
98 AC_ARG_ENABLE(hardware-acceleration,
99   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
100     use_accel=$enableval, use_accel=yes)
101 hw_accel=none
102
103
104 if test "$use_accel" != "no"; then
105 case $host_cpu in
106   i?86 | x86_64 | amd64)
107       AC_CHECK_HEADERS(cpuid.h)
108       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
109         hw_accel="x86-64"
110       else
111         hw_accel="x86"
112       fi
113   ;;
114   *)
115   ;;
116 esac
117
118 fi
119
120 AC_ARG_ENABLE(padlock,
121   AS_HELP_STRING([--disable-padlock], [unconditionally disable padlock acceleration]),
122     use_padlock=$enableval, use_padlock=yes)
123
124 if test "$use_padlock" != "no"; then
125     AC_DEFINE([ENABLE_PADLOCK], 1, [Enable padlock acceleration])
126     AC_SUBST([ENABLE_PADLOCK])
127 fi
128 AM_CONDITIONAL(ENABLE_PADLOCK, test "$use_padlock" = "yes")
129 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
130 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
131 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
132 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
133 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
134
135
136 dnl Try the hooks.m4
137 LIBGNUTLS_HOOKS
138 LIBGNUTLS_EXTRA_HOOKS
139
140 AC_ARG_ENABLE(doc,
141   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
142     enable_doc=$enableval, enable_doc=yes)
143 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
144
145 AC_ARG_ENABLE(tests,
146   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
147     enable_tests=$enableval, enable_tests=yes)
148 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
149
150 GTK_DOC_CHECK(1.1)
151 AM_GNU_GETTEXT([external])
152 AM_GNU_GETTEXT_VERSION([0.18])
153
154 AC_C_BIGENDIAN
155
156 dnl No fork on MinGW, disable some self-tests until we fix them.
157 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
158 AC_CHECK_FUNCS([fork inet_ntop inet_pton getrusage getpwuid_r nanosleep daemon getpid clock_gettime iconv localtime vasprintf],,)
159 if test "$ac_cv_func_vasprintf" != "yes";then
160   AC_MSG_CHECKING([for va_copy])
161   AC_LINK_IFELSE([AC_LANG_PROGRAM([
162         #include <stdarg.h>
163         va_list a;],[
164         va_list b;
165         va_copy(b,a);
166         va_end(b);])],
167         [AC_DEFINE(HAVE_VA_COPY, 1, [Have va_copy()])
168         AC_MSG_RESULT(va_copy)],
169         [AC_LINK_IFELSE([AC_LANG_PROGRAM([
170                 #include <stdarg.h>
171                 va_list a;],[
172                 va_list b;
173                 __va_copy(b,a);
174                 va_end(b);])],
175                 [AC_DEFINE(HAVE___VA_COPY, 1, [Have __va_copy()])
176                 AC_MSG_RESULT(__va_copy)],
177                 [AC_MSG_RESULT(no)
178                 AC_MSG_ERROR([Your system lacks vasprintf() and va_copy()])])
179         ])
180 fi
181
182 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
183
184 AC_CHECK_FUNCS([pthread_atfork __register_atfork],,)
185
186 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
187 #include <signal.h>
188 ], [timer_create (0,0,0);])
189
190 if test "$have_win" != "yes";then
191   AC_CHECK_FUNCS([pthread_mutex_lock],,)
192   if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
193     AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
194   fi
195 fi
196
197 if test "$ac_cv_func_nanosleep" != "yes";then
198   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
199   gnutls_needs_librt=yes
200 fi
201
202 if test "$ac_cv_func_clock_gettime" != "yes";then
203   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [clock_gettime (0, 0);])
204   gnutls_needs_librt=yes
205 fi
206
207 ac_have_unicode=no
208 if test "$ac_cv_func_iconv" != "yes";then
209   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
210   if test "$HAVE_LIBICONV" = "yes";then
211     ac_have_unicode=yes
212   fi
213 else
214   ac_have_unicode=yes
215 fi
216
217 if test "$ac_have_unicode" != "yes";then
218   if test "$have_win" = "yes";then
219     ac_have_unicode=yes
220   fi
221 fi
222
223 dnl Note that g*l_INIT are run after we check for library capabilities,
224 dnl to prevent issues from caching lib dependencies. See discussion
225 dnl in https://bugs.gentoo.org/show_bug.cgi?id=494940 and
226 dnl http://gnu-autoconf.7623.n7.nabble.com/Correct-way-to-check-for-clock-gettime-td12276.html
227 gl_INIT
228 ggl_INIT
229
230 dnl GCC warnings to enable
231
232 AC_ARG_ENABLE([gcc-warnings],
233   [AS_HELP_STRING([--enable-gcc-warnings],
234                   [turn on lots of GCC warnings (for developers)])],
235   [case $enableval in
236      yes|no) ;;
237      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
238    esac
239    gl_gcc_warnings=$enableval],
240   [gl_gcc_warnings=no]
241 )
242
243 if test "$gl_gcc_warnings" = yes; then
244   gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])
245
246   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
247   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
248   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
249   nw="$nw -Wtraditional"            # Warns on #elif which we use often
250   nw="$nw -Wlogical-op"             # Too many false positives
251   nw="$nw -Wold-style-definition"   # 
252   nw="$nw -Wpadded"                 # Our structs are not padded
253   nw="$nw -Wunreachable-code"       # Too many false positives
254   nw="$nw -Wtraditional-conversion" # Too many warnings for now
255   nw="$nw -Wcast-qual"              # Too many warnings for now
256   nw="$nw -Waggregate-return"       # Too many warnings for now
257   nw="$nw -Wshadow"                 # Too many warnings for now
258   nw="$nw -Wswitch-default"         # Too many warnings for now
259   nw="$nw -Wswitch-enum"            # Too many warnings for now
260   nw="$nw -Wconversion"             # Too many warnings for now
261   nw="$nw -Wsign-conversion"        # Too many warnings for now
262   nw="$nw -Wformat-y2k"             # Too many warnings for now
263   nw="$nw -Woverlength-strings"     # We use some in tests/
264   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
265   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
266   nw="$nw -Wunsafe-loop-optimizations"
267   nw="$nw -Wstrict-overflow"
268   nw="$nw -Wmissing-noreturn"
269   nw="$nw -Winline"                 # Too compiler dependent
270   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
271   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
272   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
273   nw="$nw -Wstack-protector"        # Some functions cannot be protected
274   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
275
276   gl_MANYWARN_ALL_GCC([ws])
277   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
278   for w in $ws; do
279     gl_WARN_ADD([$w])
280   done
281
282   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
283   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
284   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
285   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
286   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
287   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
288   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
289   gl_WARN_ADD([-fdiagnostics-show-option])
290 fi
291
292 AC_SUBST([WERROR_CFLAGS])
293 AC_SUBST([WSTACK_CFLAGS])
294 AC_SUBST([WARN_CFLAGS])
295
296 dnl Programs for compilation or development
297 AC_PROG_LN_S
298 LT_INIT([disable-static,win32-dll,shared])
299
300
301
302 AC_ARG_ENABLE(self-checks,
303   AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),
304     enable_self_checks=$enableval, enable_self_checks=no)
305
306 AC_ARG_ENABLE(fips140-mode,
307   AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),
308     enable_fips=$enableval, enable_fips=no)
309 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")
310 if [ test "$enable_fips" = "yes" ];then
311   AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])
312   if test "x$HAVE_LIBDL" = "xyes";then
313     enable_self_checks=yes
314
315     AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])
316
317     AC_SUBST([FIPS140_LIBS], $LIBDL)
318   else
319     enable_fips=no
320     AC_MSG_WARN([[
321 *** 
322 *** This system is not supported in FIPS140 mode.
323 *** libdl and dladdr() are required.
324 *** ]])
325   fi
326 fi
327
328 PKG_CHECK_MODULES(LIBIDN, libidn >= 0.5.6, [with_libidn=yes], [with_libidn=no])
329 if test "$with_libidn" != "no";then
330         AC_DEFINE([HAVE_LIBIDN], 1, [Build IDNA support])
331         if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
332                 GNUTLS_REQUIRES_PRIVATE="Requires.private: libidn"
333         else
334                 GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, libidn"
335         fi
336 else
337         with_libidn=no
338         AC_MSG_WARN([[
339 *** 
340 *** libidn was not found. IDNA support will be disabled.
341 *** ]])
342 fi
343
344 AM_CONDITIONAL(HAVE_LIBIDN, test "$with_libidn" != "no")
345
346 AC_ARG_ENABLE(non-suiteb-curves,
347   AS_HELP_STRING([--disable-non-suiteb-curves], [disable curves not in SuiteB]),
348     enable_non_suiteb=$enableval, enable_non_suiteb=yes)
349 if [ test "$enable_non_suiteb" = "yes" ];then
350   AC_DEFINE([ENABLE_NON_SUITEB_CURVES], 1, [Enable all curves])
351 fi
352
353 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")
354 if [ test "$enable_self_checks" = "yes" ];then
355    AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])
356 fi
357
358 AC_MSG_CHECKING([whether to build libdane])
359 AC_ARG_ENABLE(libdane,
360     AS_HELP_STRING([--disable-libdane],
361                    [disable the built of libdane]),
362     enable_dane=$enableval, enable_dane=yes)
363 AC_MSG_RESULT($enable_dane)
364
365 if test "$enable_dane" != "no"; then
366     LIBS="$oldlibs -lunbound"
367     AC_MSG_CHECKING([for unbound library])
368     AC_LINK_IFELSE([AC_LANG_PROGRAM([
369                    #include <unbound.h>],[
370                    struct ub_ctx* ctx;
371                    ctx = ub_ctx_create();])],
372                   [AC_MSG_RESULT(yes)
373                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
374                    AC_SUBST([UNBOUND_CFLAGS], [])
375                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
376                    enable_dane=yes],
377                   [AC_MSG_RESULT(no)
378                    AC_MSG_WARN([[
379 *** 
380 *** libunbound was not found. Libdane will not be built.
381 *** ]])
382                   enable_dane=no])
383     LIBS="$oldlibs"
384 fi
385
386 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
387
388 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
389                                  [specify the unbound root key file]),
390             unbound_root_key_file="$withval", 
391 if test "$have_win" = yes; then
392     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
393 else
394     if test -f /var/lib/unbound/root.key;then
395         unbound_root_key_file="/var/lib/unbound/root.key"
396     else
397         unbound_root_key_file="/etc/unbound/root.key"
398     fi
399 fi
400 )
401
402 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
403   ["$unbound_root_key_file"], [The DNSSEC root key file])
404
405 AC_ARG_WITH(system-priority-file, AS_HELP_STRING([--with-system-priority-file],
406                                  [specify the system priority file]),
407             system_priority_file="$withval", 
408 system_priority_file="/etc/gnutls/default-priorities"
409 )
410
411 AC_DEFINE_UNQUOTED([SYSTEM_PRIORITY_FILE],
412   ["$system_priority_file"], [The system priority file])
413
414 dnl Check for p11-kit
415 P11_KIT_MINIMUM=0.20.0
416 AC_ARG_WITH(p11-kit,
417         AS_HELP_STRING([--without-p11-kit],
418                 [Build without p11-kit and PKCS#11 support]))
419 if test "$with_p11_kit" != "no"; then
420         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
421         if test "$with_p11_kit" != "no";then
422                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
423                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
424                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
425                 else
426                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
427                 fi
428         else
429                 with_p11_kit=no
430                 AC_MSG_WARN([[
431 *** 
432 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
433 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
434 *** ]])
435         fi
436 fi
437
438 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
439
440 AC_ARG_WITH(tpm,
441         AS_HELP_STRING([--without-tpm],
442                 [Disable TPM (trousers) support.]),
443                 [with_tpm=$withval], [with_tpm=yes])
444 if test "$with_tpm" != "no"; then
445     LIBS="$oldlibs -ltspi"
446     AC_MSG_CHECKING([for tss library])
447     AC_LINK_IFELSE([AC_LANG_PROGRAM([
448                    #include <trousers/tss.h>
449                    #include <trousers/trousers.h>],[
450                    int err = Tspi_Context_Create((void *)0);
451                    Trspi_Error_String(err);])],
452                   [AC_MSG_RESULT(yes)
453                    AC_SUBST([TSS_LIBS], [-ltspi])
454                    AC_SUBST([TSS_CFLAGS], [])
455                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
456                    with_tpm=yes],
457                   [AC_MSG_RESULT(no)
458                    AC_MSG_WARN([[
459 *** 
460 *** trousers was not found. TPM support will be disabled.
461 *** ]])
462                   with_tpm=no])
463     LIBS="$oldlibs"
464 fi
465
466 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
467
468 LIBOPTS_CHECK([src/libopts])
469 if test "$NEED_LIBOPTS_DIR" = "true";then
470         dnl replace libopts-generated files with distributed backups, if present
471         missing_baks=
472         for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do
473                 nam=`echo $i|sed 's/.bak//g'`
474                 if test -f $i;then
475                         cp -f $i $nam
476                 else
477                         missing_baks=true
478                 fi
479         done
480         if test -z "$missing_baks"; then
481                 AC_SUBST([AUTOGEN], [/bin/true])
482         fi
483         enable_local_libopts=yes
484 else
485         enable_local_libopts=no
486 fi
487 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")
488
489 AC_CHECK_TYPE(ssize_t,
490   [
491     DEFINE_SSIZE_T="#include <sys/types.h>"
492     AC_SUBST(DEFINE_SSIZE_T)
493   ], [
494     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
495     DEFINE_SSIZE_T="typedef int ssize_t;"
496     AC_SUBST(DEFINE_SSIZE_T)
497   ], [
498     #include <sys/types.h>
499   ])
500
501 # For minitasn1.
502 AC_CHECK_SIZEOF(unsigned long int, 4)
503 AC_CHECK_SIZEOF(unsigned int, 4)
504
505 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
506                                  [disable zlib compression support]),
507             ac_zlib=$withval, ac_zlib=yes)
508 AC_MSG_CHECKING([whether to include zlib compression support])
509 if test x$ac_zlib != xno; then
510  AC_MSG_RESULT(yes)
511  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
512  if test x$ac_cv_libz != xyes; then
513    AC_MSG_WARN(
514 *** 
515 *** ZLIB was not found. You will not be able to use ZLIB compression.)
516  fi
517 else
518  AC_MSG_RESULT(no)
519 fi
520
521 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
522
523 if test x$ac_zlib != xno; then
524   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
525     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
526       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
527     else
528       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
529     fi
530   fi
531 fi
532 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
533
534
535
536 AC_ARG_WITH([default-trust-store-pkcs11],
537   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
538     [use the given pkcs11 uri as default trust store])])
539
540 if test "x$with_default_trust_store_pkcs11" != x; then
541   if test "x$with_p11_kit" = xno; then
542     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
543   fi
544   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
545     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
546 fi
547
548 AC_ARG_WITH([default-trust-store-dir],
549   [AS_HELP_STRING([--with-default-trust-store-dir=DIR],
550     [use the given directory as default trust store])])
551
552 if test "x$with_default_trust_store_dir" != x; then
553   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_DIR],
554     ["$with_default_trust_store_dir"], [use the given directory as default trust store])
555 fi
556
557 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
558 AC_ARG_WITH([default-trust-store-file],
559   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
560     [use the given file default trust store])], with_default_trust_store_file="$withval",
561   [if test "$build" = "$host" && test x$with_default_trust_store_pkcs11 = x && test x$with_default_trust_store_dir = x;then
562   for i in \
563     /etc/ssl/ca-bundle.pem \
564     /etc/ssl/certs/ca-certificates.crt \
565     /etc/pki/tls/cert.pem \
566     /usr/local/share/certs/ca-root-nss.crt \
567     /etc/ssl/cert.pem
568     do
569     if test -e "$i"; then
570       with_default_trust_store_file="$i"
571       break
572     fi
573   done
574   fi]
575 )
576
577 if test "$with_default_trust_store_file" = "no";then
578   with_default_trust_store_file=""
579 fi
580
581 AC_ARG_WITH([default-crl-file],
582   [AS_HELP_STRING([--with-default-crl-file=FILE],
583     [use the given CRL file as default])])
584
585 AC_ARG_WITH([default-blacklist-file],
586   [AS_HELP_STRING([--with-default-blacklist-file=FILE],
587     [use the given certificate blacklist file as default])])
588
589 if test "x$with_default_trust_store_file" != x; then
590   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
591     ["$with_default_trust_store_file"], [use the given file default trust store])
592 fi
593
594 if test "x$with_default_crl_file" != x; then
595   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
596     ["$with_default_crl_file"], [use the given CRL file])
597 fi
598
599 if test "x$with_default_blacklist_file" != x; then
600   AC_DEFINE_UNQUOTED([DEFAULT_BLACKLIST_FILE],
601     ["$with_default_blacklist_file"], [use the given certificate blacklist file])
602 fi
603
604 dnl Guile bindings.
605 opt_guile_bindings=yes
606 AC_MSG_CHECKING([whether building Guile bindings])
607 AC_ARG_ENABLE(guile,
608         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
609 opt_guile_bindings=$enableval)
610 AC_MSG_RESULT($opt_guile_bindings)
611
612 AC_ARG_WITH([guile-site-dir],
613   [AS_HELP_STRING([--with-guile-site-dir],
614      [use the given directory as the Guile site (use with care)])])
615
616 if test "$opt_guile_bindings" = "yes"; then
617    AC_MSG_RESULT([***
618 *** Detecting GNU Guile...
619 ])
620
621    AC_PATH_PROG([guile_snarf], [guile-snarf])
622    if test "x$guile_snarf" = "x"; then
623       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
624       opt_guile_bindings=no
625    else
626       GUILE_PROGS
627       GUILE_FLAGS
628
629       save_CFLAGS="$CFLAGS"
630       save_LIBS="$LIBS"
631       CFLAGS="$CFLAGS $GUILE_CFLAGS"
632       LIBS="$LIBS $GUILE_LDFLAGS"
633       AC_MSG_CHECKING([whether GNU Guile is recent enough])
634       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
635         [], [opt_guile_bindings=no])
636       CFLAGS="$save_CFLAGS"
637       LIBS="$save_LIBS"
638
639       if test "$opt_guile_bindings" = "yes"; then
640         AC_MSG_RESULT([yes])
641         case "x$with_guile_site_dir" in 
642              xno)
643                 # Use the default $(GUILE_SITE).
644                 GUILE_SITE_DIR
645                 ;;
646              x|xyes)
647                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
648                 # hack is used to allow `distcheck' to work (see
649                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
650                 GUILE_SITE="\$(datadir)/guile/site"
651                 AC_SUBST(GUILE_SITE)
652                 ;;
653              *)
654                 # Use the user-specified directory as $(GUILE_SITE).
655                 GUILE_SITE="$with_guile_site_dir"
656                 AC_SUBST(GUILE_SITE)
657                 ;;
658         esac
659         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
660         _gcc_cflags_save="$CFLAGS"
661         CFLAGS="${CFLAGS} -fgnu89-inline"
662         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
663                           gnu89_inline=yes, gnu89_inline=no)
664         AC_MSG_RESULT($gnu89_inline)
665         CFLAGS="$_gcc_cflags_save"
666
667         # Optional Guile functions.
668         save_CFLAGS="$CFLAGS"
669         save_LIBS="$LIBS"
670         CFLAGS="$CFLAGS $GUILE_CFLAGS"
671         LIBS="$LIBS $GUILE_LDFLAGS"
672         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
673         CFLAGS="$save_CFLAGS"
674         LIBS="$save_LIBS"
675
676         # The place where guile-gnutls.la will go.
677         AC_MSG_CHECKING([the Guile effective version])
678         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
679         AC_MSG_RESULT([$guile_effective_version])
680         guileextensiondir="$libdir/guile/$guile_effective_version"
681         AC_SUBST([guileextensiondir])
682       else
683         AC_MSG_RESULT([no])
684         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
685         opt_guile_bindings=no
686       fi
687    fi
688 fi
689 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
690
691 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
692 LIBGNUTLS_CFLAGS="-I${includedir}"
693 AC_SUBST(LIBGNUTLS_LIBS)
694 AC_SUBST(LIBGNUTLS_CFLAGS)
695
696 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")
697
698 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
699 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
700
701 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
702 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
703 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
704
705 dnl Crywrap dependencies
706    AC_MSG_RESULT([***
707 *** Checking dependencies for crywrap...
708 ])
709
710 crywrap=no
711
712 if test "$have_win" != "yes"; then
713
714 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
715
716 dnl **********************
717 dnl * Typedefs & co
718 dnl **********************
719 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
720 [AC_LANG_PROGRAM([#include <sys/types.h>
721 #include <signal.h>
722 ],
723                  [return *(signal (0, 0)) (0) == 1;])],
724                    [ac_cv_type_signal=int],
725                    [ac_cv_type_signal=void])])
726 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
727                     (`int' or `void').])
728
729 AC_FUNC_SELECT_ARGTYPES
730 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
731                 putenv regcomp scandir select socket strcasecmp strchr \
732                 strdup strerror strncasecmp strrchr strstr strtoul uname])
733
734 AC_ARG_ENABLE(crywrap,
735         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
736
737
738  if test "x$enable_crywrap" != "xno" ; then
739         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
740  fi
741
742  if test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
743   crywrap=yes
744  fi
745
746 fi
747
748 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
749
750 dnl end of crywrap requirements
751
752 dnl Some variables needed in makefiles
753 YEAR=`date +%Y`
754 AC_SUBST([YEAR], $YEAR)
755
756 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
757 AC_CONFIG_FILES([
758   Makefile
759   doc/Makefile
760   doc/credentials/Makefile
761   doc/credentials/openpgp/Makefile
762   doc/credentials/srp/Makefile
763   doc/credentials/x509/Makefile
764   doc/cyclo/Makefile
765   doc/doxygen/Doxyfile
766   doc/examples/Makefile
767   doc/latex/Makefile
768   doc/manpages/Makefile
769   doc/reference/Makefile
770   doc/reference/version.xml
771   doc/scripts/Makefile
772   extra/Makefile
773   extra/includes/Makefile
774   libdane/Makefile
775   libdane/includes/Makefile
776   libdane/gnutls-dane.pc
777   gl/Makefile
778   gl/tests/Makefile
779   guile/Makefile
780   guile/modules/Makefile
781   guile/src/Makefile
782   guile/tests/Makefile
783   lib/Makefile
784   lib/accelerated/Makefile
785   lib/accelerated/x86/Makefile
786   lib/algorithms/Makefile
787   lib/auth/Makefile
788   lib/ext/Makefile
789   lib/extras/Makefile
790   lib/gnutls.pc
791   lib/includes/Makefile
792   lib/includes/gnutls/gnutls.h
793   lib/minitasn1/Makefile
794   lib/nettle/Makefile
795   lib/opencdk/Makefile
796   lib/openpgp/Makefile
797   lib/x509/Makefile
798   po/Makefile.in
799   src/Makefile
800   src/crywrap/Makefile
801   src/gl/Makefile
802   tests/Makefile
803   tests/cert-tests/Makefile
804   tests/dsa/Makefile
805   tests/dtls/Makefile
806   tests/srp/Makefile
807   tests/ecdsa/Makefile
808   tests/key-tests/Makefile
809   tests/openpgp-certs/Makefile
810   tests/pkcs1-padding/Makefile
811   tests/pkcs12-decode/Makefile
812   tests/pkcs8-decode/Makefile
813   tests/rsa-md5-collision/Makefile
814   tests/safe-renegotiation/Makefile
815   tests/scripts/Makefile
816   tests/sha2/Makefile
817   tests/slow/Makefile
818   tests/suite/Makefile
819   tests/userid/Makefile
820 ])
821
822 AC_OUTPUT
823
824 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
825 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
826 AC_MSG_NOTICE([summary of build options:
827
828   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
829   Host/Target system:   ${host}
830   Build system:         ${build}
831   Install prefix:       ${prefix}
832   Compiler:             ${CC}
833   CFlags:               ${CFLAGS}
834   Library types:        Shared=${enable_shared}, Static=${enable_static}
835   Local libopts:        ${enable_local_libopts}
836   Local libtasn1:       ${included_libtasn1}
837   Use nettle-mini:      ${mini_nettle}
838 ])
839
840 AC_MSG_NOTICE([External hardware support:
841
842   /dev/crypto:          $enable_cryptodev
843   Hardware accel:       $hw_accel
844   Padlock accel:        $use_padlock
845   PKCS#11 support:      $with_p11_kit
846   TPM support:          $with_tpm
847 ])
848
849 AC_MSG_NOTICE([Optional features:
850 (note that included applications might not compile properly
851 if features are disabled)
852
853   DTLS-SRTP support:    $ac_enable_srtp
854   ALPN support:         $ac_enable_alpn
855   OCSP support:         $ac_enable_ocsp
856   Ses. ticket support:  $ac_enable_session_tickets
857   OpenPGP support:      $ac_enable_openpgp
858   SRP support:          $ac_enable_srp
859   PSK support:          $ac_enable_psk
860   DHE support:          $ac_enable_dhe
861   ECDHE support:        $ac_enable_ecdhe
862   RSA-EXPORT support:   $ac_enable_rsa_export
863   Anon auth support:    $ac_enable_anon
864   Heartbeat support:    $ac_enable_heartbeat
865   IDNA support:         $libidn
866   Unicode support:      $ac_have_unicode
867   Self checks:          $enable_self_checks
868   Non-SuiteB curves:    $enable_non_suiteb
869   FIPS140 mode:         $enable_fips
870 ])
871
872 AC_MSG_NOTICE([Optional applications:
873
874   crywrap app:          $crywrap
875 ])
876
877 AC_MSG_NOTICE([Optional libraries:
878
879   Guile wrappers:       $opt_guile_bindings
880   C++ library:          $use_cxx
881   DANE library:         $enable_dane
882   OpenSSL compat:       $enable_openssl
883 ])
884
885 AC_MSG_NOTICE([System files:
886
887   Trust store pkcs11:   $with_default_trust_store_pkcs11
888   Trust store dir:      $with_default_trust_store_dir
889   Trust store file:     $with_default_trust_store_file
890   Blacklist file:       $with_default_blacklist_file
891   CRL file:             $with_default_crl_file
892   Priority file:        $system_priority_file
893   DNSSEC root key file: $unbound_root_key_file
894 ])
895
896 if test ! -f "$unbound_root_key_file"; then
897 AC_MSG_WARN([[
898 *** 
899 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
900 *** This file is needed for the verification of DNSSEC responses.
901 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
902 *** to generate or update it.
903 *** ]])
904 fi