updated e-mail address
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.3.0], [bugs@gnutls.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 ggl_EARLY
41 AM_PROG_AS
42 AM_PROG_AR
43 AC_PROG_CXX
44 AM_PROG_CC_C_O
45 AC_PROG_YACC
46 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
47
48 if test x"$AUTOGEN" = "x/bin/true"; then
49   AC_MSG_WARN([[
50 ***
51 *** autogen not found. Will not link against libopts.
52 *** ]])
53 enable_local_libopts=yes
54 fi
55
56 # For includes/gnutls/gnutls.h.in.
57 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
58 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
59 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
60 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
61
62 touch suppressions.valgrind
63 dnl C and C++ capabilities
64 AC_C_INLINE
65 AC_HEADER_STDC
66
67 # For the C++ code
68 AC_ARG_ENABLE(cxx,
69   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
70     use_cxx=$enableval, use_cxx=yes)
71 if test "$use_cxx" != "no"; then
72   AC_LANG_PUSH(C++)
73   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
74   AC_LANG_POP(C++)
75 fi
76 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
77 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
78
79 dnl Detect windows build
80 case "$host" in
81   *mingw32* | *mingw64*)
82     have_win=yes
83   ;;
84   *darwin*)
85     have_macosx=yes
86   ;;
87   *)
88     have_elf=yes
89   ;;
90 esac
91
92 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
93 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
94 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
95
96 dnl Hardware Acceleration
97 AC_ARG_ENABLE(hardware-acceleration,
98   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
99     use_accel=$enableval, use_accel=yes)
100 hw_accel=none
101
102
103 if test "$use_accel" != "no"; then
104 case $host_cpu in
105   i?86 | x86_64 | amd64)
106       AC_CHECK_HEADERS(cpuid.h)
107       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
108         hw_accel="x86-64"
109       else
110         hw_accel="x86"
111       fi
112   ;;
113   *)
114   ;;
115 esac
116
117 fi
118
119 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
120 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
121 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
122 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
123 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
124
125 dnl Try the hooks.m4
126 LIBGNUTLS_HOOKS
127 LIBGNUTLS_EXTRA_HOOKS
128
129 AC_ARG_ENABLE(doc,
130   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
131     enable_doc=$enableval, enable_doc=yes)
132 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
133
134 AC_ARG_ENABLE(tests,
135   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
136     enable_tests=$enableval, enable_tests=yes)
137 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
138
139 GTK_DOC_CHECK(1.1)
140 AM_GNU_GETTEXT([external])
141 AM_GNU_GETTEXT_VERSION([0.18])
142
143 AC_C_BIGENDIAN
144
145 gl_INIT
146 ggl_INIT
147
148 dnl GCC warnings to enable
149
150 AC_ARG_ENABLE([gcc-warnings],
151   [AS_HELP_STRING([--enable-gcc-warnings],
152                   [turn on lots of GCC warnings (for developers)])],
153   [case $enableval in
154      yes|no) ;;
155      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
156    esac
157    gl_gcc_warnings=$enableval],
158   [gl_gcc_warnings=no]
159 )
160
161 if test "$gl_gcc_warnings" = yes; then
162   gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])
163
164   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
165   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
166   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
167   nw="$nw -Wtraditional"            # Warns on #elif which we use often
168   nw="$nw -Wlogical-op"             # Too many false positives
169   nw="$nw -Wold-style-definition"   # 
170   nw="$nw -Wpadded"                 # Our structs are not padded
171   nw="$nw -Wunreachable-code"       # Too many false positives
172   nw="$nw -Wtraditional-conversion" # Too many warnings for now
173   nw="$nw -Wcast-qual"              # Too many warnings for now
174   nw="$nw -Waggregate-return"       # Too many warnings for now
175   nw="$nw -Wshadow"                 # Too many warnings for now
176   nw="$nw -Wswitch-default"         # Too many warnings for now
177   nw="$nw -Wswitch-enum"            # Too many warnings for now
178   nw="$nw -Wconversion"             # Too many warnings for now
179   nw="$nw -Wsign-conversion"        # Too many warnings for now
180   nw="$nw -Wformat-y2k"             # Too many warnings for now
181   nw="$nw -Woverlength-strings"     # We use some in tests/
182   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
183   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
184   nw="$nw -Wunsafe-loop-optimizations"
185   nw="$nw -Wstrict-overflow"
186   nw="$nw -Wmissing-noreturn"
187   nw="$nw -Winline"                 # Too compiler dependent
188   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
189   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
190   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
191   nw="$nw -Wstack-protector"        # Some functions cannot be protected
192   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
193
194   gl_MANYWARN_ALL_GCC([ws])
195   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
196   for w in $ws; do
197     gl_WARN_ADD([$w])
198   done
199
200   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
201   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
202   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
203   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
204   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
205   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
206   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
207   gl_WARN_ADD([-fdiagnostics-show-option])
208 fi
209
210 AC_SUBST([WERROR_CFLAGS])
211 AC_SUBST([WSTACK_CFLAGS])
212 AC_SUBST([WARN_CFLAGS])
213
214 dnl Programs for compilation or development
215 AC_PROG_LN_S
216 AC_LIBTOOL_WIN32_DLL
217 AC_PROG_LIBTOOL
218
219
220 dnl No fork on MinGW, disable some self-tests until we fix them.
221 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
222 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)
223 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
224
225 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
226 #include <signal.h>
227 ], [timer_create (0,0,0);])
228
229 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
230   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
231 fi
232
233 if test "$ac_cv_func_nanosleep" != "yes";then
234   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
235 fi
236
237 ac_have_unicode=no
238 if test "$ac_cv_func_iconv" != "yes";then
239   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
240   if test "$HAVE_LIBICONV" = "yes";then
241     ac_have_unicode=yes
242   fi
243 else
244   ac_have_unicode=yes
245 fi
246
247 if test "$ac_have_unicode" != "yes";then
248   if test "$have_win" = "yes";then
249     ac_have_unicode=yes
250   fi
251 fi
252
253 AC_MSG_CHECKING([whether to build libdane])
254 AC_ARG_ENABLE(libdane,
255     AS_HELP_STRING([--disable-libdane],
256                    [disable the built of libdane]),
257     enable_dane=$enableval, enable_dane=yes)
258 AC_MSG_RESULT($enable_dane)
259
260 if test "$enable_dane" != "no"; then
261     LIBS="$oldlibs -lunbound"
262     AC_MSG_CHECKING([for unbound library])
263     AC_LINK_IFELSE([AC_LANG_PROGRAM([
264                    #include <unbound.h>],[
265                    struct ub_ctx* ctx;
266                    ctx = ub_ctx_create();])],
267                   [AC_MSG_RESULT(yes)
268                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
269                    AC_SUBST([UNBOUND_CFLAGS], [])
270                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
271                    enable_dane=yes],
272                   [AC_MSG_RESULT(no)
273                    AC_MSG_WARN([[
274 *** 
275 *** libunbound was not found. Libdane will not be built.
276 *** ]])
277                   enable_dane=no])
278     LIBS="$oldlibs"
279 fi
280
281 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
282
283 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
284                                  [specify the unbound root key file]),
285             unbound_root_key_file="$withval", 
286 if test "$have_win" = yes; then
287     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
288 else
289     unbound_root_key_file="/etc/unbound/root.key"
290 fi
291 )
292
293 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
294   ["$unbound_root_key_file"], [The DNSSEC root key file])
295
296 dnl Check for p11-kit
297 P11_KIT_MINIMUM=0.19.1
298 AC_ARG_WITH(p11-kit,
299         AS_HELP_STRING([--without-p11-kit],
300                 [Build without p11-kit and PKCS#11 support]))
301 if test "$with_p11_kit" != "no"; then
302         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
303         if test "$with_p11_kit" != "no";then
304                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
305                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
306                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
307                 else
308                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
309                 fi
310         else
311                 with_p11_kit=no
312                 AC_MSG_WARN([[
313 *** 
314 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
315 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
316 *** ]])
317         fi
318 fi
319
320 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
321
322 AC_ARG_WITH(tpm,
323         AS_HELP_STRING([--without-tpm],
324                 [Disable TPM (trousers) support.]),
325                 [with_tpm=$withval], [with_tpm=yes])
326 if test "$with_tpm" != "no"; then
327     LIBS="$oldlibs -ltspi"
328     AC_MSG_CHECKING([for tss library])
329     AC_LINK_IFELSE([AC_LANG_PROGRAM([
330                    #include <trousers/tss.h>
331                    #include <trousers/trousers.h>],[
332                    int err = Tspi_Context_Create((void *)0);
333                    Trspi_Error_String(err);])],
334                   [AC_MSG_RESULT(yes)
335                    AC_SUBST([TSS_LIBS], [-ltspi])
336                    AC_SUBST([TSS_CFLAGS], [])
337                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
338                    with_tpm=yes],
339                   [AC_MSG_RESULT(no)
340                    AC_MSG_WARN([[
341 *** 
342 *** trousers was not found. TPM support will be disabled.
343 *** ]])
344                   with_tpm=no])
345     LIBS="$oldlibs"
346 fi
347
348 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
349
350 LIBOPTS_CHECK([src/libopts])
351 if test "$NEED_LIBOPTS_DIR" == "true";then
352         dnl delete libopts-generated files
353         for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do
354                 nam=`echo $i|sed 's/.bak//g'`
355                 if test -f $i;then
356                         cp -f $i $nam
357                 fi
358         done
359         AC_SUBST([AUTOGEN], [/bin/true])
360         enable_local_libopts=yes
361 else
362         enable_local_libopts=no
363 fi
364 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")
365
366 AC_CHECK_TYPE(ssize_t,
367   [
368     DEFINE_SSIZE_T="#include <sys/types.h>"
369     AC_SUBST(DEFINE_SSIZE_T)
370   ], [
371     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
372     DEFINE_SSIZE_T="typedef int ssize_t;"
373     AC_SUBST(DEFINE_SSIZE_T)
374   ], [
375     #include <sys/types.h>
376   ])
377
378 # For minitasn1.
379 AC_CHECK_SIZEOF(unsigned long int, 4)
380 AC_CHECK_SIZEOF(unsigned int, 4)
381
382 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
383                                  [disable zlib compression support]),
384             ac_zlib=$withval, ac_zlib=yes)
385 AC_MSG_CHECKING([whether to include zlib compression support])
386 if test x$ac_zlib != xno; then
387  AC_MSG_RESULT(yes)
388  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
389  if test x$ac_cv_libz != xyes; then
390    AC_MSG_WARN(
391 *** 
392 *** ZLIB was not found. You will not be able to use ZLIB compression.)
393  fi
394 else
395  AC_MSG_RESULT(no)
396 fi
397
398 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
399
400 if test x$ac_zlib != xno; then
401   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
402     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
403       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
404     else
405       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
406     fi
407   fi
408 fi
409 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
410
411
412
413 AC_ARG_WITH([default-trust-store-pkcs11],
414   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
415     [use the given pkcs11 uri as default trust store])])
416
417 if test "x$with_default_trust_store_pkcs11" != x; then
418   if test "x$with_p11_kit" = xno; then
419     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
420   fi
421   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
422     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
423 fi
424
425 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
426 AC_ARG_WITH([default-trust-store-file],
427   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
428     [use the given file default trust store])], with_default_trust_store_file="$withval",
429   [if test "$build" = "$host";then
430   for i in \
431     /etc/ssl/ca-bundle.pem \
432     /etc/ssl/certs/ca-certificates.crt \
433     /etc/pki/tls/cert.pem \
434     /usr/local/share/certs/ca-root-nss.crt \
435     /etc/ssl/cert.pem
436     do
437     if test -e $i; then
438       with_default_trust_store_file="$i"
439       break
440     fi
441   done
442   fi]
443 )
444
445 if test "$with_default_trust_store_file" = "no";then
446   with_default_trust_store_file=""
447 fi
448
449 AC_ARG_WITH([default-crl-file],
450   [AS_HELP_STRING([--with-default-crl-file=FILE],
451     [use the given CRL file as default])])
452
453 if test "x$with_default_trust_store_file" != x; then
454   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
455     ["$with_default_trust_store_file"], [use the given file default trust store])
456 fi
457
458 if test "x$with_default_crl_file" != x; then
459   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
460     ["$with_default_crl_file"], [use the given CRL file])
461 fi
462
463 dnl Guile bindings.
464 opt_guile_bindings=yes
465 AC_MSG_CHECKING([whether building Guile bindings])
466 AC_ARG_ENABLE(guile,
467         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
468 opt_guile_bindings=$enableval)
469 AC_MSG_RESULT($opt_guile_bindings)
470
471 AC_ARG_WITH([guile-site-dir],
472   [AS_HELP_STRING([--with-guile-site-dir],
473      [use the given directory as the Guile site (use with care)])])
474
475 if test "$opt_guile_bindings" = "yes"; then
476    AC_MSG_RESULT([***
477 *** Detecting GNU Guile...
478 ])
479
480    AC_PATH_PROG([guile_snarf], [guile-snarf])
481    if test "x$guile_snarf" = "x"; then
482       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
483       opt_guile_bindings=no
484    else
485       GUILE_PROGS
486       GUILE_FLAGS
487
488       save_CFLAGS="$CFLAGS"
489       save_LIBS="$LIBS"
490       CFLAGS="$CFLAGS $GUILE_CFLAGS"
491       LIBS="$LIBS $GUILE_LDFLAGS"
492       AC_MSG_CHECKING([whether GNU Guile is recent enough])
493       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
494         [], [opt_guile_bindings=no])
495       CFLAGS="$save_CFLAGS"
496       LIBS="$save_LIBS"
497
498       if test "$opt_guile_bindings" = "yes"; then
499         AC_MSG_RESULT([yes])
500         case "x$with_guile_site_dir" in 
501              xno)
502                 # Use the default $(GUILE_SITE).
503                 GUILE_SITE_DIR
504                 ;;
505              x|xyes)
506                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
507                 # hack is used to allow `distcheck' to work (see
508                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
509                 GUILE_SITE="\$(datadir)/guile/site"
510                 AC_SUBST(GUILE_SITE)
511                 ;;
512              *)
513                 # Use the user-specified directory as $(GUILE_SITE).
514                 GUILE_SITE="$with_guile_site_dir"
515                 AC_SUBST(GUILE_SITE)
516                 ;;
517         esac
518         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
519         _gcc_cflags_save="$CFLAGS"
520         CFLAGS="${CFLAGS} -fgnu89-inline"
521         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
522                           gnu89_inline=yes, gnu89_inline=no)
523         AC_MSG_RESULT($gnu89_inline)
524         CFLAGS="$_gcc_cflags_save"
525
526         # Optional Guile functions.
527         save_CFLAGS="$CFLAGS"
528         save_LIBS="$LIBS"
529         CFLAGS="$CFLAGS $GUILE_CFLAGS"
530         LIBS="$LIBS $GUILE_LDFLAGS"
531         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
532         CFLAGS="$save_CFLAGS"
533         LIBS="$save_LIBS"
534
535         # The place where guile-gnutls.la will go.
536         AC_MSG_CHECKING([the Guile effective version])
537         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
538         AC_MSG_RESULT([$guile_effective_version])
539         guileextensiondir="$libdir/guile/$guile_effective_version"
540         AC_SUBST([guileextensiondir])
541       else
542         AC_MSG_RESULT([no])
543         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
544         opt_guile_bindings=no
545       fi
546    fi
547 fi
548 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
549
550 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
551 LIBGNUTLS_CFLAGS="-I${includedir}"
552 AC_SUBST(LIBGNUTLS_LIBS)
553 AC_SUBST(LIBGNUTLS_CFLAGS)
554
555
556 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
557 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
558
559 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
560 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
561 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
562
563 dnl Crywrap dependencies
564    AC_MSG_RESULT([***
565 *** Checking dependencies for crywrap...
566 ])
567
568 crywrap=no
569
570 if test "$have_win" != "yes"; then
571
572 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
573
574 dnl **********************
575 dnl * Typedefs & co
576 dnl **********************
577 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
578 [AC_LANG_PROGRAM([#include <sys/types.h>
579 #include <signal.h>
580 ],
581                  [return *(signal (0, 0)) (0) == 1;])],
582                    [ac_cv_type_signal=int],
583                    [ac_cv_type_signal=void])])
584 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
585                     (`int' or `void').])
586
587 AC_FUNC_SELECT_ARGTYPES
588 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
589                 putenv regcomp scandir select socket strcasecmp strchr \
590                 strdup strerror strncasecmp strrchr strstr strtoul uname])
591
592 AC_ARG_ENABLE(crywrap,
593         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
594
595  libidn=no
596
597  if test "x$enable_crywrap" != "xno" ; then
598         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
599         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
600  fi
601
602  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
603   crywrap=yes
604  fi
605
606 fi
607
608 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
609
610 dnl end of crywrap requirements
611
612 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
613 AC_CONFIG_FILES([
614   Makefile
615   doc/Makefile
616   doc/credentials/Makefile
617   doc/credentials/openpgp/Makefile
618   doc/credentials/srp/Makefile
619   doc/credentials/x509/Makefile
620   doc/cyclo/Makefile
621   doc/doxygen/Doxyfile
622   doc/examples/Makefile
623   doc/latex/Makefile
624   doc/manpages/Makefile
625   doc/reference/Makefile
626   doc/reference/version.xml
627   doc/scripts/Makefile
628   extra/Makefile
629   extra/includes/Makefile
630   libdane/Makefile
631   libdane/includes/Makefile
632   libdane/gnutls-dane.pc
633   gl/Makefile
634   gl/tests/Makefile
635   guile/Makefile
636   guile/modules/Makefile
637   guile/src/Makefile
638   guile/tests/Makefile
639   lib/Makefile
640   lib/accelerated/Makefile
641   lib/accelerated/x86/Makefile
642   lib/algorithms/Makefile
643   lib/auth/Makefile
644   lib/ext/Makefile
645   lib/extras/Makefile
646   lib/gnutls.pc
647   lib/includes/Makefile
648   lib/includes/gnutls/gnutls.h
649   lib/minitasn1/Makefile
650   lib/nettle/Makefile
651   lib/opencdk/Makefile
652   lib/openpgp/Makefile
653   lib/x509/Makefile
654   po/Makefile.in
655   src/Makefile
656   src/crywrap/Makefile
657   src/gl/Makefile
658   tests/Makefile
659   tests/cert-tests/Makefile
660   tests/dsa/Makefile
661   tests/dtls/Makefile
662   tests/srp/Makefile
663   tests/ecdsa/Makefile
664   tests/key-id/Makefile
665   tests/openpgp-certs/Makefile
666   tests/pkcs1-padding/Makefile
667   tests/pkcs12-decode/Makefile
668   tests/pkcs8-decode/Makefile
669   tests/rsa-md5-collision/Makefile
670   tests/safe-renegotiation/Makefile
671   tests/scripts/Makefile
672   tests/sha2/Makefile
673   tests/slow/Makefile
674   tests/suite/Makefile
675   tests/userid/Makefile
676 ])
677
678 AC_OUTPUT
679
680 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
681 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
682 AC_MSG_NOTICE([summary of build options:
683
684   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
685   Host/Target system:   ${host}
686   Build system:         ${build}
687   Install prefix:       ${prefix}
688   Compiler:             ${CC}
689   CFlags:               ${CFLAGS}
690   Library types:        Shared=${enable_shared}, Static=${enable_static}
691 ])
692
693 AC_MSG_NOTICE([External hardware support:
694
695   /dev/crypto:          $enable_cryptodev
696   Hardware accel:       $hw_accel
697   PKCS#11 support:      $with_p11_kit
698   TPM support:          $with_tpm
699 ])
700
701 AC_MSG_NOTICE([Optional features:
702 (note that included applications might not compile properly
703 if features are disabled)
704
705   DTLS-SRTP support:    $ac_enable_srtp
706   ALPN support:         $ac_enable_alpn
707   OCSP support:         $ac_enable_ocsp
708   OpenPGP support:      $ac_enable_openpgp
709   SRP support:          $ac_enable_srp
710   PSK support:          $ac_enable_psk
711   DHE support:          $ac_enable_dhe
712   ECDHE support:        $ac_enable_ecdhe
713   Anon auth support:    $ac_enable_anon
714   Heartbeat support:    $ac_enable_heartbeat
715   RSA-EXPORT compat:    $ac_enable_rsa_export
716   Unicode support:      $ac_have_unicode
717 ])
718
719 AC_MSG_NOTICE([Optional applications:
720
721   crywrap app:          $libidn
722   local libopts:        ${enable_local_libopts}
723   local libtasn1:       ${included_libtasn1}
724 ])
725
726 AC_MSG_NOTICE([Optional libraries:
727
728   Guile wrappers:       $opt_guile_bindings
729   C++ library:          $use_cxx
730   DANE library:         $enable_dane
731   OpenSSL compat:       $enable_openssl
732 ])
733
734 AC_MSG_NOTICE([System files:
735
736   Trust store pkcs:     $with_default_trust_store_pkcs11
737   Trust store file:     $with_default_trust_store_file
738   CRL file:             $with_default_crl_file
739   DNSSEC root key file: $unbound_root_key_file
740 ])
741
742 if test ! -f "$unbound_root_key_file"; then
743 AC_MSG_WARN([[
744 *** 
745 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
746 *** This file is needed for the verification of DNSSEC responses.
747 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
748 *** to generate or update it.
749 *** ]])
750 fi