Fix patch version calculation when it contains non-numeric chars
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.3.0], [bugs@gnutls.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 subdir-objects no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 ggl_EARLY
41 AM_PROG_AS
42 AM_PROG_AR
43 AC_PROG_CXX
44 AM_PROG_CC_C_O
45 AC_PROG_YACC
46 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
47
48 if test x"$AUTOGEN" = "x/bin/true"; then
49   AC_MSG_WARN([[
50 ***
51 *** autogen not found. Will not link against libopts.
52 *** ]])
53 enable_local_libopts=yes
54 fi
55
56 # For includes/gnutls/gnutls.h.in.
57 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
58 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
59 AC_SUBST(PATCH_VERSION, [[`echo $PACKAGE_VERSION | sed 's/.*\..*\.\([0-9]*\).*/\1/g'`]])
60 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
61
62 touch suppressions.valgrind
63 dnl C and C++ capabilities
64 AC_C_INLINE
65 AC_HEADER_STDC
66
67 # For the C++ code
68 AC_ARG_ENABLE(cxx,
69   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
70     use_cxx=$enableval, use_cxx=yes)
71 if test "$use_cxx" != "no"; then
72   AC_LANG_PUSH(C++)
73   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
74   AC_LANG_POP(C++)
75 fi
76 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
77 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
78
79 dnl Detect windows build
80 case "$host" in
81   *mingw32* | *mingw64*)
82     have_win=yes
83   ;;
84   *darwin*)
85     have_macosx=yes
86   ;;
87   *)
88     have_elf=yes
89   ;;
90 esac
91
92 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
93 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
94 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
95
96 dnl Hardware Acceleration
97 AC_ARG_ENABLE(hardware-acceleration,
98   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
99     use_accel=$enableval, use_accel=yes)
100 hw_accel=none
101
102
103 if test "$use_accel" != "no"; then
104 case $host_cpu in
105   i?86 | x86_64 | amd64)
106       AC_CHECK_HEADERS(cpuid.h)
107       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
108         hw_accel="x86-64"
109       else
110         hw_accel="x86"
111       fi
112   ;;
113   *)
114   ;;
115 esac
116
117 fi
118
119 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
120 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
121 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
122 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
123 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
124
125
126 dnl Try the hooks.m4
127 LIBGNUTLS_HOOKS
128 LIBGNUTLS_EXTRA_HOOKS
129
130 AC_ARG_ENABLE(doc,
131   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
132     enable_doc=$enableval, enable_doc=yes)
133 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
134
135 AC_ARG_ENABLE(tests,
136   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
137     enable_tests=$enableval, enable_tests=yes)
138 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
139
140 GTK_DOC_CHECK(1.1)
141 AM_GNU_GETTEXT([external])
142 AM_GNU_GETTEXT_VERSION([0.18])
143
144 AC_C_BIGENDIAN
145
146 dnl No fork on MinGW, disable some self-tests until we fix them.
147 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
148 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)
149 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
150
151 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
152 #include <signal.h>
153 ], [timer_create (0,0,0);])
154
155 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
156   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
157 fi
158
159 if test "$ac_cv_func_nanosleep" != "yes";then
160   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
161   gnutls_needs_librt=yes
162 fi
163
164 if test "$ac_cv_func_clock_gettime" != "yes";then
165   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [clock_gettime (0, 0);])
166   gnutls_needs_librt=yes
167 fi
168
169 ac_have_unicode=no
170 if test "$ac_cv_func_iconv" != "yes";then
171   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
172   if test "$HAVE_LIBICONV" = "yes";then
173     ac_have_unicode=yes
174   fi
175 else
176   ac_have_unicode=yes
177 fi
178
179 if test "$ac_have_unicode" != "yes";then
180   if test "$have_win" = "yes";then
181     ac_have_unicode=yes
182   fi
183 fi
184
185 dnl Note that g*l_INIT are run after we check for library capabilities,
186 dnl to prevent issues from caching lib dependencies. See discussion
187 dnl in https://bugs.gentoo.org/show_bug.cgi?id=494940 and
188 dnl http://gnu-autoconf.7623.n7.nabble.com/Correct-way-to-check-for-clock-gettime-td12276.html
189 gl_INIT
190 ggl_INIT
191
192 dnl GCC warnings to enable
193
194 AC_ARG_ENABLE([gcc-warnings],
195   [AS_HELP_STRING([--enable-gcc-warnings],
196                   [turn on lots of GCC warnings (for developers)])],
197   [case $enableval in
198      yes|no) ;;
199      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
200    esac
201    gl_gcc_warnings=$enableval],
202   [gl_gcc_warnings=no]
203 )
204
205 if test "$gl_gcc_warnings" = yes; then
206   gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])
207
208   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
209   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
210   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
211   nw="$nw -Wtraditional"            # Warns on #elif which we use often
212   nw="$nw -Wlogical-op"             # Too many false positives
213   nw="$nw -Wold-style-definition"   # 
214   nw="$nw -Wpadded"                 # Our structs are not padded
215   nw="$nw -Wunreachable-code"       # Too many false positives
216   nw="$nw -Wtraditional-conversion" # Too many warnings for now
217   nw="$nw -Wcast-qual"              # Too many warnings for now
218   nw="$nw -Waggregate-return"       # Too many warnings for now
219   nw="$nw -Wshadow"                 # Too many warnings for now
220   nw="$nw -Wswitch-default"         # Too many warnings for now
221   nw="$nw -Wswitch-enum"            # Too many warnings for now
222   nw="$nw -Wconversion"             # Too many warnings for now
223   nw="$nw -Wsign-conversion"        # Too many warnings for now
224   nw="$nw -Wformat-y2k"             # Too many warnings for now
225   nw="$nw -Woverlength-strings"     # We use some in tests/
226   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
227   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
228   nw="$nw -Wunsafe-loop-optimizations"
229   nw="$nw -Wstrict-overflow"
230   nw="$nw -Wmissing-noreturn"
231   nw="$nw -Winline"                 # Too compiler dependent
232   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
233   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
234   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
235   nw="$nw -Wstack-protector"        # Some functions cannot be protected
236   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
237
238   gl_MANYWARN_ALL_GCC([ws])
239   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
240   for w in $ws; do
241     gl_WARN_ADD([$w])
242   done
243
244   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
245   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
246   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
247   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
248   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
249   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
250   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
251   gl_WARN_ADD([-fdiagnostics-show-option])
252 fi
253
254 AC_SUBST([WERROR_CFLAGS])
255 AC_SUBST([WSTACK_CFLAGS])
256 AC_SUBST([WARN_CFLAGS])
257
258 dnl Programs for compilation or development
259 AC_PROG_LN_S
260 LT_INIT([disable-static,win32-dll,shared])
261
262
263
264 AC_ARG_ENABLE(self-checks,
265   AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),
266     enable_self_checks=$enableval, enable_self_checks=no)
267
268 AC_ARG_ENABLE(fips140-mode,
269   AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),
270     enable_fips=$enableval, enable_fips=no)
271 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")
272 if [ test "$enable_fips" = "yes" ];then
273   AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])
274   if test "x$HAVE_LIBDL" = "xyes";then
275     enable_self_checks=yes
276
277     AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])
278
279     AC_SUBST([FIPS140_LIBS], $LIBDL)
280   else
281     enable_fips=no
282     AC_MSG_WARN([[
283 *** 
284 *** This system is not supported in FIPS140 mode.
285 *** libdl and dladdr() are required.
286 *** ]])
287   fi
288 fi
289
290 AC_ARG_ENABLE(non-suiteb-curves,
291   AS_HELP_STRING([--disable-non-suiteb-curves], [disable curves not in SuiteB]),
292     enable_non_suiteb=$enableval, enable_non_suiteb=yes)
293 if [ test "$enable_non_suiteb" = "yes" ];then
294   AC_DEFINE([ENABLE_NON_SUITEB_CURVES], 1, [Enable all curves])
295 fi
296
297 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")
298 if [ test "$enable_self_checks" = "yes" ];then
299    AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])
300 fi
301
302 AC_MSG_CHECKING([whether to build libdane])
303 AC_ARG_ENABLE(libdane,
304     AS_HELP_STRING([--disable-libdane],
305                    [disable the built of libdane]),
306     enable_dane=$enableval, enable_dane=yes)
307 AC_MSG_RESULT($enable_dane)
308
309 if test "$enable_dane" != "no"; then
310     LIBS="$oldlibs -lunbound"
311     AC_MSG_CHECKING([for unbound library])
312     AC_LINK_IFELSE([AC_LANG_PROGRAM([
313                    #include <unbound.h>],[
314                    struct ub_ctx* ctx;
315                    ctx = ub_ctx_create();])],
316                   [AC_MSG_RESULT(yes)
317                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
318                    AC_SUBST([UNBOUND_CFLAGS], [])
319                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
320                    enable_dane=yes],
321                   [AC_MSG_RESULT(no)
322                    AC_MSG_WARN([[
323 *** 
324 *** libunbound was not found. Libdane will not be built.
325 *** ]])
326                   enable_dane=no])
327     LIBS="$oldlibs"
328 fi
329
330 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
331
332 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
333                                  [specify the unbound root key file]),
334             unbound_root_key_file="$withval", 
335 if test "$have_win" = yes; then
336     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
337 else
338     if test -f /var/lib/unbound/root.key;then
339         unbound_root_key_file="/var/lib/unbound/root.key"
340     else
341         unbound_root_key_file="/etc/unbound/root.key"
342     fi
343 fi
344 )
345
346 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
347   ["$unbound_root_key_file"], [The DNSSEC root key file])
348
349 AC_ARG_WITH(system-priority-file, AS_HELP_STRING([--with-system-priority-file],
350                                  [specify the system priority file]),
351             system_priority_file="$withval", 
352 system_priority_file="/etc/gnutls/default-priority"
353 )
354
355 AC_DEFINE_UNQUOTED([SYSTEM_PRIORITY_FILE],
356   ["$system_priority_file"], [The system priority file])
357
358 dnl Check for p11-kit
359 P11_KIT_MINIMUM=0.20.0
360 AC_ARG_WITH(p11-kit,
361         AS_HELP_STRING([--without-p11-kit],
362                 [Build without p11-kit and PKCS#11 support]))
363 if test "$with_p11_kit" != "no"; then
364         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
365         if test "$with_p11_kit" != "no";then
366                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
367                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
368                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
369                 else
370                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
371                 fi
372         else
373                 with_p11_kit=no
374                 AC_MSG_WARN([[
375 *** 
376 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
377 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
378 *** ]])
379         fi
380 fi
381
382 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
383
384 AC_ARG_WITH(tpm,
385         AS_HELP_STRING([--without-tpm],
386                 [Disable TPM (trousers) support.]),
387                 [with_tpm=$withval], [with_tpm=yes])
388 if test "$with_tpm" != "no"; then
389     LIBS="$oldlibs -ltspi"
390     AC_MSG_CHECKING([for tss library])
391     AC_LINK_IFELSE([AC_LANG_PROGRAM([
392                    #include <trousers/tss.h>
393                    #include <trousers/trousers.h>],[
394                    int err = Tspi_Context_Create((void *)0);
395                    Trspi_Error_String(err);])],
396                   [AC_MSG_RESULT(yes)
397                    AC_SUBST([TSS_LIBS], [-ltspi])
398                    AC_SUBST([TSS_CFLAGS], [])
399                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
400                    with_tpm=yes],
401                   [AC_MSG_RESULT(no)
402                    AC_MSG_WARN([[
403 *** 
404 *** trousers was not found. TPM support will be disabled.
405 *** ]])
406                   with_tpm=no])
407     LIBS="$oldlibs"
408 fi
409
410 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
411
412 LIBOPTS_CHECK([src/libopts])
413 if test "$NEED_LIBOPTS_DIR" = "true";then
414         dnl replace libopts-generated files with distributed backups, if present
415         missing_baks=
416         for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do
417                 nam=`echo $i|sed 's/.bak//g'`
418                 if test -f $i;then
419                         cp -f $i $nam
420                 else
421                         missing_baks=true
422                 fi
423         done
424         if test -z "$missing_baks"; then
425                 AC_SUBST([AUTOGEN], [/bin/true])
426         fi
427         enable_local_libopts=yes
428 else
429         enable_local_libopts=no
430 fi
431 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")
432
433 AC_CHECK_TYPE(ssize_t,
434   [
435     DEFINE_SSIZE_T="#include <sys/types.h>"
436     AC_SUBST(DEFINE_SSIZE_T)
437   ], [
438     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
439     DEFINE_SSIZE_T="typedef int ssize_t;"
440     AC_SUBST(DEFINE_SSIZE_T)
441   ], [
442     #include <sys/types.h>
443   ])
444
445 # For minitasn1.
446 AC_CHECK_SIZEOF(unsigned long int, 4)
447 AC_CHECK_SIZEOF(unsigned int, 4)
448
449 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
450                                  [disable zlib compression support]),
451             ac_zlib=$withval, ac_zlib=yes)
452 AC_MSG_CHECKING([whether to include zlib compression support])
453 if test x$ac_zlib != xno; then
454  AC_MSG_RESULT(yes)
455  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
456  if test x$ac_cv_libz != xyes; then
457    AC_MSG_WARN(
458 *** 
459 *** ZLIB was not found. You will not be able to use ZLIB compression.)
460  fi
461 else
462  AC_MSG_RESULT(no)
463 fi
464
465 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
466
467 if test x$ac_zlib != xno; then
468   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
469     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
470       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
471     else
472       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
473     fi
474   fi
475 fi
476 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
477
478
479
480 AC_ARG_WITH([default-trust-store-pkcs11],
481   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
482     [use the given pkcs11 uri as default trust store])])
483
484 if test "x$with_default_trust_store_pkcs11" != x; then
485   if test "x$with_p11_kit" = xno; then
486     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
487   fi
488   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
489     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
490 fi
491
492 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
493 AC_ARG_WITH([default-trust-store-file],
494   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
495     [use the given file default trust store])], with_default_trust_store_file="$withval",
496   [if test "$build" = "$host" && test x$with_default_trust_store_pkcs11 = x;then
497   for i in \
498     /etc/ssl/ca-bundle.pem \
499     /etc/ssl/certs/ca-certificates.crt \
500     /etc/pki/tls/cert.pem \
501     /usr/local/share/certs/ca-root-nss.crt \
502     /etc/ssl/cert.pem
503     do
504     if test -e "$i"; then
505       with_default_trust_store_file="$i"
506       break
507     fi
508   done
509   fi]
510 )
511
512 if test "$with_default_trust_store_file" = "no";then
513   with_default_trust_store_file=""
514 fi
515
516 AC_ARG_WITH([default-crl-file],
517   [AS_HELP_STRING([--with-default-crl-file=FILE],
518     [use the given CRL file as default])])
519
520 AC_ARG_WITH([default-blacklist-file],
521   [AS_HELP_STRING([--with-default-blacklist-file=FILE],
522     [use the given certificate blacklist file as default])])
523
524 if test "x$with_default_trust_store_file" != x; then
525   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
526     ["$with_default_trust_store_file"], [use the given file default trust store])
527 fi
528
529 if test "x$with_default_crl_file" != x; then
530   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
531     ["$with_default_crl_file"], [use the given CRL file])
532 fi
533
534 if test "x$with_default_blacklist_file" != x; then
535   AC_DEFINE_UNQUOTED([DEFAULT_BLACKLIST_FILE],
536     ["$with_default_blacklist_file"], [use the given certificate blacklist file])
537 fi
538
539 dnl Guile bindings.
540 opt_guile_bindings=yes
541 AC_MSG_CHECKING([whether building Guile bindings])
542 AC_ARG_ENABLE(guile,
543         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
544 opt_guile_bindings=$enableval)
545 AC_MSG_RESULT($opt_guile_bindings)
546
547 AC_ARG_WITH([guile-site-dir],
548   [AS_HELP_STRING([--with-guile-site-dir],
549      [use the given directory as the Guile site (use with care)])])
550
551 if test "$opt_guile_bindings" = "yes"; then
552    AC_MSG_RESULT([***
553 *** Detecting GNU Guile...
554 ])
555
556    AC_PATH_PROG([guile_snarf], [guile-snarf])
557    if test "x$guile_snarf" = "x"; then
558       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
559       opt_guile_bindings=no
560    else
561       GUILE_PROGS
562       GUILE_FLAGS
563
564       save_CFLAGS="$CFLAGS"
565       save_LIBS="$LIBS"
566       CFLAGS="$CFLAGS $GUILE_CFLAGS"
567       LIBS="$LIBS $GUILE_LDFLAGS"
568       AC_MSG_CHECKING([whether GNU Guile is recent enough])
569       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
570         [], [opt_guile_bindings=no])
571       CFLAGS="$save_CFLAGS"
572       LIBS="$save_LIBS"
573
574       if test "$opt_guile_bindings" = "yes"; then
575         AC_MSG_RESULT([yes])
576         case "x$with_guile_site_dir" in 
577              xno)
578                 # Use the default $(GUILE_SITE).
579                 GUILE_SITE_DIR
580                 ;;
581              x|xyes)
582                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
583                 # hack is used to allow `distcheck' to work (see
584                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
585                 GUILE_SITE="\$(datadir)/guile/site"
586                 AC_SUBST(GUILE_SITE)
587                 ;;
588              *)
589                 # Use the user-specified directory as $(GUILE_SITE).
590                 GUILE_SITE="$with_guile_site_dir"
591                 AC_SUBST(GUILE_SITE)
592                 ;;
593         esac
594         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
595         _gcc_cflags_save="$CFLAGS"
596         CFLAGS="${CFLAGS} -fgnu89-inline"
597         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
598                           gnu89_inline=yes, gnu89_inline=no)
599         AC_MSG_RESULT($gnu89_inline)
600         CFLAGS="$_gcc_cflags_save"
601
602         # Optional Guile functions.
603         save_CFLAGS="$CFLAGS"
604         save_LIBS="$LIBS"
605         CFLAGS="$CFLAGS $GUILE_CFLAGS"
606         LIBS="$LIBS $GUILE_LDFLAGS"
607         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
608         CFLAGS="$save_CFLAGS"
609         LIBS="$save_LIBS"
610
611         # The place where guile-gnutls.la will go.
612         AC_MSG_CHECKING([the Guile effective version])
613         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
614         AC_MSG_RESULT([$guile_effective_version])
615         guileextensiondir="$libdir/guile/$guile_effective_version"
616         AC_SUBST([guileextensiondir])
617       else
618         AC_MSG_RESULT([no])
619         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
620         opt_guile_bindings=no
621       fi
622    fi
623 fi
624 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
625
626 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
627 LIBGNUTLS_CFLAGS="-I${includedir}"
628 AC_SUBST(LIBGNUTLS_LIBS)
629 AC_SUBST(LIBGNUTLS_CFLAGS)
630
631 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")
632
633 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
634 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
635
636 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
637 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
638 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
639
640 dnl Crywrap dependencies
641    AC_MSG_RESULT([***
642 *** Checking dependencies for crywrap...
643 ])
644
645 crywrap=no
646
647 if test "$have_win" != "yes"; then
648
649 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
650
651 dnl **********************
652 dnl * Typedefs & co
653 dnl **********************
654 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
655 [AC_LANG_PROGRAM([#include <sys/types.h>
656 #include <signal.h>
657 ],
658                  [return *(signal (0, 0)) (0) == 1;])],
659                    [ac_cv_type_signal=int],
660                    [ac_cv_type_signal=void])])
661 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
662                     (`int' or `void').])
663
664 AC_FUNC_SELECT_ARGTYPES
665 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
666                 putenv regcomp scandir select socket strcasecmp strchr \
667                 strdup strerror strncasecmp strrchr strstr strtoul uname])
668
669 AC_ARG_ENABLE(crywrap,
670         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
671
672  libidn=no
673
674  if test "x$enable_crywrap" != "xno" ; then
675         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
676         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
677  fi
678
679  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
680   crywrap=yes
681  fi
682
683 fi
684
685 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
686
687 dnl end of crywrap requirements
688
689 dnl Some variables needed in makefiles
690 YEAR=`date +%Y`
691 AC_SUBST([YEAR], $YEAR)
692
693 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
694 AC_CONFIG_FILES([
695   Makefile
696   doc/Makefile
697   doc/credentials/Makefile
698   doc/credentials/openpgp/Makefile
699   doc/credentials/srp/Makefile
700   doc/credentials/x509/Makefile
701   doc/cyclo/Makefile
702   doc/doxygen/Doxyfile
703   doc/examples/Makefile
704   doc/latex/Makefile
705   doc/manpages/Makefile
706   doc/reference/Makefile
707   doc/reference/version.xml
708   doc/scripts/Makefile
709   extra/Makefile
710   extra/includes/Makefile
711   libdane/Makefile
712   libdane/includes/Makefile
713   libdane/gnutls-dane.pc
714   gl/Makefile
715   gl/tests/Makefile
716   guile/Makefile
717   guile/modules/Makefile
718   guile/src/Makefile
719   guile/tests/Makefile
720   lib/Makefile
721   lib/accelerated/Makefile
722   lib/accelerated/x86/Makefile
723   lib/algorithms/Makefile
724   lib/auth/Makefile
725   lib/ext/Makefile
726   lib/extras/Makefile
727   lib/gnutls.pc
728   lib/includes/Makefile
729   lib/includes/gnutls/gnutls.h
730   lib/minitasn1/Makefile
731   lib/nettle/Makefile
732   lib/opencdk/Makefile
733   lib/openpgp/Makefile
734   lib/x509/Makefile
735   po/Makefile.in
736   src/Makefile
737   src/crywrap/Makefile
738   src/gl/Makefile
739   tests/Makefile
740   tests/cert-tests/Makefile
741   tests/dsa/Makefile
742   tests/dtls/Makefile
743   tests/srp/Makefile
744   tests/ecdsa/Makefile
745   tests/key-id/Makefile
746   tests/openpgp-certs/Makefile
747   tests/pkcs1-padding/Makefile
748   tests/pkcs12-decode/Makefile
749   tests/pkcs8-decode/Makefile
750   tests/rsa-md5-collision/Makefile
751   tests/safe-renegotiation/Makefile
752   tests/scripts/Makefile
753   tests/sha2/Makefile
754   tests/slow/Makefile
755   tests/suite/Makefile
756   tests/userid/Makefile
757 ])
758
759 AC_OUTPUT
760
761 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
762 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
763 AC_MSG_NOTICE([summary of build options:
764
765   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
766   Host/Target system:   ${host}
767   Build system:         ${build}
768   Install prefix:       ${prefix}
769   Compiler:             ${CC}
770   CFlags:               ${CFLAGS}
771   Library types:        Shared=${enable_shared}, Static=${enable_static}
772   Local libopts:        ${enable_local_libopts}
773   Local libtasn1:       ${included_libtasn1}
774   Use nettle-mini:      ${mini_nettle}
775 ])
776
777 AC_MSG_NOTICE([External hardware support:
778
779   /dev/crypto:          $enable_cryptodev
780   Hardware accel:       $hw_accel
781   PKCS#11 support:      $with_p11_kit
782   TPM support:          $with_tpm
783 ])
784
785 AC_MSG_NOTICE([Optional features:
786 (note that included applications might not compile properly
787 if features are disabled)
788
789   DTLS-SRTP support:    $ac_enable_srtp
790   ALPN support:         $ac_enable_alpn
791   OCSP support:         $ac_enable_ocsp
792   Ses. ticket support:  $ac_enable_session_tickets
793   OpenPGP support:      $ac_enable_openpgp
794   SRP support:          $ac_enable_srp
795   PSK support:          $ac_enable_psk
796   DHE support:          $ac_enable_dhe
797   ECDHE support:        $ac_enable_ecdhe
798   RSA-EXPORT support:   $ac_enable_rsa_export
799   Anon auth support:    $ac_enable_anon
800   Heartbeat support:    $ac_enable_heartbeat
801   Unicode support:      $ac_have_unicode
802   Self checks:          $enable_self_checks
803   Non-SuiteB curves:    $enable_non_suiteb
804   FIPS140 mode:         $enable_fips
805 ])
806
807 AC_MSG_NOTICE([Optional applications:
808
809   crywrap app:          $libidn
810 ])
811
812 AC_MSG_NOTICE([Optional libraries:
813
814   Guile wrappers:       $opt_guile_bindings
815   C++ library:          $use_cxx
816   DANE library:         $enable_dane
817   OpenSSL compat:       $enable_openssl
818 ])
819
820 AC_MSG_NOTICE([System files:
821
822   Trust store pkcs11:   $with_default_trust_store_pkcs11
823   Trust store file:     $with_default_trust_store_file
824   Blacklist file:       $with_default_blacklist_file
825   CRL file:             $with_default_crl_file
826   Priority file:        $system_priority_file
827   DNSSEC root key file: $unbound_root_key_file
828 ])
829
830 if test ! -f "$unbound_root_key_file"; then
831 AC_MSG_WARN([[
832 *** 
833 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
834 *** This file is needed for the verification of DNSSEC responses.
835 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
836 *** to generate or update it.
837 *** ]])
838 fi