[PATCH] Update to use new p11-kit APIs
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.2.6], [bug-gnutls@gnu.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 AM_PROG_AS
41 AM_PROG_AR
42 AC_PROG_CXX
43
44 # For includes/gnutls/gnutls.h.in.
45 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
46 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
47 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
48 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
49
50 touch suppressions.valgrind
51 dnl C and C++ capabilities
52 AC_C_INLINE
53 AC_HEADER_STDC
54
55 # For the C++ code
56 AC_ARG_ENABLE(cxx,
57   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
58     use_cxx=$enableval, use_cxx=yes)
59 if test "$use_cxx" != "no"; then
60   AC_LANG_PUSH(C++)
61   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
62   AC_LANG_POP(C++)
63 fi
64 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
65 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
66
67 dnl Detect windows build
68 case "$host" in
69   *mingw32* | *mingw64*)
70     have_win=yes
71   ;;
72   *darwin*)
73     have_macosx=yes
74   ;;
75   *)
76     have_elf=yes
77   ;;
78 esac
79
80 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
81 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
82 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
83
84 dnl Hardware Acceleration
85 AC_ARG_ENABLE(hardware-acceleration,
86   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
87     use_accel=$enableval, use_accel=yes)
88 hw_accel=none
89
90
91 if test "$use_accel" != "no"; then
92 case $host_cpu in
93   i?86 | x86_64 | amd64)
94       AC_CHECK_HEADERS(cpuid.h)
95       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
96         hw_accel="x86-64"
97       else
98         hw_accel="x86"
99       fi
100   ;;
101   *)
102   ;;
103 esac
104
105 fi
106
107 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
108 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
109 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
110 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
111 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
112
113 dnl Try the hooks.m4
114 LIBGNUTLS_HOOKS
115 LIBGNUTLS_EXTRA_HOOKS
116
117 AC_ARG_ENABLE(doc,
118   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
119     enable_doc=$enableval, enable_doc=yes)
120 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
121
122 AC_ARG_ENABLE(tests,
123   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
124     enable_tests=$enableval, enable_tests=yes)
125 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
126
127 GTK_DOC_CHECK(1.1)
128 AM_GNU_GETTEXT([external])
129 AM_GNU_GETTEXT_VERSION([0.18])
130
131 AC_C_BIGENDIAN
132
133 gl_INIT
134
135 dnl GCC warnings to enable
136
137 AC_ARG_ENABLE([gcc-warnings],
138   [AS_HELP_STRING([--enable-gcc-warnings],
139                   [turn on lots of GCC warnings (for developers)])],
140   [case $enableval in
141      yes|no) ;;
142      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
143    esac
144    gl_gcc_warnings=$enableval],
145   [gl_gcc_warnings=no]
146 )
147
148 if test "$gl_gcc_warnings" = yes; then
149   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
150
151   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
152   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
153   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
154   nw="$nw -Wtraditional"            # Warns on #elif which we use often
155   nw="$nw -Wlogical-op"             # Too many false positives
156   nw="$nw -Wold-style-definition"   # 
157   nw="$nw -Wpadded"                 # Our structs are not padded
158   nw="$nw -Wunreachable-code"       # Too many false positives
159   nw="$nw -Wtraditional-conversion" # Too many warnings for now
160   nw="$nw -Wcast-qual"              # Too many warnings for now
161   nw="$nw -Waggregate-return"       # Too many warnings for now
162   nw="$nw -Wshadow"                 # Too many warnings for now
163   nw="$nw -Wswitch-default"         # Too many warnings for now
164   nw="$nw -Wswitch-enum"            # Too many warnings for now
165   nw="$nw -Wconversion"             # Too many warnings for now
166   nw="$nw -Wsign-conversion"        # Too many warnings for now
167   nw="$nw -Wformat-y2k"             # Too many warnings for now
168   nw="$nw -Woverlength-strings"     # We use some in tests/
169   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
170   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
171   nw="$nw -Wunsafe-loop-optimizations"
172   nw="$nw -Wstrict-overflow"
173   nw="$nw -Wmissing-noreturn"
174   nw="$nw -Winline"                 # Too compiler dependent
175   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
176   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
177   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
178   nw="$nw -Wstack-protector"        # Some functions cannot be protected
179   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
180
181   gl_MANYWARN_ALL_GCC([ws])
182   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
183   for w in $ws; do
184     gl_WARN_ADD([$w])
185   done
186
187   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
188   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
189   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
190   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
191   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
192   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
193   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
194   gl_WARN_ADD([-fdiagnostics-show-option])
195 fi
196
197 AC_SUBST([WERROR_CFLAGS])
198 AC_SUBST([WSTACK_CFLAGS])
199 AC_SUBST([WARN_CFLAGS])
200
201 dnl Programs for compilation or development
202 AC_PROG_LN_S
203 AC_LIBTOOL_WIN32_DLL
204 AC_PROG_LIBTOOL
205
206
207 dnl No fork on MinGW, disable some self-tests until we fix them.
208 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
209 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)
210 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
211
212 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
213 #include <signal.h>
214 ], [timer_create (0,0,0);])
215
216 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
217   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
218 fi
219
220 if test "$ac_cv_func_nanosleep" != "yes";then
221   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
222 fi
223
224 ac_have_unicode=no
225 if test "$ac_cv_func_iconv" != "yes";then
226   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
227   if test "$HAVE_LIBICONV" = "yes";then
228     ac_have_unicode=yes
229   fi
230 else
231   ac_have_unicode=yes
232 fi
233
234 if test "$ac_have_unicode" != "yes";then
235   if test "$have_win" = "yes";then
236     ac_have_unicode=yes
237   fi
238 fi
239
240 AC_MSG_CHECKING([whether to build libdane])
241 AC_ARG_ENABLE(libdane,
242     AS_HELP_STRING([--disable-libdane],
243                    [disable the built of libdane]),
244     enable_dane=$enableval, enable_dane=yes)
245 AC_MSG_RESULT($enable_dane)
246
247 if test "$enable_dane" != "no"; then
248     LIBS="$oldlibs -lunbound"
249     AC_MSG_CHECKING([for unbound library])
250     AC_LINK_IFELSE([AC_LANG_PROGRAM([
251                    #include <unbound.h>],[
252                    struct ub_ctx* ctx;
253                    ctx = ub_ctx_create();])],
254                   [AC_MSG_RESULT(yes)
255                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
256                    AC_SUBST([UNBOUND_CFLAGS], [])
257                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
258                    enable_dane=yes],
259                   [AC_MSG_RESULT(no)
260                    AC_MSG_WARN([[
261 *** 
262 *** libunbound was not found. Libdane will not be built.
263 *** ]])
264                   enable_dane=no])
265     LIBS="$oldlibs"
266 fi
267
268 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
269
270 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
271                                  [specify the unbound root key file]),
272             unbound_root_key_file="$withval", 
273 if test "$have_win" = yes; then
274     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
275 else
276     unbound_root_key_file="/etc/unbound/root.key"
277 fi
278 )
279
280 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
281   ["$unbound_root_key_file"], [The DNSSEC root key file])
282
283 dnl Check for p11-kit
284 P11_KIT_MINIMUM=0.19.1
285 AC_ARG_WITH(p11-kit,
286         AS_HELP_STRING([--without-p11-kit],
287                 [Build without p11-kit and PKCS#11 support]))
288 if test "$with_p11_kit" != "no"; then
289         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
290         if test "$with_p11_kit" != "no";then
291                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
292                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
293                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
294                 else
295                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
296                 fi
297         else
298                 with_p11_kit=no
299                 AC_MSG_WARN([[
300 *** 
301 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
302 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
303 *** ]])
304         fi
305 fi
306
307 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
308
309 AC_ARG_WITH(tpm,
310         AS_HELP_STRING([--without-tpm],
311                 [Disable TPM (trousers) support.]),
312                 [with_tpm=$withval], [with_tpm=yes])
313 if test "$with_tpm" != "no"; then
314     LIBS="$oldlibs -ltspi"
315     AC_MSG_CHECKING([for tss library])
316     AC_LINK_IFELSE([AC_LANG_PROGRAM([
317                    #include <trousers/tss.h>
318                    #include <trousers/trousers.h>],[
319                    int err = Tspi_Context_Create((void *)0);
320                    Trspi_Error_String(err);])],
321                   [AC_MSG_RESULT(yes)
322                    AC_SUBST([TSS_LIBS], [-ltspi])
323                    AC_SUBST([TSS_CFLAGS], [])
324                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
325                    with_tpm=yes],
326                   [AC_MSG_RESULT(no)
327                    AC_MSG_WARN([[
328 *** 
329 *** trousers was not found. TPM support will be disabled.
330 *** ]])
331                   with_tpm=no])
332     LIBS="$oldlibs"
333 fi
334
335 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
336
337 enable_local_libopts=yes
338 dnl PKG_CHECK_MODULES([autoopts], autoopts >= 36.2.11,, [enable_local_libopts=yes])
339
340 NEED_LIBOPTS_DIR=true
341 LIBOPTS_CHECK([src/libopts])
342
343 AC_CHECK_TYPE(ssize_t,
344   [
345     DEFINE_SSIZE_T="#include <sys/types.h>"
346     AC_SUBST(DEFINE_SSIZE_T)
347   ], [
348     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
349     DEFINE_SSIZE_T="typedef int ssize_t;"
350     AC_SUBST(DEFINE_SSIZE_T)
351   ], [
352     #include <sys/types.h>
353   ])
354
355 # For minitasn1.
356 AC_CHECK_SIZEOF(unsigned long int, 4)
357 AC_CHECK_SIZEOF(unsigned int, 4)
358
359 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
360                                  [disable zlib compression support]),
361             ac_zlib=$withval, ac_zlib=yes)
362 AC_MSG_CHECKING([whether to include zlib compression support])
363 if test x$ac_zlib != xno; then
364  AC_MSG_RESULT(yes)
365  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
366  if test x$ac_cv_libz != xyes; then
367    AC_MSG_WARN(
368 *** 
369 *** ZLIB was not found. You will not be able to use ZLIB compression.)
370  fi
371 else
372  AC_MSG_RESULT(no)
373 fi
374
375 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
376
377 if test x$ac_zlib != xno; then
378   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
379     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
380       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
381     else
382       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
383     fi
384   fi
385 fi
386 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
387
388
389
390 AC_ARG_WITH([default-trust-store-pkcs11],
391   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
392     [use the given pkcs11 uri as default trust store])])
393
394 if test "x$with_default_trust_store_pkcs11" != x; then
395   if test "x$with_p11_kit" = xno; then
396     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
397   fi
398   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
399     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
400 fi
401
402 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
403 AC_ARG_WITH([default-trust-store-file],
404   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
405     [use the given file default trust store])], with_default_trust_store_file="$withval",
406   [if test "$build" = "$host";then
407   for i in \
408     /etc/ssl/ca-bundle.pem \
409     /etc/ssl/certs/ca-certificates.crt \
410     /etc/pki/tls/cert.pem \
411     /usr/local/share/certs/ca-root-nss.crt \
412     /etc/ssl/cert.pem
413     do
414     if test -e $i; then
415       with_default_trust_store_file="$i"
416       break
417     fi
418   done
419   fi]
420 )
421
422 if test "$with_default_trust_store_file" = "no";then
423   with_default_trust_store_file=""
424 fi
425
426 AC_ARG_WITH([default-crl-file],
427   [AS_HELP_STRING([--with-default-crl-file=FILE],
428     [use the given CRL file as default])])
429
430 if test "x$with_default_trust_store_file" != x; then
431   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
432     ["$with_default_trust_store_file"], [use the given file default trust store])
433 fi
434
435 if test "x$with_default_crl_file" != x; then
436   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
437     ["$with_default_crl_file"], [use the given CRL file])
438 fi
439
440 dnl Guile bindings.
441 opt_guile_bindings=yes
442 AC_MSG_CHECKING([whether building Guile bindings])
443 AC_ARG_ENABLE(guile,
444         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
445 opt_guile_bindings=$enableval)
446 AC_MSG_RESULT($opt_guile_bindings)
447
448 AC_ARG_WITH([guile-site-dir],
449   [AS_HELP_STRING([--with-guile-site-dir],
450      [use the given directory as the Guile site (use with care)])])
451
452 if test "$opt_guile_bindings" = "yes"; then
453    AC_MSG_RESULT([***
454 *** Detecting GNU Guile...
455 ])
456
457    AC_PATH_PROG([guile_snarf], [guile-snarf])
458    if test "x$guile_snarf" = "x"; then
459       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
460       opt_guile_bindings=no
461    else
462       GUILE_PROGS
463       GUILE_FLAGS
464
465       save_CFLAGS="$CFLAGS"
466       save_LIBS="$LIBS"
467       CFLAGS="$CFLAGS $GUILE_CFLAGS"
468       LIBS="$LIBS $GUILE_LDFLAGS"
469       AC_MSG_CHECKING([whether GNU Guile is recent enough])
470       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
471         [], [opt_guile_bindings=no])
472       CFLAGS="$save_CFLAGS"
473       LIBS="$save_LIBS"
474
475       if test "$opt_guile_bindings" = "yes"; then
476         AC_MSG_RESULT([yes])
477         case "x$with_guile_site_dir" in 
478              xno)
479                 # Use the default $(GUILE_SITE).
480                 GUILE_SITE_DIR
481                 ;;
482              x|xyes)
483                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
484                 # hack is used to allow `distcheck' to work (see
485                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
486                 GUILE_SITE="\$(datadir)/guile/site"
487                 AC_SUBST(GUILE_SITE)
488                 ;;
489              *)
490                 # Use the user-specified directory as $(GUILE_SITE).
491                 GUILE_SITE="$with_guile_site_dir"
492                 AC_SUBST(GUILE_SITE)
493                 ;;
494         esac
495         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
496         _gcc_cflags_save="$CFLAGS"
497         CFLAGS="${CFLAGS} -fgnu89-inline"
498         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
499                           gnu89_inline=yes, gnu89_inline=no)
500         AC_MSG_RESULT($gnu89_inline)
501         CFLAGS="$_gcc_cflags_save"
502
503         # Optional Guile functions.
504         save_CFLAGS="$CFLAGS"
505         save_LIBS="$LIBS"
506         CFLAGS="$CFLAGS $GUILE_CFLAGS"
507         LIBS="$LIBS $GUILE_LDFLAGS"
508         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
509         CFLAGS="$save_CFLAGS"
510         LIBS="$save_LIBS"
511
512         # The place where guile-gnutls.la will go.
513         AC_MSG_CHECKING([the Guile effective version])
514         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
515         AC_MSG_RESULT([$guile_effective_version])
516         guileextensiondir="$libdir/guile/$guile_effective_version"
517         AC_SUBST([guileextensiondir])
518       else
519         AC_MSG_RESULT([no])
520         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
521         opt_guile_bindings=no
522       fi
523    fi
524 fi
525 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
526
527 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
528 LIBGNUTLS_CFLAGS="-I${includedir}"
529 AC_SUBST(LIBGNUTLS_LIBS)
530 AC_SUBST(LIBGNUTLS_CFLAGS)
531
532
533 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
534 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
535
536 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
537 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
538 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
539
540 dnl Crywrap dependencies
541    AC_MSG_RESULT([***
542 *** Checking dependencies for crywrap...
543 ])
544
545 crywrap=no
546
547 if test "$have_win" != "yes"; then
548
549 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
550
551 dnl **********************
552 dnl * Typedefs & co
553 dnl **********************
554 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
555 [AC_LANG_PROGRAM([#include <sys/types.h>
556 #include <signal.h>
557 ],
558                  [return *(signal (0, 0)) (0) == 1;])],
559                    [ac_cv_type_signal=int],
560                    [ac_cv_type_signal=void])])
561 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
562                     (`int' or `void').])
563
564 AC_FUNC_SELECT_ARGTYPES
565 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
566                 putenv regcomp scandir select socket strcasecmp strchr \
567                 strdup strerror strncasecmp strrchr strstr strtoul uname])
568
569 AC_ARG_ENABLE(crywrap,
570         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
571
572  libidn=no
573
574  if test "x$enable_crywrap" != "xno" ; then
575         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
576         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
577  fi
578
579  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
580   crywrap=yes
581  fi
582
583 fi
584
585 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
586 rm -f suppressions.valgrind
587 dnl end of crywrap requirements
588
589 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
590 AC_CONFIG_FILES([
591   Makefile
592   doc/Makefile
593   doc/credentials/Makefile
594   doc/credentials/openpgp/Makefile
595   doc/credentials/srp/Makefile
596   doc/credentials/x509/Makefile
597   doc/cyclo/Makefile
598   doc/doxygen/Doxyfile
599   doc/examples/Makefile
600   doc/latex/Makefile
601   doc/manpages/Makefile
602   doc/reference/Makefile
603   doc/reference/version.xml
604   doc/scripts/Makefile
605   extra/Makefile
606   extra/includes/Makefile
607   libdane/Makefile
608   libdane/includes/Makefile
609   libdane/gnutls-dane.pc
610   gl/Makefile
611   gl/tests/Makefile
612   guile/Makefile
613   guile/modules/Makefile
614   guile/src/Makefile
615   guile/tests/Makefile
616   lib/Makefile
617   lib/accelerated/Makefile
618   lib/accelerated/x86/Makefile
619   lib/algorithms/Makefile
620   lib/auth/Makefile
621   lib/ext/Makefile
622   lib/extras/Makefile
623   lib/gnutls.pc
624   lib/includes/Makefile
625   lib/includes/gnutls/gnutls.h
626   lib/minitasn1/Makefile
627   lib/nettle/Makefile
628   lib/opencdk/Makefile
629   lib/openpgp/Makefile
630   lib/x509/Makefile
631   po/Makefile.in
632   src/Makefile
633   src/crywrap/Makefile
634   tests/Makefile
635   tests/cert-tests/Makefile
636   tests/dsa/Makefile
637   tests/dtls/Makefile
638   tests/srp/Makefile
639   tests/ecdsa/Makefile
640   tests/key-id/Makefile
641   tests/openpgp-certs/Makefile
642   tests/pkcs1-padding/Makefile
643   tests/pkcs12-decode/Makefile
644   tests/pkcs8-decode/Makefile
645   tests/rsa-md5-collision/Makefile
646   tests/safe-renegotiation/Makefile
647   tests/scripts/Makefile
648   tests/sha2/Makefile
649   tests/slow/Makefile
650   tests/suite/Makefile
651   tests/userid/Makefile
652 ])
653
654 AC_OUTPUT
655
656 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
657 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
658 AC_MSG_NOTICE([summary of build options:
659
660   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
661   Host/Target system:   ${host}
662   Build system:         ${build}
663   Install prefix:       ${prefix}
664   Compiler:             ${CC}
665   CFlags:               ${CFLAGS}
666   Library types:        Shared=${enable_shared}, Static=${enable_static}
667 ])
668
669 AC_MSG_NOTICE([External hardware support:
670
671   /dev/crypto:          $enable_cryptodev
672   Hardware accel:       $hw_accel
673   PKCS#11 support:      $with_p11_kit
674   TPM support:          $with_tpm
675 ])
676
677 AC_MSG_NOTICE([Optional features:
678 (note that included applications might not compile properly
679 if features are disabled)
680
681   DTLS-SRTP support:    $ac_enable_srtp
682   ALPN support:         $ac_enable_alpn
683   OCSP support:         $ac_enable_ocsp
684   OpenPGP support:      $ac_enable_openpgp
685   SRP support:          $ac_enable_srp
686   PSK support:          $ac_enable_psk
687   DHE support:          $ac_enable_dhe
688   ECDHE support:        $ac_enable_ecdhe
689   Anon auth support:    $ac_enable_anon
690   Heartbeat support:    $ac_enable_heartbeat
691   RSA-EXPORT compat:    $ac_enable_rsa_export
692   Unicode support:      $ac_have_unicode
693 ])
694
695 AC_MSG_NOTICE([Optional applications:
696
697   crywrap app:          $libidn
698   local libopts:        $enable_local_libopts
699 ])
700
701 AC_MSG_NOTICE([Optional libraries:
702
703   Guile wrappers:       $opt_guile_bindings
704   C++ library:          $use_cxx
705   DANE library:         $enable_dane
706   OpenSSL compat:       $enable_openssl
707 ])
708
709 AC_MSG_NOTICE([System files:
710
711   Trust store pkcs:     $with_default_trust_store_pkcs11
712   Trust store file:     $with_default_trust_store_file
713   CRL file:             $with_default_crl_file
714   DNSSEC root key file: $unbound_root_key_file
715 ])
716
717 if test ! -f "$unbound_root_key_file"; then
718 AC_MSG_WARN([[
719 *** 
720 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
721 *** This file is needed for the verification of DNSSEC responses.
722 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
723 *** to generate or update it.
724 *** ]])
725 fi