link with libiconv when needed.
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.2.3], [bug-gnutls@gnu.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 AM_PROG_AS
41 AM_PROG_AR
42 AC_PROG_CXX
43
44 # For includes/gnutls/gnutls.h.in.
45 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
46 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
47 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
48 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
49
50 touch suppressions.valgrind
51 dnl C and C++ capabilities
52 AC_C_INLINE
53 AC_HEADER_STDC
54
55 # For the C++ code
56 AC_ARG_ENABLE(cxx,
57   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
58     use_cxx=$enableval, use_cxx=yes)
59 if test "$use_cxx" != "no"; then
60   AC_LANG_PUSH(C++)
61   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
62   AC_LANG_POP(C++)
63 fi
64 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
65 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
66
67 dnl Detect windows build
68 case "$host" in
69   *mingw32* | *mingw64*)
70     have_win=yes
71   ;;
72   *darwin*)
73     have_macosx=yes
74   ;;
75   *)
76     have_elf=yes
77   ;;
78 esac
79
80 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
81 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
82 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
83
84 dnl Hardware Acceleration
85 AC_ARG_ENABLE(hardware-acceleration,
86   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
87     use_accel=$enableval, use_accel=yes)
88 hw_accel=none
89
90
91 if test "$use_accel" != "no"; then
92 case $host_cpu in
93   i?86 | x86_64 | amd64)
94       AC_CHECK_HEADERS(cpuid.h)
95       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
96         hw_accel="x86-64"
97       else
98         hw_accel="x86"
99       fi
100   ;;
101   *)
102   ;;
103 esac
104
105 fi
106
107 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
108 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
109 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
110 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
111 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
112
113 dnl Try the hooks.m4
114 LIBGNUTLS_HOOKS
115 LIBGNUTLS_EXTRA_HOOKS
116
117 AC_ARG_ENABLE(doc,
118   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
119     enable_doc=$enableval, enable_doc=yes)
120 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
121
122 AC_ARG_ENABLE(tests,
123   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
124     enable_tests=$enableval, enable_tests=yes)
125 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
126
127 GTK_DOC_CHECK(1.1)
128 AM_GNU_GETTEXT([external])
129 AM_GNU_GETTEXT_VERSION([0.18])
130
131 AC_C_BIGENDIAN
132
133 gl_INIT
134
135 dnl GCC warnings to enable
136
137 AC_ARG_ENABLE([gcc-warnings],
138   [AS_HELP_STRING([--enable-gcc-warnings],
139                   [turn on lots of GCC warnings (for developers)])],
140   [case $enableval in
141      yes|no) ;;
142      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
143    esac
144    gl_gcc_warnings=$enableval],
145   [gl_gcc_warnings=no]
146 )
147
148 if test "$gl_gcc_warnings" = yes; then
149   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
150
151   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
152   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
153   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
154   nw="$nw -Wtraditional"            # Warns on #elif which we use often
155   nw="$nw -Wlogical-op"             # Too many false positives
156   nw="$nw -Wold-style-definition"   # 
157   nw="$nw -Wpadded"                 # Our structs are not padded
158   nw="$nw -Wunreachable-code"       # Too many false positives
159   nw="$nw -Wtraditional-conversion" # Too many warnings for now
160   nw="$nw -Wcast-qual"              # Too many warnings for now
161   nw="$nw -Waggregate-return"       # Too many warnings for now
162   nw="$nw -Wshadow"                 # Too many warnings for now
163   nw="$nw -Wswitch-default"         # Too many warnings for now
164   nw="$nw -Wswitch-enum"            # Too many warnings for now
165   nw="$nw -Wconversion"             # Too many warnings for now
166   nw="$nw -Wsign-conversion"        # Too many warnings for now
167   nw="$nw -Wformat-y2k"             # Too many warnings for now
168   nw="$nw -Woverlength-strings"     # We use some in tests/
169   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
170   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
171   nw="$nw -Wunsafe-loop-optimizations"
172   nw="$nw -Wstrict-overflow"
173   nw="$nw -Wmissing-noreturn"
174   nw="$nw -Winline"                 # Too compiler dependent
175   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
176   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
177   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
178   nw="$nw -Wstack-protector"        # Some functions cannot be protected
179   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
180
181   gl_MANYWARN_ALL_GCC([ws])
182   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
183   for w in $ws; do
184     gl_WARN_ADD([$w])
185   done
186
187   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
188   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
189   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
190   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
191   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
192   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
193   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
194   gl_WARN_ADD([-fdiagnostics-show-option])
195 fi
196
197 AC_SUBST([WERROR_CFLAGS])
198 AC_SUBST([WSTACK_CFLAGS])
199 AC_SUBST([WARN_CFLAGS])
200
201 dnl Programs for compilation or development
202 AC_PROG_LN_S
203 AC_LIBTOOL_WIN32_DLL
204 AC_PROG_LIBTOOL
205
206
207 dnl No fork on MinGW, disable some self-tests until we fix them.
208 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
209 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv],,)
210 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
211
212 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
213   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
214 fi
215
216 if test "$ac_cv_func_nanosleep" != "yes";then
217   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
218 fi
219
220 if test "$ac_cv_func_iconv" != "yes";then
221   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
222   if test "$HAVE_LIBICONV" = "yes";then
223     ac_have_unicode=yes
224   fi
225 else
226   ac_have_unicode=yes
227 fi
228
229 AC_MSG_CHECKING([whether to build libdane])
230 AC_ARG_ENABLE(libdane,
231     AS_HELP_STRING([--disable-libdane],
232                    [disable the built of libdane]),
233     enable_dane=$enableval, enable_dane=yes)
234 AC_MSG_RESULT($enable_dane)
235
236 if test "$enable_dane" != "no"; then
237     LIBS="$oldlibs -lunbound"
238     AC_MSG_CHECKING([for unbound library])
239     AC_LINK_IFELSE([AC_LANG_PROGRAM([
240                    #include <unbound.h>],[
241                    struct ub_ctx* ctx;
242                    ctx = ub_ctx_create();])],
243                   [AC_MSG_RESULT(yes)
244                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
245                    AC_SUBST([UNBOUND_CFLAGS], [])
246                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
247                    enable_dane=yes],
248                   [AC_MSG_RESULT(no)
249                    AC_MSG_WARN([[
250 *** 
251 *** libunbound was not found. Libdane will not be built.
252 *** ]])
253                   enable_dane=no])
254     LIBS="$oldlibs"
255 fi
256
257 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
258
259 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
260                                  [specify the unbound root key file]),
261             unbound_root_key_file="$withval", 
262 if test "$have_win" = yes; then
263     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
264 else
265     unbound_root_key_file="/etc/unbound/root.key"
266 fi
267 )
268
269 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
270   ["$unbound_root_key_file"], [The DNSSEC root key file])
271
272 dnl Check for p11-kit
273 AC_ARG_WITH(p11-kit,
274         AS_HELP_STRING([--without-p11-kit],
275                 [Build without p11-kit and PKCS#11 support]))
276 if test "$with_p11_kit" != "no"; then
277         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.11], [with_p11_kit=yes], [with_p11_kit=no])
278         if test "$with_p11_kit" != "no";then
279                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
280                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
281                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
282                 else
283                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
284                 fi
285         else
286                 with_p11_kit=no
287                 AC_MSG_WARN([[
288 *** 
289 *** p11-kit was not found. PKCS #11 support will be disabled.
290 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
291 *** ]])
292         fi
293 fi
294
295 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
296
297 AC_ARG_WITH(tpm,
298         AS_HELP_STRING([--with-tpm],
299                 [Build with TPM (trousers) support. Note that trousers is under the Common Public License and incompatible with GPL programs.]),
300                 [with_tpm=$withval], [with_tpm=no])
301 if test "$with_tpm" != "no"; then
302     LIBS="$oldlibs -ltspi"
303     AC_MSG_CHECKING([for tss library])
304     AC_LINK_IFELSE([AC_LANG_PROGRAM([
305                    #include <trousers/tss.h>
306                    #include <trousers/trousers.h>],[
307                    int err = Tspi_Context_Create((void *)0);
308                    Trspi_Error_String(err);])],
309                   [AC_MSG_RESULT(yes)
310                    AC_SUBST([TSS_LIBS], [-ltspi])
311                    AC_SUBST([TSS_CFLAGS], [])
312                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
313                    with_tpm=yes],
314                   [AC_MSG_RESULT(no)
315                    AC_MSG_WARN([[
316 *** 
317 *** trousers was not found. TPM support will be disabled.
318 *** ]])
319                   with_tpm=no])
320     LIBS="$oldlibs"
321 fi
322
323 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
324
325 enable_local_libopts=yes
326 dnl PKG_CHECK_MODULES([autoopts], autoopts >= 36.2.11,, [enable_local_libopts=yes])
327
328 NEED_LIBOPTS_DIR=true
329 LIBOPTS_CHECK([src/libopts])
330
331 AC_CHECK_TYPE(ssize_t,
332   [
333     DEFINE_SSIZE_T="#include <sys/types.h>"
334     AC_SUBST(DEFINE_SSIZE_T)
335   ], [
336     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
337     DEFINE_SSIZE_T="typedef int ssize_t;"
338     AC_SUBST(DEFINE_SSIZE_T)
339   ], [
340     #include <sys/types.h>
341   ])
342
343 # For minitasn1.
344 AC_CHECK_SIZEOF(unsigned long int, 4)
345 AC_CHECK_SIZEOF(unsigned int, 4)
346
347 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
348                                  [disable zlib compression support]),
349             ac_zlib=$withval, ac_zlib=yes)
350 AC_MSG_CHECKING([whether to include zlib compression support])
351 if test x$ac_zlib != xno; then
352  AC_MSG_RESULT(yes)
353  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
354  if test x$ac_cv_libz != xyes; then
355    AC_MSG_WARN(
356 *** 
357 *** ZLIB was not found. You will not be able to use ZLIB compression.)
358  fi
359 else
360  AC_MSG_RESULT(no)
361 fi
362
363 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
364
365 if test x$ac_zlib != xno; then
366   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
367     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
368       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
369     else
370       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
371     fi
372   fi
373 fi
374 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
375
376
377
378 AC_ARG_WITH([default-trust-store-pkcs11],
379   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
380     [use the given pkcs11 uri as default trust store])])
381
382 if test "x$with_default_trust_store_pkcs11" != x; then
383   if test "x$with_p11_kit" = xno; then
384     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
385   fi
386   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
387     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
388 fi
389
390 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
391 AC_ARG_WITH([default-trust-store-file],
392   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
393     [use the given file default trust store])], with_default_trust_store_file="$withval",
394   [if test "$build" = "$host";then
395   for i in \
396     /etc/ssl/ca-bundle.pem \
397     /etc/ssl/certs/ca-certificates.crt \
398     /etc/pki/tls/cert.pem \
399     /usr/local/share/certs/ca-root-nss.crt \
400     /etc/ssl/cert.pem
401     do
402     if test -e $i; then
403       with_default_trust_store_file="$i"
404       break
405     fi
406   done
407   fi]
408 )
409
410 if test "$with_default_trust_store_file" = "no";then
411   with_default_trust_store_file=""
412 fi
413
414 AC_ARG_WITH([default-crl-file],
415   [AS_HELP_STRING([--with-default-crl-file=FILE],
416     [use the given CRL file as default])])
417
418 if test "x$with_default_trust_store_file" != x; then
419   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
420     ["$with_default_trust_store_file"], [use the given file default trust store])
421 fi
422
423 if test "x$with_default_crl_file" != x; then
424   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
425     ["$with_default_crl_file"], [use the given CRL file])
426 fi
427
428 dnl Guile bindings.
429 opt_guile_bindings=yes
430 AC_MSG_CHECKING([whether building Guile bindings])
431 AC_ARG_ENABLE(guile,
432         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
433 opt_guile_bindings=$enableval)
434 AC_MSG_RESULT($opt_guile_bindings)
435
436 AC_ARG_WITH([guile-site-dir],
437   [AS_HELP_STRING([--with-guile-site-dir],
438      [use the given directory as the Guile site (use with care)])])
439
440 if test "$opt_guile_bindings" = "yes"; then
441    AC_MSG_RESULT([***
442 *** Detecting GNU Guile...
443 ])
444
445    AC_PATH_PROG([guile_snarf], [guile-snarf])
446    if test "x$guile_snarf" = "x"; then
447       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
448       opt_guile_bindings=no
449    else
450       GUILE_PROGS
451       GUILE_FLAGS
452
453       save_CFLAGS="$CFLAGS"
454       save_LIBS="$LIBS"
455       CFLAGS="$CFLAGS $GUILE_CFLAGS"
456       LIBS="$LIBS $GUILE_LDFLAGS"
457       AC_MSG_CHECKING([whether GNU Guile is recent enough])
458       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
459         [], [opt_guile_bindings=no])
460       CFLAGS="$save_CFLAGS"
461       LIBS="$save_LIBS"
462
463       if test "$opt_guile_bindings" = "yes"; then
464         AC_MSG_RESULT([yes])
465         case "x$with_guile_site_dir" in 
466              xno)
467                 # Use the default $(GUILE_SITE).
468                 GUILE_SITE_DIR
469                 ;;
470              x|xyes)
471                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
472                 # hack is used to allow `distcheck' to work (see
473                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
474                 GUILE_SITE="\$(datadir)/guile/site"
475                 AC_SUBST(GUILE_SITE)
476                 ;;
477              *)
478                 # Use the user-specified directory as $(GUILE_SITE).
479                 GUILE_SITE="$with_guile_site_dir"
480                 AC_SUBST(GUILE_SITE)
481                 ;;
482         esac
483         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
484         _gcc_cflags_save="$CFLAGS"
485         CFLAGS="${CFLAGS} -fgnu89-inline"
486         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
487                           gnu89_inline=yes, gnu89_inline=no)
488         AC_MSG_RESULT($gnu89_inline)
489         CFLAGS="$_gcc_cflags_save"
490
491         # Optional Guile functions.
492         save_CFLAGS="$CFLAGS"
493         save_LIBS="$LIBS"
494         CFLAGS="$CFLAGS $GUILE_CFLAGS"
495         LIBS="$LIBS $GUILE_LDFLAGS"
496         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
497         CFLAGS="$save_CFLAGS"
498         LIBS="$save_LIBS"
499
500         # The place where guile-gnutls.la will go.
501         AC_MSG_CHECKING([the Guile effective version])
502         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
503         AC_MSG_RESULT([$guile_effective_version])
504         guileextensiondir="$libdir/guile/$guile_effective_version"
505         AC_SUBST([guileextensiondir])
506       else
507         AC_MSG_RESULT([no])
508         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
509         opt_guile_bindings=no
510       fi
511    fi
512 fi
513 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
514
515 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
516 LIBGNUTLS_CFLAGS="-I${includedir}"
517 AC_SUBST(LIBGNUTLS_LIBS)
518 AC_SUBST(LIBGNUTLS_CFLAGS)
519
520
521 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
522 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
523
524 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
525 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
526 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
527
528 dnl Crywrap dependencies
529    AC_MSG_RESULT([***
530 *** Checking dependencies for crywrap...
531 ])
532
533 crywrap=no
534
535 if test "$have_win" != "yes"; then
536
537 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
538
539 dnl **********************
540 dnl * Typedefs & co
541 dnl **********************
542 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
543 [AC_LANG_PROGRAM([#include <sys/types.h>
544 #include <signal.h>
545 ],
546                  [return *(signal (0, 0)) (0) == 1;])],
547                    [ac_cv_type_signal=int],
548                    [ac_cv_type_signal=void])])
549 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
550                     (`int' or `void').])
551
552 AC_FUNC_SELECT_ARGTYPES
553 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
554                 putenv regcomp scandir select socket strcasecmp strchr \
555                 strdup strerror strncasecmp strrchr strstr strtoul uname])
556
557 AC_ARG_ENABLE(crywrap,
558         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
559
560  libidn=no
561
562  if test "x$enable_crywrap" != "xno" ; then
563         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
564  fi
565
566  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no";then
567   crywrap=yes
568  fi
569
570 fi
571
572 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
573 rm -f suppressions.valgrind
574 dnl end of crywrap requirements
575
576 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
577 AC_CONFIG_FILES([
578   Makefile
579   doc/Makefile
580   doc/credentials/Makefile
581   doc/credentials/openpgp/Makefile
582   doc/credentials/srp/Makefile
583   doc/credentials/x509/Makefile
584   doc/cyclo/Makefile
585   doc/doxygen/Doxyfile
586   doc/examples/Makefile
587   doc/latex/Makefile
588   doc/manpages/Makefile
589   doc/reference/Makefile
590   doc/reference/version.xml
591   doc/scripts/Makefile
592   extra/Makefile
593   extra/includes/Makefile
594   libdane/Makefile
595   libdane/includes/Makefile
596   libdane/gnutls-dane.pc
597   gl/Makefile
598   gl/tests/Makefile
599   guile/Makefile
600   guile/modules/Makefile
601   guile/src/Makefile
602   guile/tests/Makefile
603   lib/Makefile
604   lib/accelerated/Makefile
605   lib/accelerated/x86/Makefile
606   lib/algorithms/Makefile
607   lib/auth/Makefile
608   lib/ext/Makefile
609   lib/extras/Makefile
610   lib/gnutls.pc
611   lib/includes/Makefile
612   lib/includes/gnutls/gnutls.h
613   lib/minitasn1/Makefile
614   lib/nettle/Makefile
615   lib/opencdk/Makefile
616   lib/openpgp/Makefile
617   lib/x509/Makefile
618   po/Makefile.in
619   src/Makefile
620   src/crywrap/Makefile
621   tests/Makefile
622   tests/cert-tests/Makefile
623   tests/dsa/Makefile
624   tests/dtls/Makefile
625   tests/srp/Makefile
626   tests/ecdsa/Makefile
627   tests/key-id/Makefile
628   tests/openpgp-certs/Makefile
629   tests/pkcs1-padding/Makefile
630   tests/pkcs12-decode/Makefile
631   tests/pkcs8-decode/Makefile
632   tests/rsa-md5-collision/Makefile
633   tests/safe-renegotiation/Makefile
634   tests/scripts/Makefile
635   tests/sha2/Makefile
636   tests/slow/Makefile
637   tests/suite/Makefile
638   tests/userid/Makefile
639 ])
640
641 AC_OUTPUT
642
643 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
644 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
645 AC_MSG_NOTICE([summary of build options:
646
647   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
648   Host/Target system:   ${host}
649   Build system:         ${build}
650   Install prefix:       ${prefix}
651   Compiler:             ${CC}
652   CFlags:               ${CFLAGS}
653   Library types:        Shared=${enable_shared}, Static=${enable_static}
654 ])
655
656 AC_MSG_NOTICE([External hardware support:
657
658   /dev/crypto:          $enable_cryptodev
659   Hardware accel:       $hw_accel
660   PKCS#11 support:      $with_p11_kit
661   TPM support:          $with_tpm
662 ])
663
664 AC_MSG_NOTICE([Optional features:
665 (note that included applications might not compile properly
666 if features are disabled)
667
668   DTLS-SRTP support:    $ac_enable_srtp
669   ALPN support:         $ac_enable_alpn
670   OCSP support:         $ac_enable_ocsp
671   OpenPGP support:      $ac_enable_openpgp
672   SRP support:          $ac_enable_srp
673   PSK support:          $ac_enable_psk
674   DHE support:          $ac_enable_dhe
675   ECDHE support:        $ac_enable_ecdhe
676   Anon auth support:    $ac_enable_anon
677   Heartbeat support:    $ac_enable_heartbeat
678   RSA-EXPORT compat:    $ac_enable_rsa_export
679   Unicode support:      $ac_have_unicode
680 ])
681
682 AC_MSG_NOTICE([Optional applications:
683
684   crywrap app:          $libidn
685   local libopts:        $enable_local_libopts
686 ])
687
688 AC_MSG_NOTICE([Optional libraries:
689
690   Guile wrappers:       $opt_guile_bindings
691   C++ library:          $use_cxx
692   DANE library:         $enable_dane
693   OpenSSL compat:       $enable_openssl
694 ])
695
696 AC_MSG_NOTICE([System files:
697
698   Trust store pkcs:     $with_default_trust_store_pkcs11
699   Trust store file:     $with_default_trust_store_file
700   CRL file:             $with_default_crl_file
701   DNSSEC root key file: $unbound_root_key_file
702 ])
703
704 if test ! -f "$unbound_root_key_file"; then
705 AC_MSG_WARN([[
706 *** 
707 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
708 *** This file is needed for the verification of DNSSEC responses.
709 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
710 *** to generate or update it.
711 *** ]])
712 fi