Ported libgcrypt's AES-based DRBG.
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.3.0], [bugs@gnutls.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 ggl_EARLY
41 AM_PROG_AS
42 AM_PROG_AR
43 AC_PROG_CXX
44 AM_PROG_CC_C_O
45 AC_PROG_YACC
46 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
47
48 if test x"$AUTOGEN" = "x/bin/true"; then
49   AC_MSG_WARN([[
50 ***
51 *** autogen not found. Will not link against libopts.
52 *** ]])
53 enable_local_libopts=yes
54 fi
55
56 # For includes/gnutls/gnutls.h.in.
57 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
58 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
59 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
60 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
61
62 touch suppressions.valgrind
63 dnl C and C++ capabilities
64 AC_C_INLINE
65 AC_HEADER_STDC
66
67 # For the C++ code
68 AC_ARG_ENABLE(cxx,
69   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
70     use_cxx=$enableval, use_cxx=yes)
71 if test "$use_cxx" != "no"; then
72   AC_LANG_PUSH(C++)
73   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
74   AC_LANG_POP(C++)
75 fi
76 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
77 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
78
79 dnl Detect windows build
80 case "$host" in
81   *mingw32* | *mingw64*)
82     have_win=yes
83   ;;
84   *darwin*)
85     have_macosx=yes
86   ;;
87   *)
88     have_elf=yes
89   ;;
90 esac
91
92 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
93 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
94 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
95
96 dnl Hardware Acceleration
97 AC_ARG_ENABLE(hardware-acceleration,
98   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
99     use_accel=$enableval, use_accel=yes)
100 hw_accel=none
101
102
103 if test "$use_accel" != "no"; then
104 case $host_cpu in
105   i?86 | x86_64 | amd64)
106       AC_CHECK_HEADERS(cpuid.h)
107       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
108         hw_accel="x86-64"
109       else
110         hw_accel="x86"
111       fi
112   ;;
113   *)
114   ;;
115 esac
116
117 fi
118
119 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
120 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
121 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
122 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
123 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
124
125 AC_ARG_ENABLE(self-checks,
126   AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),
127     enable_self_checks=$enableval, enable_self_checks=no)
128
129 AC_ARG_ENABLE(fips140-mode,
130   AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),
131     enable_fips=$enableval, enable_fips=no)
132 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")
133 if [ test "$enable_fips" = "yes" ];then
134   AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])
135   if test "x$HAVE_LIBDL" = "xyes";then
136     enable_self_checks=yes
137
138     dnl clock_gettime precision is needed on the FIPS140 DRBG.
139     if test "$ac_cv_func_clock_gettime" != "yes";then
140       AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [clock_gettime (0, 0);])
141     fi
142
143     AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])
144
145     AC_SUBST([FIPS140_LIBS], $LIBDL)
146   else
147     enable_fips=no
148     AC_MSG_WARN([[
149 *** 
150 *** This system is not supported in FIPS140 mode.
151 *** libdl and dladdr() are required.
152 *** ]])
153   fi
154 fi
155
156 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")
157 if [ test "$enable_self_checks" = "yes" ];then
158    AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])
159 fi
160
161 dnl Try the hooks.m4
162 LIBGNUTLS_HOOKS
163 LIBGNUTLS_EXTRA_HOOKS
164
165 AC_ARG_ENABLE(doc,
166   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
167     enable_doc=$enableval, enable_doc=yes)
168 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
169
170 AC_ARG_ENABLE(tests,
171   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
172     enable_tests=$enableval, enable_tests=yes)
173 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
174
175 GTK_DOC_CHECK(1.1)
176 AM_GNU_GETTEXT([external])
177 AM_GNU_GETTEXT_VERSION([0.18])
178
179 AC_C_BIGENDIAN
180
181 gl_INIT
182 ggl_INIT
183
184 dnl GCC warnings to enable
185
186 AC_ARG_ENABLE([gcc-warnings],
187   [AS_HELP_STRING([--enable-gcc-warnings],
188                   [turn on lots of GCC warnings (for developers)])],
189   [case $enableval in
190      yes|no) ;;
191      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
192    esac
193    gl_gcc_warnings=$enableval],
194   [gl_gcc_warnings=no]
195 )
196
197 if test "$gl_gcc_warnings" = yes; then
198   gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])
199
200   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
201   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
202   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
203   nw="$nw -Wtraditional"            # Warns on #elif which we use often
204   nw="$nw -Wlogical-op"             # Too many false positives
205   nw="$nw -Wold-style-definition"   # 
206   nw="$nw -Wpadded"                 # Our structs are not padded
207   nw="$nw -Wunreachable-code"       # Too many false positives
208   nw="$nw -Wtraditional-conversion" # Too many warnings for now
209   nw="$nw -Wcast-qual"              # Too many warnings for now
210   nw="$nw -Waggregate-return"       # Too many warnings for now
211   nw="$nw -Wshadow"                 # Too many warnings for now
212   nw="$nw -Wswitch-default"         # Too many warnings for now
213   nw="$nw -Wswitch-enum"            # Too many warnings for now
214   nw="$nw -Wconversion"             # Too many warnings for now
215   nw="$nw -Wsign-conversion"        # Too many warnings for now
216   nw="$nw -Wformat-y2k"             # Too many warnings for now
217   nw="$nw -Woverlength-strings"     # We use some in tests/
218   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
219   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
220   nw="$nw -Wunsafe-loop-optimizations"
221   nw="$nw -Wstrict-overflow"
222   nw="$nw -Wmissing-noreturn"
223   nw="$nw -Winline"                 # Too compiler dependent
224   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
225   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
226   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
227   nw="$nw -Wstack-protector"        # Some functions cannot be protected
228   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
229
230   gl_MANYWARN_ALL_GCC([ws])
231   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
232   for w in $ws; do
233     gl_WARN_ADD([$w])
234   done
235
236   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
237   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
238   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
239   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
240   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
241   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
242   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
243   gl_WARN_ADD([-fdiagnostics-show-option])
244 fi
245
246 AC_SUBST([WERROR_CFLAGS])
247 AC_SUBST([WSTACK_CFLAGS])
248 AC_SUBST([WARN_CFLAGS])
249
250 dnl Programs for compilation or development
251 AC_PROG_LN_S
252 AC_LIBTOOL_WIN32_DLL
253 AC_PROG_LIBTOOL
254
255
256 dnl No fork on MinGW, disable some self-tests until we fix them.
257 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
258 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)
259 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
260
261 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
262 #include <signal.h>
263 ], [timer_create (0,0,0);])
264
265 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
266   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
267 fi
268
269 if test "$ac_cv_func_nanosleep" != "yes";then
270   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
271   gnutls_needs_librt=yes
272 fi
273
274 ac_have_unicode=no
275 if test "$ac_cv_func_iconv" != "yes";then
276   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
277   if test "$HAVE_LIBICONV" = "yes";then
278     ac_have_unicode=yes
279   fi
280 else
281   ac_have_unicode=yes
282 fi
283
284 if test "$ac_have_unicode" != "yes";then
285   if test "$have_win" = "yes";then
286     ac_have_unicode=yes
287   fi
288 fi
289
290 AC_MSG_CHECKING([whether to build libdane])
291 AC_ARG_ENABLE(libdane,
292     AS_HELP_STRING([--disable-libdane],
293                    [disable the built of libdane]),
294     enable_dane=$enableval, enable_dane=yes)
295 AC_MSG_RESULT($enable_dane)
296
297 if test "$enable_dane" != "no"; then
298     LIBS="$oldlibs -lunbound"
299     AC_MSG_CHECKING([for unbound library])
300     AC_LINK_IFELSE([AC_LANG_PROGRAM([
301                    #include <unbound.h>],[
302                    struct ub_ctx* ctx;
303                    ctx = ub_ctx_create();])],
304                   [AC_MSG_RESULT(yes)
305                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
306                    AC_SUBST([UNBOUND_CFLAGS], [])
307                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
308                    enable_dane=yes],
309                   [AC_MSG_RESULT(no)
310                    AC_MSG_WARN([[
311 *** 
312 *** libunbound was not found. Libdane will not be built.
313 *** ]])
314                   enable_dane=no])
315     LIBS="$oldlibs"
316 fi
317
318 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
319
320 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
321                                  [specify the unbound root key file]),
322             unbound_root_key_file="$withval", 
323 if test "$have_win" = yes; then
324     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
325 else
326     if test -f /var/lib/unbound/root.key;then
327         unbound_root_key_file="/var/lib/unbound/root.key"
328     else
329         unbound_root_key_file="/etc/unbound/root.key"
330     fi
331 fi
332 )
333
334 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
335   ["$unbound_root_key_file"], [The DNSSEC root key file])
336
337 dnl Check for p11-kit
338 P11_KIT_MINIMUM=0.19.1
339 AC_ARG_WITH(p11-kit,
340         AS_HELP_STRING([--without-p11-kit],
341                 [Build without p11-kit and PKCS#11 support]))
342 if test "$with_p11_kit" != "no"; then
343         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
344         if test "$with_p11_kit" != "no";then
345                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
346                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
347                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
348                 else
349                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
350                 fi
351         else
352                 with_p11_kit=no
353                 AC_MSG_WARN([[
354 *** 
355 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
356 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
357 *** ]])
358         fi
359 fi
360
361 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
362
363 AC_ARG_WITH(tpm,
364         AS_HELP_STRING([--without-tpm],
365                 [Disable TPM (trousers) support.]),
366                 [with_tpm=$withval], [with_tpm=yes])
367 if test "$with_tpm" != "no"; then
368     LIBS="$oldlibs -ltspi"
369     AC_MSG_CHECKING([for tss library])
370     AC_LINK_IFELSE([AC_LANG_PROGRAM([
371                    #include <trousers/tss.h>
372                    #include <trousers/trousers.h>],[
373                    int err = Tspi_Context_Create((void *)0);
374                    Trspi_Error_String(err);])],
375                   [AC_MSG_RESULT(yes)
376                    AC_SUBST([TSS_LIBS], [-ltspi])
377                    AC_SUBST([TSS_CFLAGS], [])
378                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
379                    with_tpm=yes],
380                   [AC_MSG_RESULT(no)
381                    AC_MSG_WARN([[
382 *** 
383 *** trousers was not found. TPM support will be disabled.
384 *** ]])
385                   with_tpm=no])
386     LIBS="$oldlibs"
387 fi
388
389 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
390
391 LIBOPTS_CHECK([src/libopts])
392 if test "$NEED_LIBOPTS_DIR" == "true";then
393         dnl delete libopts-generated files
394         for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do
395                 nam=`echo $i|sed 's/.bak//g'`
396                 if test -f $i;then
397                         cp -f $i $nam
398                 fi
399         done
400         AC_SUBST([AUTOGEN], [/bin/true])
401         enable_local_libopts=yes
402 else
403         enable_local_libopts=no
404 fi
405 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")
406
407 AC_CHECK_TYPE(ssize_t,
408   [
409     DEFINE_SSIZE_T="#include <sys/types.h>"
410     AC_SUBST(DEFINE_SSIZE_T)
411   ], [
412     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
413     DEFINE_SSIZE_T="typedef int ssize_t;"
414     AC_SUBST(DEFINE_SSIZE_T)
415   ], [
416     #include <sys/types.h>
417   ])
418
419 # For minitasn1.
420 AC_CHECK_SIZEOF(unsigned long int, 4)
421 AC_CHECK_SIZEOF(unsigned int, 4)
422
423 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
424                                  [disable zlib compression support]),
425             ac_zlib=$withval, ac_zlib=yes)
426 AC_MSG_CHECKING([whether to include zlib compression support])
427 if test x$ac_zlib != xno; then
428  AC_MSG_RESULT(yes)
429  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
430  if test x$ac_cv_libz != xyes; then
431    AC_MSG_WARN(
432 *** 
433 *** ZLIB was not found. You will not be able to use ZLIB compression.)
434  fi
435 else
436  AC_MSG_RESULT(no)
437 fi
438
439 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
440
441 if test x$ac_zlib != xno; then
442   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
443     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
444       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
445     else
446       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
447     fi
448   fi
449 fi
450 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
451
452
453
454 AC_ARG_WITH([default-trust-store-pkcs11],
455   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
456     [use the given pkcs11 uri as default trust store])])
457
458 if test "x$with_default_trust_store_pkcs11" != x; then
459   if test "x$with_p11_kit" = xno; then
460     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
461   fi
462   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
463     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
464 fi
465
466 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
467 AC_ARG_WITH([default-trust-store-file],
468   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
469     [use the given file default trust store])], with_default_trust_store_file="$withval",
470   [if test "$build" = "$host";then
471   for i in \
472     /etc/ssl/ca-bundle.pem \
473     /etc/ssl/certs/ca-certificates.crt \
474     /etc/pki/tls/cert.pem \
475     /usr/local/share/certs/ca-root-nss.crt \
476     /etc/ssl/cert.pem
477     do
478     if test -e $i; then
479       with_default_trust_store_file="$i"
480       break
481     fi
482   done
483   fi]
484 )
485
486 if test "$with_default_trust_store_file" = "no";then
487   with_default_trust_store_file=""
488 fi
489
490 AC_ARG_WITH([default-crl-file],
491   [AS_HELP_STRING([--with-default-crl-file=FILE],
492     [use the given CRL file as default])])
493
494 if test "x$with_default_trust_store_file" != x; then
495   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
496     ["$with_default_trust_store_file"], [use the given file default trust store])
497 fi
498
499 if test "x$with_default_crl_file" != x; then
500   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
501     ["$with_default_crl_file"], [use the given CRL file])
502 fi
503
504 dnl Guile bindings.
505 opt_guile_bindings=yes
506 AC_MSG_CHECKING([whether building Guile bindings])
507 AC_ARG_ENABLE(guile,
508         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
509 opt_guile_bindings=$enableval)
510 AC_MSG_RESULT($opt_guile_bindings)
511
512 AC_ARG_WITH([guile-site-dir],
513   [AS_HELP_STRING([--with-guile-site-dir],
514      [use the given directory as the Guile site (use with care)])])
515
516 if test "$opt_guile_bindings" = "yes"; then
517    AC_MSG_RESULT([***
518 *** Detecting GNU Guile...
519 ])
520
521    AC_PATH_PROG([guile_snarf], [guile-snarf])
522    if test "x$guile_snarf" = "x"; then
523       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
524       opt_guile_bindings=no
525    else
526       GUILE_PROGS
527       GUILE_FLAGS
528
529       save_CFLAGS="$CFLAGS"
530       save_LIBS="$LIBS"
531       CFLAGS="$CFLAGS $GUILE_CFLAGS"
532       LIBS="$LIBS $GUILE_LDFLAGS"
533       AC_MSG_CHECKING([whether GNU Guile is recent enough])
534       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
535         [], [opt_guile_bindings=no])
536       CFLAGS="$save_CFLAGS"
537       LIBS="$save_LIBS"
538
539       if test "$opt_guile_bindings" = "yes"; then
540         AC_MSG_RESULT([yes])
541         case "x$with_guile_site_dir" in 
542              xno)
543                 # Use the default $(GUILE_SITE).
544                 GUILE_SITE_DIR
545                 ;;
546              x|xyes)
547                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
548                 # hack is used to allow `distcheck' to work (see
549                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
550                 GUILE_SITE="\$(datadir)/guile/site"
551                 AC_SUBST(GUILE_SITE)
552                 ;;
553              *)
554                 # Use the user-specified directory as $(GUILE_SITE).
555                 GUILE_SITE="$with_guile_site_dir"
556                 AC_SUBST(GUILE_SITE)
557                 ;;
558         esac
559         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
560         _gcc_cflags_save="$CFLAGS"
561         CFLAGS="${CFLAGS} -fgnu89-inline"
562         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
563                           gnu89_inline=yes, gnu89_inline=no)
564         AC_MSG_RESULT($gnu89_inline)
565         CFLAGS="$_gcc_cflags_save"
566
567         # Optional Guile functions.
568         save_CFLAGS="$CFLAGS"
569         save_LIBS="$LIBS"
570         CFLAGS="$CFLAGS $GUILE_CFLAGS"
571         LIBS="$LIBS $GUILE_LDFLAGS"
572         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
573         CFLAGS="$save_CFLAGS"
574         LIBS="$save_LIBS"
575
576         # The place where guile-gnutls.la will go.
577         AC_MSG_CHECKING([the Guile effective version])
578         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
579         AC_MSG_RESULT([$guile_effective_version])
580         guileextensiondir="$libdir/guile/$guile_effective_version"
581         AC_SUBST([guileextensiondir])
582       else
583         AC_MSG_RESULT([no])
584         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
585         opt_guile_bindings=no
586       fi
587    fi
588 fi
589 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
590
591 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
592 LIBGNUTLS_CFLAGS="-I${includedir}"
593 AC_SUBST(LIBGNUTLS_LIBS)
594 AC_SUBST(LIBGNUTLS_CFLAGS)
595
596 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")
597
598 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
599 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
600
601 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
602 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
603 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
604
605 dnl Crywrap dependencies
606    AC_MSG_RESULT([***
607 *** Checking dependencies for crywrap...
608 ])
609
610 crywrap=no
611
612 if test "$have_win" != "yes"; then
613
614 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
615
616 dnl **********************
617 dnl * Typedefs & co
618 dnl **********************
619 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
620 [AC_LANG_PROGRAM([#include <sys/types.h>
621 #include <signal.h>
622 ],
623                  [return *(signal (0, 0)) (0) == 1;])],
624                    [ac_cv_type_signal=int],
625                    [ac_cv_type_signal=void])])
626 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
627                     (`int' or `void').])
628
629 AC_FUNC_SELECT_ARGTYPES
630 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
631                 putenv regcomp scandir select socket strcasecmp strchr \
632                 strdup strerror strncasecmp strrchr strstr strtoul uname])
633
634 AC_ARG_ENABLE(crywrap,
635         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
636
637  libidn=no
638
639  if test "x$enable_crywrap" != "xno" ; then
640         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
641         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
642  fi
643
644  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
645   crywrap=yes
646  fi
647
648 fi
649
650 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
651
652 dnl end of crywrap requirements
653
654 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
655 AC_CONFIG_FILES([
656   Makefile
657   doc/Makefile
658   doc/credentials/Makefile
659   doc/credentials/openpgp/Makefile
660   doc/credentials/srp/Makefile
661   doc/credentials/x509/Makefile
662   doc/cyclo/Makefile
663   doc/doxygen/Doxyfile
664   doc/examples/Makefile
665   doc/latex/Makefile
666   doc/manpages/Makefile
667   doc/reference/Makefile
668   doc/reference/version.xml
669   doc/scripts/Makefile
670   extra/Makefile
671   extra/includes/Makefile
672   libdane/Makefile
673   libdane/includes/Makefile
674   libdane/gnutls-dane.pc
675   gl/Makefile
676   gl/tests/Makefile
677   guile/Makefile
678   guile/modules/Makefile
679   guile/src/Makefile
680   guile/tests/Makefile
681   lib/Makefile
682   lib/accelerated/Makefile
683   lib/accelerated/x86/Makefile
684   lib/algorithms/Makefile
685   lib/auth/Makefile
686   lib/ext/Makefile
687   lib/extras/Makefile
688   lib/gnutls.pc
689   lib/includes/Makefile
690   lib/includes/gnutls/gnutls.h
691   lib/minitasn1/Makefile
692   lib/nettle/Makefile
693   lib/opencdk/Makefile
694   lib/openpgp/Makefile
695   lib/x509/Makefile
696   po/Makefile.in
697   src/Makefile
698   src/crywrap/Makefile
699   src/gl/Makefile
700   tests/Makefile
701   tests/cert-tests/Makefile
702   tests/dsa/Makefile
703   tests/dtls/Makefile
704   tests/srp/Makefile
705   tests/ecdsa/Makefile
706   tests/key-id/Makefile
707   tests/openpgp-certs/Makefile
708   tests/pkcs1-padding/Makefile
709   tests/pkcs12-decode/Makefile
710   tests/pkcs8-decode/Makefile
711   tests/rsa-md5-collision/Makefile
712   tests/safe-renegotiation/Makefile
713   tests/scripts/Makefile
714   tests/sha2/Makefile
715   tests/slow/Makefile
716   tests/suite/Makefile
717   tests/userid/Makefile
718 ])
719
720 AC_OUTPUT
721
722 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
723 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
724 AC_MSG_NOTICE([summary of build options:
725
726   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
727   Host/Target system:   ${host}
728   Build system:         ${build}
729   Install prefix:       ${prefix}
730   Compiler:             ${CC}
731   CFlags:               ${CFLAGS}
732   Library types:        Shared=${enable_shared}, Static=${enable_static}
733 ])
734
735 AC_MSG_NOTICE([External hardware support:
736
737   /dev/crypto:          $enable_cryptodev
738   Hardware accel:       $hw_accel
739   PKCS#11 support:      $with_p11_kit
740   TPM support:          $with_tpm
741 ])
742
743 AC_MSG_NOTICE([Optional features:
744 (note that included applications might not compile properly
745 if features are disabled)
746
747   DTLS-SRTP support:    $ac_enable_srtp
748   ALPN support:         $ac_enable_alpn
749   OCSP support:         $ac_enable_ocsp
750   OpenPGP support:      $ac_enable_openpgp
751   SRP support:          $ac_enable_srp
752   PSK support:          $ac_enable_psk
753   DHE support:          $ac_enable_dhe
754   ECDHE support:        $ac_enable_ecdhe
755   Anon auth support:    $ac_enable_anon
756   Heartbeat support:    $ac_enable_heartbeat
757   RSA-EXPORT compat:    $ac_enable_rsa_export
758   Unicode support:      $ac_have_unicode
759   Self checks:          $enable_self_checks
760   FIPS140 mode:         $enable_fips
761 ])
762
763 AC_MSG_NOTICE([Optional applications:
764
765   crywrap app:          $libidn
766   local libopts:        ${enable_local_libopts}
767   local libtasn1:       ${included_libtasn1}
768 ])
769
770 AC_MSG_NOTICE([Optional libraries:
771
772   Guile wrappers:       $opt_guile_bindings
773   C++ library:          $use_cxx
774   DANE library:         $enable_dane
775   OpenSSL compat:       $enable_openssl
776 ])
777
778 AC_MSG_NOTICE([System files:
779
780   Trust store pkcs:     $with_default_trust_store_pkcs11
781   Trust store file:     $with_default_trust_store_file
782   CRL file:             $with_default_crl_file
783   DNSSEC root key file: $unbound_root_key_file
784 ])
785
786 if test ! -f "$unbound_root_key_file"; then
787 AC_MSG_WARN([[
788 *** 
789 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
790 *** This file is needed for the verification of DNSSEC responses.
791 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
792 *** to generate or update it.
793 *** ]])
794 fi