www.gitorious.org Git - gnutls:gnutls.git/blob

1 dnl Process this file with autoconf to produce a configure script.

3 #

4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson

5 #

6 # This file is part of GnuTLS.

7 #

8 # This program is free software; you can redistribute it and/or modify

9 # it under the terms of the GNU General Public License as published by

10 # the Free Software Foundation; either version 3 of the License, or

11 # (at your option) any later version.

12 #

13 # This program is distributed in the hope that it will be useful, but

14 # WITHOUT ANY WARRANTY; without even the implied warranty of

15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU

16 # General Public License for more details.

17 #

18 # You should have received a copy of the GNU General Public License

19 # along with this program; if not, write to the Free Software

20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301

21 # USA

23 AC_PREREQ(2.61)

24 AC_INIT([GnuTLS], [3.3.0], [bugs@gnutls.org])

25 AC_CONFIG_AUX_DIR([build-aux])

26 AC_CONFIG_MACRO_DIR([m4])

27 AC_CANONICAL_HOST

29 AM_INIT_AUTOMAKE([1.12.2 subdir-objects no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])

30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

31 AC_CONFIG_HEADERS([config.h])

33 AC_MSG_RESULT([***

34 *** Checking for compilation programs...

35 ])

37 dnl Checks for programs.

38 AC_PROG_CC

39 gl_EARLY

40 ggl_EARLY

41 AM_PROG_AS

42 AM_PROG_AR

43 AC_PROG_CXX

44 AM_PROG_CC_C_O

45 AC_PROG_YACC

46 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])

48 if test x"$AUTOGEN" = "x/bin/true"; then

49 AC_MSG_WARN([[

50 ***

51 *** autogen not found. Will not link against libopts.

52 *** ]])

53 enable_local_libopts=yes

54 fi

56 # For includes/gnutls/gnutls.h.in.

57 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/$.*$\..*\..*/\1/g'`)

58 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.$.*$\..*/\1/g'`)

59 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.$.*$/\1/g'`)

60 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)

62 touch suppressions.valgrind

63 dnl C and C++ capabilities

64 AC_C_INLINE

65 AC_HEADER_STDC

67 # For the C++ code

68 AC_ARG_ENABLE(cxx,

69 AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),

70 use_cxx=$enableval, use_cxx=yes)

71 if test "$use_cxx" != "no"; then

72 AC_LANG_PUSH(C++)

73 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)

74 AC_LANG_POP(C++)

75 fi

76 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")

77 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])

79 dnl Detect windows build

80 case "$host" in

81 *mingw32* | *mingw64*)

82 have_win=yes

83 ;;

84 *darwin*)

85 have_macosx=yes

86 ;;

87 *)

88 have_elf=yes

89 ;;

90 esac

92 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)

93 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)

94 AM_CONDITIONAL(ELF, test "$have_elf" = yes)

96 dnl Hardware Acceleration

97 AC_ARG_ENABLE(hardware-acceleration,

98 AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),

99 use_accel=$enableval, use_accel=yes)

100 hw_accel=none

101

102

103 if test "$use_accel" != "no"; then

104 case $host_cpu in

105 i?86 | x86_64 | amd64)

106 AC_CHECK_HEADERS(cpuid.h)

107 if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then

108 hw_accel="x86-64"

109 else

110 hw_accel="x86"

111 fi

112 ;;

113 *)

114 ;;

115 esac

116

117 fi

118

119 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")

120 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")

121 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")

122 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])

123 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")

124

125

126 dnl Try the hooks.m4

127 LIBGNUTLS_HOOKS

128 LIBGNUTLS_EXTRA_HOOKS

129

130 AC_ARG_ENABLE(doc,

131 AS_HELP_STRING([--disable-doc], [don't generate any documentation]),

132 enable_doc=$enableval, enable_doc=yes)

133 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")

134

135 AC_ARG_ENABLE(tests,

136 AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),

137 enable_tests=$enableval, enable_tests=yes)

138 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")

139

140 GTK_DOC_CHECK(1.1)

141 AM_GNU_GETTEXT([external])

142 AM_GNU_GETTEXT_VERSION([0.18])

143

144 AC_C_BIGENDIAN

145

146 gl_INIT

147 ggl_INIT

148

149 dnl GCC warnings to enable

150

151 AC_ARG_ENABLE([gcc-warnings],

152 [AS_HELP_STRING([--enable-gcc-warnings],

153 [turn on lots of GCC warnings (for developers)])],

154 [case $enableval in

155 yes|no) ;;

156 *) AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;

157 esac

158 gl_gcc_warnings=$enableval],

159 [gl_gcc_warnings=no]

160 )

161

162 if test "$gl_gcc_warnings" = yes; then

163 gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])

164

165 nw="$nw -Wsystem-headers" # Don't let system headers trigger warnings

166 nw="$nw -Wc++-compat" # We don't care about C++ compilers

167 nw="$nw -Wundef" # Warns on '#if GNULIB_FOO' etc in gnulib

168 nw="$nw -Wtraditional" # Warns on #elif which we use often

169 nw="$nw -Wlogical-op" # Too many false positives

170 nw="$nw -Wold-style-definition" #

171 nw="$nw -Wpadded" # Our structs are not padded

172 nw="$nw -Wunreachable-code" # Too many false positives

173 nw="$nw -Wtraditional-conversion" # Too many warnings for now

174 nw="$nw -Wcast-qual" # Too many warnings for now

175 nw="$nw -Waggregate-return" # Too many warnings for now

176 nw="$nw -Wshadow" # Too many warnings for now

177 nw="$nw -Wswitch-default" # Too many warnings for now

178 nw="$nw -Wswitch-enum" # Too many warnings for now

179 nw="$nw -Wconversion" # Too many warnings for now

180 nw="$nw -Wsign-conversion" # Too many warnings for now

181 nw="$nw -Wformat-y2k" # Too many warnings for now

182 nw="$nw -Woverlength-strings" # We use some in tests/

183 nw="$nw -Wvla" # There is no point to avoid C99 variable length arrays

184 nw="$nw -Wformat-nonliteral" # Incompatible with gettext _()

185 nw="$nw -Wunsafe-loop-optimizations"

186 nw="$nw -Wstrict-overflow"

187 nw="$nw -Wmissing-noreturn"

188 nw="$nw -Winline" # Too compiler dependent

189 nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?

190 nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?

191 nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?

192 nw="$nw -Wstack-protector" # Some functions cannot be protected

193 nw="$nw -Wredundant-decls" # Some files cannot be compiled with that (gl_fd_to_handle)

194

195 gl_MANYWARN_ALL_GCC([ws])

196 gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])

197 for w in $ws; do

198 gl_WARN_ADD([$w])

199 done

200

201 gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one

202 gl_WARN_ADD([-Wno-format-y2k]) # Too many warnings for now

203 gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get

204 gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get

205 gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now

206 gl_WARN_ADD([-Wno-stack-protector]) # Some functions cannot be protected

207 gl_WARN_ADD([-Wno-int-to-pointer-cast]) # Some files cannot be compiled with that (gl_fd_to_handle)

208 gl_WARN_ADD([-fdiagnostics-show-option])

209 fi

210

211 AC_SUBST([WERROR_CFLAGS])

212 AC_SUBST([WSTACK_CFLAGS])

213 AC_SUBST([WARN_CFLAGS])

214

215 dnl Programs for compilation or development

216 AC_PROG_LN_S

217 AC_LIBTOOL_WIN32_DLL

218 LT_INIT([disable-static])

219 AC_PROG_LIBTOOL

220

221

222 dnl No fork on MinGW, disable some self-tests until we fix them.

223 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)

224 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)

225 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")

226

227 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>

228 #include <signal.h>

229 ], [timer_create (0,0,0);])

230

231 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then

232 AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])

233 fi

234

235 if test "$ac_cv_func_nanosleep" != "yes";then

236 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])

237 gnutls_needs_librt=yes

238 fi

239

240 ac_have_unicode=no

241 if test "$ac_cv_func_iconv" != "yes";then

242 AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])

243 if test "$HAVE_LIBICONV" = "yes";then

244 ac_have_unicode=yes

245 fi

246 else

247 ac_have_unicode=yes

248 fi

249

250 if test "$ac_have_unicode" != "yes";then

251 if test "$have_win" = "yes";then

252 ac_have_unicode=yes

253 fi

254 fi

255

256 AC_ARG_ENABLE(self-checks,

257 AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),

258 enable_self_checks=$enableval, enable_self_checks=no)

259

260 AC_ARG_ENABLE(fips140-mode,

261 AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),

262 enable_fips=$enableval, enable_fips=no)

263 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")

264 if [ test "$enable_fips" = "yes" ];then

265 AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])

266 if test "x$HAVE_LIBDL" = "xyes";then

267 enable_self_checks=yes

268

269 dnl clock_gettime precision is needed on the FIPS140 DRBG.

270 if test "$ac_cv_func_clock_gettime" != "yes";then

271 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [clock_gettime (0, 0);])

272 gnutls_needs_librt=yes

273 fi

274

275 AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])

276

277 AC_SUBST([FIPS140_LIBS], $LIBDL)

278 else

279 enable_fips=no

280 AC_MSG_WARN([[

281 ***

282 *** This system is not supported in FIPS140 mode.

283 *** libdl and dladdr() are required.

284 *** ]])

285 fi

286 fi

287

288 AC_ARG_ENABLE(non-suiteb-curves,

289 AS_HELP_STRING([--disable-non-suiteb-curves], [disable curves not in SuiteB]),

290 enable_non_suiteb=$enableval, enable_non_suiteb=yes)

291 if [ test "$enable_non_suiteb" = "yes" ];then

292 AC_DEFINE([ENABLE_NON_SUITEB_CURVES], 1, [Enable all curves])

293 fi

294

295 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")

296 if [ test "$enable_self_checks" = "yes" ];then

297 AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])

298 fi

299

300 AC_MSG_CHECKING([whether to build libdane])

301 AC_ARG_ENABLE(libdane,

302 AS_HELP_STRING([--disable-libdane],

303 [disable the built of libdane]),

304 enable_dane=$enableval, enable_dane=yes)

305 AC_MSG_RESULT($enable_dane)

306

307 if test "$enable_dane" != "no"; then

308 LIBS="$oldlibs -lunbound"

309 AC_MSG_CHECKING([for unbound library])

310 AC_LINK_IFELSE([AC_LANG_PROGRAM([

311 #include <unbound.h>],[

312 struct ub_ctx* ctx;

313 ctx = ub_ctx_create();])],

314 [AC_MSG_RESULT(yes)

315 AC_SUBST([UNBOUND_LIBS], [-lunbound])

316 AC_SUBST([UNBOUND_CFLAGS], [])

317 AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])

318 enable_dane=yes],

319 [AC_MSG_RESULT(no)

320 AC_MSG_WARN([[

321 ***

322 *** libunbound was not found. Libdane will not be built.

323 *** ]])

324 enable_dane=no])

325 LIBS="$oldlibs"

326 fi

327

328 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")

329

330 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],

331 [specify the unbound root key file]),

332 unbound_root_key_file="$withval",

333 if test "$have_win" = yes; then

334 unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"

335 else

336 if test -f /var/lib/unbound/root.key;then

337 unbound_root_key_file="/var/lib/unbound/root.key"

338 else

339 unbound_root_key_file="/etc/unbound/root.key"

340 fi

341 fi

342 )

343

344 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],

345 ["$unbound_root_key_file"], [The DNSSEC root key file])

346

347 dnl Check for p11-kit

348 P11_KIT_MINIMUM=0.19.1

349 AC_ARG_WITH(p11-kit,

350 AS_HELP_STRING([--without-p11-kit],

351 [Build without p11-kit and PKCS#11 support]))

352 if test "$with_p11_kit" != "no"; then

353 PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])

354 if test "$with_p11_kit" != "no";then

355 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])

356 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then

357 GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"

358 else

359 GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"

360 fi

361 else

362 with_p11_kit=no

363 AC_MSG_WARN([[

364 ***

365 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.

366 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html

367 *** ]])

368 fi

369 fi

370

371 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")

372

373 AC_ARG_WITH(tpm,

374 AS_HELP_STRING([--without-tpm],

375 [Disable TPM (trousers) support.]),

376 [with_tpm=$withval], [with_tpm=yes])

377 if test "$with_tpm" != "no"; then

378 LIBS="$oldlibs -ltspi"

379 AC_MSG_CHECKING([for tss library])

380 AC_LINK_IFELSE([AC_LANG_PROGRAM([

381 #include <trousers/tss.h>

382 #include <trousers/trousers.h>],[

383 int err = Tspi_Context_Create((void *)0);

384 Trspi_Error_String(err);])],

385 [AC_MSG_RESULT(yes)

386 AC_SUBST([TSS_LIBS], [-ltspi])

387 AC_SUBST([TSS_CFLAGS], [])

388 AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])

389 with_tpm=yes],

390 [AC_MSG_RESULT(no)

391 AC_MSG_WARN([[

392 ***

393 *** trousers was not found. TPM support will be disabled.

394 *** ]])

395 with_tpm=no])

396 LIBS="$oldlibs"

397 fi

398

399 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")

400

401 LIBOPTS_CHECK([src/libopts])

402 if test "$NEED_LIBOPTS_DIR" = "true";then

403 dnl delete libopts-generated files

404 for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do

405 nam=`echo $i|sed 's/.bak//g'`

406 if test -f $i;then

407 cp -f $i $nam

408 fi

409 done

410 AC_SUBST([AUTOGEN], [/bin/true])

411 enable_local_libopts=yes

412 else

413 enable_local_libopts=no

414 fi

415 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")

416

417 AC_CHECK_TYPE(ssize_t,

418 [

419 DEFINE_SSIZE_T="#include <sys/types.h>"

420 AC_SUBST(DEFINE_SSIZE_T)

421 ], [

422 AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])

423 DEFINE_SSIZE_T="typedef int ssize_t;"

424 AC_SUBST(DEFINE_SSIZE_T)

425 ], [

426 #include <sys/types.h>

427 ])

428

429 # For minitasn1.

430 AC_CHECK_SIZEOF(unsigned long int, 4)

431 AC_CHECK_SIZEOF(unsigned int, 4)

432

433 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],

434 [disable zlib compression support]),

435 ac_zlib=$withval, ac_zlib=yes)

436 AC_MSG_CHECKING([whether to include zlib compression support])

437 if test x$ac_zlib != xno; then

438 AC_MSG_RESULT(yes)

439 AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])

440 if test x$ac_cv_libz != xyes; then

441 AC_MSG_WARN(

442 ***

443 *** ZLIB was not found. You will not be able to use ZLIB compression.)

444 fi

445 else

446 AC_MSG_RESULT(no)

447 fi

448

449 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)

450

451 if test x$ac_zlib != xno; then

452 if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then

453 if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then

454 GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"

455 else

456 GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"

457 fi

458 fi

459 fi

460 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)

461

462

463

464 AC_ARG_WITH([default-trust-store-pkcs11],

465 [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],

466 [use the given pkcs11 uri as default trust store])])

467

468 if test "x$with_default_trust_store_pkcs11" != x; then

469 if test "x$with_p11_kit" = xno; then

470 AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])

471 fi

472 AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],

473 ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])

474 fi

475

476 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html

477 AC_ARG_WITH([default-trust-store-file],

478 [AS_HELP_STRING([--with-default-trust-store-file=FILE],

479 [use the given file default trust store])], with_default_trust_store_file="$withval",

480 [if test "$build" = "$host";then

481 for i in \

482 /etc/ssl/ca-bundle.pem \

483 /etc/ssl/certs/ca-certificates.crt \

484 /etc/pki/tls/cert.pem \

485 /usr/local/share/certs/ca-root-nss.crt \

486 /etc/ssl/cert.pem

487 do

488 if test -e $i; then

489 with_default_trust_store_file="$i"

490 break

491 fi

492 done

493 fi]

494 )

495

496 if test "$with_default_trust_store_file" = "no";then

497 with_default_trust_store_file=""

498 fi

499

500 AC_ARG_WITH([default-crl-file],

501 [AS_HELP_STRING([--with-default-crl-file=FILE],

502 [use the given CRL file as default])])

503

504 if test "x$with_default_trust_store_file" != x; then

505 AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],

506 ["$with_default_trust_store_file"], [use the given file default trust store])

507 fi

508

509 if test "x$with_default_crl_file" != x; then

510 AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],

511 ["$with_default_crl_file"], [use the given CRL file])

512 fi

513

514 dnl Guile bindings.

515 opt_guile_bindings=yes

516 AC_MSG_CHECKING([whether building Guile bindings])

517 AC_ARG_ENABLE(guile,

518 AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),

519 opt_guile_bindings=$enableval)

520 AC_MSG_RESULT($opt_guile_bindings)

521

522 AC_ARG_WITH([guile-site-dir],

523 [AS_HELP_STRING([--with-guile-site-dir],

524 [use the given directory as the Guile site (use with care)])])

525

526 if test "$opt_guile_bindings" = "yes"; then

527 AC_MSG_RESULT([***

528 *** Detecting GNU Guile...

529 ])

530

531 AC_PATH_PROG([guile_snarf], [guile-snarf])

532 if test "x$guile_snarf" = "x"; then

533 AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found. Guile bindings not built.])

534 opt_guile_bindings=no

535 else

536 GUILE_PROGS

537 GUILE_FLAGS

538

539 save_CFLAGS="$CFLAGS"

540 save_LIBS="$LIBS"

541 CFLAGS="$CFLAGS $GUILE_CFLAGS"

542 LIBS="$LIBS $GUILE_LDFLAGS"

543 AC_MSG_CHECKING([whether GNU Guile is recent enough])

544 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],

545 [], [opt_guile_bindings=no])

546 CFLAGS="$save_CFLAGS"

547 LIBS="$save_LIBS"

548

549 if test "$opt_guile_bindings" = "yes"; then

550 AC_MSG_RESULT([yes])

551 case "x$with_guile_site_dir" in

552 xno)

553 # Use the default $(GUILE_SITE).

554 GUILE_SITE_DIR

555 ;;

556 x|xyes)

557 # Automatically derive $(GUILE_SITE) from $(pkgdatadir). This

558 # hack is used to allow `distcheck' to work (see

559 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').

560 GUILE_SITE="\$(datadir)/guile/site"

561 AC_SUBST(GUILE_SITE)

562 ;;

563 *)

564 # Use the user-specified directory as $(GUILE_SITE).

565 GUILE_SITE="$with_guile_site_dir"

566 AC_SUBST(GUILE_SITE)

567 ;;

568 esac

569 AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])

570 _gcc_cflags_save="$CFLAGS"

571 CFLAGS="${CFLAGS} -fgnu89-inline"

572 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],

573 gnu89_inline=yes, gnu89_inline=no)

574 AC_MSG_RESULT($gnu89_inline)

575 CFLAGS="$_gcc_cflags_save"

576

577 # Optional Guile functions.

578 save_CFLAGS="$CFLAGS"

579 save_LIBS="$LIBS"

580 CFLAGS="$CFLAGS $GUILE_CFLAGS"

581 LIBS="$LIBS $GUILE_LDFLAGS"

582 AC_CHECK_FUNCS([scm_gc_malloc_pointerless])

583 CFLAGS="$save_CFLAGS"

584 LIBS="$save_LIBS"

585

586 # The place where guile-gnutls.la will go.

587 AC_MSG_CHECKING([the Guile effective version])

588 guile_effective_version="`$GUILE -c '(display (effective-version))'`"

589 AC_MSG_RESULT([$guile_effective_version])

590 guileextensiondir="$libdir/guile/$guile_effective_version"

591 AC_SUBST([guileextensiondir])

592 else

593 AC_MSG_RESULT([no])

594 AC_MSG_WARN([A sufficiently recent GNU Guile not found. Guile bindings not built.])

595 opt_guile_bindings=no

596 fi

597 fi

598 fi

599 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")

600

601 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"

602 LIBGNUTLS_CFLAGS="-I${includedir}"

603 AC_SUBST(LIBGNUTLS_LIBS)

604 AC_SUBST(LIBGNUTLS_CFLAGS)

605

606 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")

607

608 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])

609 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])

610

611 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])

612 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])

613 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])

614

615 dnl Crywrap dependencies

616 AC_MSG_RESULT([***

617 *** Checking dependencies for crywrap...

618 ])

619

620 crywrap=no

621

622 if test "$have_win" != "yes"; then

623

624 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])

625

626 dnl **********************

627 dnl * Typedefs & co

628 dnl **********************

629 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(

630 [AC_LANG_PROGRAM([#include <sys/types.h>

631 #include <signal.h>

632 ],

633 [return *(signal (0, 0)) (0) == 1;])],

634 [ac_cv_type_signal=int],

635 [ac_cv_type_signal=void])])

636 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers

637 (`int' or `void').])

638

639 AC_FUNC_SELECT_ARGTYPES

640 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \

641 putenv regcomp scandir select socket strcasecmp strchr \

642 strdup strerror strncasecmp strrchr strstr strtoul uname])

643

644 AC_ARG_ENABLE(crywrap,

645 AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))

646

647 libidn=no

648

649 if test "x$enable_crywrap" != "xno" ; then

650 PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])

651 AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])

652 fi

653

654 if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then

655 crywrap=yes

656 fi

657

658 fi

659

660 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")

661

662 dnl end of crywrap requirements

663

664 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])

665 AC_CONFIG_FILES([

666 Makefile

667 doc/Makefile

668 doc/credentials/Makefile

669 doc/credentials/openpgp/Makefile

670 doc/credentials/srp/Makefile

671 doc/credentials/x509/Makefile

672 doc/cyclo/Makefile

673 doc/doxygen/Doxyfile

674 doc/examples/Makefile

675 doc/latex/Makefile

676 doc/manpages/Makefile

677 doc/reference/Makefile

678 doc/reference/version.xml

679 doc/scripts/Makefile

680 extra/Makefile

681 extra/includes/Makefile

682 libdane/Makefile

683 libdane/includes/Makefile

684 libdane/gnutls-dane.pc

685 gl/Makefile

686 gl/tests/Makefile

687 guile/Makefile

688 guile/modules/Makefile

689 guile/src/Makefile

690 guile/tests/Makefile

691 lib/Makefile

692 lib/accelerated/Makefile

693 lib/accelerated/x86/Makefile

694 lib/algorithms/Makefile

695 lib/auth/Makefile

696 lib/ext/Makefile

697 lib/extras/Makefile

698 lib/gnutls.pc

699 lib/includes/Makefile

700 lib/includes/gnutls/gnutls.h

701 lib/minitasn1/Makefile

702 lib/nettle/Makefile

703 lib/opencdk/Makefile

704 lib/openpgp/Makefile

705 lib/x509/Makefile

706 po/Makefile.in

707 src/Makefile

708 src/crywrap/Makefile

709 src/gl/Makefile

710 tests/Makefile

711 tests/cert-tests/Makefile

712 tests/dsa/Makefile

713 tests/dtls/Makefile

714 tests/srp/Makefile

715 tests/ecdsa/Makefile

716 tests/key-id/Makefile

717 tests/openpgp-certs/Makefile

718 tests/pkcs1-padding/Makefile

719 tests/pkcs12-decode/Makefile

720 tests/pkcs8-decode/Makefile

721 tests/rsa-md5-collision/Makefile

722 tests/safe-renegotiation/Makefile

723 tests/scripts/Makefile

724 tests/sha2/Makefile

725 tests/slow/Makefile

726 tests/suite/Makefile

727 tests/userid/Makefile

728 ])

729

730 AC_OUTPUT

731

732 dnl Warning flags: errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}

733 dnl Valgrind: $opt_valgrind_tests ${VALGRIND}

734 AC_MSG_NOTICE([summary of build options:

735

736 version: ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE

737 Host/Target system: ${host}

738 Build system: ${build}

739 Install prefix: ${prefix}

740 Compiler: ${CC}

741 CFlags: ${CFLAGS}

742 Library types: Shared=${enable_shared}, Static=${enable_static}

743 ])

744

745 AC_MSG_NOTICE([External hardware support:

746

747 /dev/crypto: $enable_cryptodev

748 Hardware accel: $hw_accel

749 PKCS#11 support: $with_p11_kit

750 TPM support: $with_tpm

751 ])

752

753 AC_MSG_NOTICE([Optional features:

754 (note that included applications might not compile properly

755 if features are disabled)

756

757 DTLS-SRTP support: $ac_enable_srtp

758 ALPN support: $ac_enable_alpn

759 OCSP support: $ac_enable_ocsp

760 OpenPGP support: $ac_enable_openpgp

761 SRP support: $ac_enable_srp

762 PSK support: $ac_enable_psk

763 DHE support: $ac_enable_dhe

764 ECDHE support: $ac_enable_ecdhe

765 Anon auth support: $ac_enable_anon

766 Heartbeat support: $ac_enable_heartbeat

767 RSA-EXPORT compat: $ac_enable_rsa_export

768 Unicode support: $ac_have_unicode

769 Self checks: $enable_self_checks

770 Non-SuiteB curves: $enable_non_suiteb

771 FIPS140 mode: $enable_fips

772 ])

773

774 AC_MSG_NOTICE([Optional applications:

775

776 crywrap app: $libidn

777 local libopts: ${enable_local_libopts}

778 local libtasn1: ${included_libtasn1}

779 ])

780

781 AC_MSG_NOTICE([Optional libraries:

782

783 Guile wrappers: $opt_guile_bindings

784 C++ library: $use_cxx

785 DANE library: $enable_dane

786 OpenSSL compat: $enable_openssl

787 ])

788

789 AC_MSG_NOTICE([System files:

790

791 Trust store pkcs: $with_default_trust_store_pkcs11

792 Trust store file: $with_default_trust_store_file

793 CRL file: $with_default_crl_file

794 DNSSEC root key file: $unbound_root_key_file

795 ])

796

797 if test ! -f "$unbound_root_key_file"; then

798 AC_MSG_WARN([[

799 ***

800 *** The DNSSEC root key file in $unbound_root_key_file was not found.

801 *** This file is needed for the verification of DNSSEC responses.

802 *** Use the command: unbound-anchor -a "$unbound_root_key_file"

803 *** to generate or update it.

804 *** ]])

805 fi