Merged the FIPS140-2 support code.
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.3.0], [bugs@gnutls.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 subdir-objects no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 ggl_EARLY
41 AM_PROG_AS
42 AM_PROG_AR
43 AC_PROG_CXX
44 AM_PROG_CC_C_O
45 AC_PROG_YACC
46 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
47
48 if test x"$AUTOGEN" = "x/bin/true"; then
49   AC_MSG_WARN([[
50 ***
51 *** autogen not found. Will not link against libopts.
52 *** ]])
53 enable_local_libopts=yes
54 fi
55
56 # For includes/gnutls/gnutls.h.in.
57 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
58 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
59 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
60 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
61
62 touch suppressions.valgrind
63 dnl C and C++ capabilities
64 AC_C_INLINE
65 AC_HEADER_STDC
66
67 # For the C++ code
68 AC_ARG_ENABLE(cxx,
69   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
70     use_cxx=$enableval, use_cxx=yes)
71 if test "$use_cxx" != "no"; then
72   AC_LANG_PUSH(C++)
73   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
74   AC_LANG_POP(C++)
75 fi
76 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
77 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
78
79 dnl Detect windows build
80 case "$host" in
81   *mingw32* | *mingw64*)
82     have_win=yes
83   ;;
84   *darwin*)
85     have_macosx=yes
86   ;;
87   *)
88     have_elf=yes
89   ;;
90 esac
91
92 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
93 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
94 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
95
96 dnl Hardware Acceleration
97 AC_ARG_ENABLE(hardware-acceleration,
98   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
99     use_accel=$enableval, use_accel=yes)
100 hw_accel=none
101
102
103 if test "$use_accel" != "no"; then
104 case $host_cpu in
105   i?86 | x86_64 | amd64)
106       AC_CHECK_HEADERS(cpuid.h)
107       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
108         hw_accel="x86-64"
109       else
110         hw_accel="x86"
111       fi
112   ;;
113   *)
114   ;;
115 esac
116
117 fi
118
119 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
120 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
121 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
122 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
123 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
124
125
126 dnl Try the hooks.m4
127 LIBGNUTLS_HOOKS
128 LIBGNUTLS_EXTRA_HOOKS
129
130 AC_ARG_ENABLE(doc,
131   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
132     enable_doc=$enableval, enable_doc=yes)
133 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
134
135 AC_ARG_ENABLE(tests,
136   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
137     enable_tests=$enableval, enable_tests=yes)
138 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
139
140 GTK_DOC_CHECK(1.1)
141 AM_GNU_GETTEXT([external])
142 AM_GNU_GETTEXT_VERSION([0.18])
143
144 AC_C_BIGENDIAN
145
146 gl_INIT
147 ggl_INIT
148
149 dnl GCC warnings to enable
150
151 AC_ARG_ENABLE([gcc-warnings],
152   [AS_HELP_STRING([--enable-gcc-warnings],
153                   [turn on lots of GCC warnings (for developers)])],
154   [case $enableval in
155      yes|no) ;;
156      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
157    esac
158    gl_gcc_warnings=$enableval],
159   [gl_gcc_warnings=no]
160 )
161
162 if test "$gl_gcc_warnings" = yes; then
163   gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])
164
165   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
166   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
167   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
168   nw="$nw -Wtraditional"            # Warns on #elif which we use often
169   nw="$nw -Wlogical-op"             # Too many false positives
170   nw="$nw -Wold-style-definition"   # 
171   nw="$nw -Wpadded"                 # Our structs are not padded
172   nw="$nw -Wunreachable-code"       # Too many false positives
173   nw="$nw -Wtraditional-conversion" # Too many warnings for now
174   nw="$nw -Wcast-qual"              # Too many warnings for now
175   nw="$nw -Waggregate-return"       # Too many warnings for now
176   nw="$nw -Wshadow"                 # Too many warnings for now
177   nw="$nw -Wswitch-default"         # Too many warnings for now
178   nw="$nw -Wswitch-enum"            # Too many warnings for now
179   nw="$nw -Wconversion"             # Too many warnings for now
180   nw="$nw -Wsign-conversion"        # Too many warnings for now
181   nw="$nw -Wformat-y2k"             # Too many warnings for now
182   nw="$nw -Woverlength-strings"     # We use some in tests/
183   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
184   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
185   nw="$nw -Wunsafe-loop-optimizations"
186   nw="$nw -Wstrict-overflow"
187   nw="$nw -Wmissing-noreturn"
188   nw="$nw -Winline"                 # Too compiler dependent
189   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
190   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
191   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
192   nw="$nw -Wstack-protector"        # Some functions cannot be protected
193   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
194
195   gl_MANYWARN_ALL_GCC([ws])
196   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
197   for w in $ws; do
198     gl_WARN_ADD([$w])
199   done
200
201   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
202   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
203   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
204   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
205   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
206   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
207   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
208   gl_WARN_ADD([-fdiagnostics-show-option])
209 fi
210
211 AC_SUBST([WERROR_CFLAGS])
212 AC_SUBST([WSTACK_CFLAGS])
213 AC_SUBST([WARN_CFLAGS])
214
215 dnl Programs for compilation or development
216 AC_PROG_LN_S
217 AC_LIBTOOL_WIN32_DLL
218 AC_PROG_LIBTOOL
219
220
221 dnl No fork on MinGW, disable some self-tests until we fix them.
222 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
223 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)
224 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
225
226 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
227 #include <signal.h>
228 ], [timer_create (0,0,0);])
229
230 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
231   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
232 fi
233
234 if test "$ac_cv_func_nanosleep" != "yes";then
235   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
236   gnutls_needs_librt=yes
237 fi
238
239 ac_have_unicode=no
240 if test "$ac_cv_func_iconv" != "yes";then
241   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
242   if test "$HAVE_LIBICONV" = "yes";then
243     ac_have_unicode=yes
244   fi
245 else
246   ac_have_unicode=yes
247 fi
248
249 if test "$ac_have_unicode" != "yes";then
250   if test "$have_win" = "yes";then
251     ac_have_unicode=yes
252   fi
253 fi
254
255 AC_ARG_ENABLE(self-checks,
256   AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),
257     enable_self_checks=$enableval, enable_self_checks=no)
258
259 AC_ARG_ENABLE(fips140-mode,
260   AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),
261     enable_fips=$enableval, enable_fips=no)
262 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")
263 if [ test "$enable_fips" = "yes" ];then
264   AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])
265   if test "x$HAVE_LIBDL" = "xyes";then
266     enable_self_checks=yes
267
268     dnl clock_gettime precision is needed on the FIPS140 DRBG.
269     if test "$ac_cv_func_clock_gettime" != "yes";then
270       AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [clock_gettime (0, 0);])
271       gnutls_needs_librt=yes
272     fi
273
274     AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])
275
276     AC_SUBST([FIPS140_LIBS], $LIBDL)
277   else
278     enable_fips=no
279     AC_MSG_WARN([[
280 *** 
281 *** This system is not supported in FIPS140 mode.
282 *** libdl and dladdr() are required.
283 *** ]])
284   fi
285 fi
286
287 AC_ARG_ENABLE(non-suiteb-curves,
288   AS_HELP_STRING([--disable-non-suiteb-curves], [disable curves not in SuiteB]),
289     enable_non_suiteb=$enableval, enable_non_suiteb=yes)
290 if [ test "$enable_non_suiteb" = "yes" ];then
291   AC_DEFINE([ENABLE_NON_SUITEB_CURVES], 1, [Enable all curves])
292 fi
293
294 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")
295 if [ test "$enable_self_checks" = "yes" ];then
296    AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])
297 fi
298
299 AC_MSG_CHECKING([whether to build libdane])
300 AC_ARG_ENABLE(libdane,
301     AS_HELP_STRING([--disable-libdane],
302                    [disable the built of libdane]),
303     enable_dane=$enableval, enable_dane=yes)
304 AC_MSG_RESULT($enable_dane)
305
306 if test "$enable_dane" != "no"; then
307     LIBS="$oldlibs -lunbound"
308     AC_MSG_CHECKING([for unbound library])
309     AC_LINK_IFELSE([AC_LANG_PROGRAM([
310                    #include <unbound.h>],[
311                    struct ub_ctx* ctx;
312                    ctx = ub_ctx_create();])],
313                   [AC_MSG_RESULT(yes)
314                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
315                    AC_SUBST([UNBOUND_CFLAGS], [])
316                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
317                    enable_dane=yes],
318                   [AC_MSG_RESULT(no)
319                    AC_MSG_WARN([[
320 *** 
321 *** libunbound was not found. Libdane will not be built.
322 *** ]])
323                   enable_dane=no])
324     LIBS="$oldlibs"
325 fi
326
327 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
328
329 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
330                                  [specify the unbound root key file]),
331             unbound_root_key_file="$withval", 
332 if test "$have_win" = yes; then
333     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
334 else
335     if test -f /var/lib/unbound/root.key;then
336         unbound_root_key_file="/var/lib/unbound/root.key"
337     else
338         unbound_root_key_file="/etc/unbound/root.key"
339     fi
340 fi
341 )
342
343 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
344   ["$unbound_root_key_file"], [The DNSSEC root key file])
345
346 dnl Check for p11-kit
347 P11_KIT_MINIMUM=0.19.1
348 AC_ARG_WITH(p11-kit,
349         AS_HELP_STRING([--without-p11-kit],
350                 [Build without p11-kit and PKCS#11 support]))
351 if test "$with_p11_kit" != "no"; then
352         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
353         if test "$with_p11_kit" != "no";then
354                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
355                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
356                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
357                 else
358                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
359                 fi
360         else
361                 with_p11_kit=no
362                 AC_MSG_WARN([[
363 *** 
364 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
365 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
366 *** ]])
367         fi
368 fi
369
370 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
371
372 AC_ARG_WITH(tpm,
373         AS_HELP_STRING([--without-tpm],
374                 [Disable TPM (trousers) support.]),
375                 [with_tpm=$withval], [with_tpm=yes])
376 if test "$with_tpm" != "no"; then
377     LIBS="$oldlibs -ltspi"
378     AC_MSG_CHECKING([for tss library])
379     AC_LINK_IFELSE([AC_LANG_PROGRAM([
380                    #include <trousers/tss.h>
381                    #include <trousers/trousers.h>],[
382                    int err = Tspi_Context_Create((void *)0);
383                    Trspi_Error_String(err);])],
384                   [AC_MSG_RESULT(yes)
385                    AC_SUBST([TSS_LIBS], [-ltspi])
386                    AC_SUBST([TSS_CFLAGS], [])
387                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
388                    with_tpm=yes],
389                   [AC_MSG_RESULT(no)
390                    AC_MSG_WARN([[
391 *** 
392 *** trousers was not found. TPM support will be disabled.
393 *** ]])
394                   with_tpm=no])
395     LIBS="$oldlibs"
396 fi
397
398 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
399
400 LIBOPTS_CHECK([src/libopts])
401 if test "$NEED_LIBOPTS_DIR" = "true";then
402         dnl delete libopts-generated files
403         for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do
404                 nam=`echo $i|sed 's/.bak//g'`
405                 if test -f $i;then
406                         cp -f $i $nam
407                 fi
408         done
409         AC_SUBST([AUTOGEN], [/bin/true])
410         enable_local_libopts=yes
411 else
412         enable_local_libopts=no
413 fi
414 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")
415
416 AC_CHECK_TYPE(ssize_t,
417   [
418     DEFINE_SSIZE_T="#include <sys/types.h>"
419     AC_SUBST(DEFINE_SSIZE_T)
420   ], [
421     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
422     DEFINE_SSIZE_T="typedef int ssize_t;"
423     AC_SUBST(DEFINE_SSIZE_T)
424   ], [
425     #include <sys/types.h>
426   ])
427
428 # For minitasn1.
429 AC_CHECK_SIZEOF(unsigned long int, 4)
430 AC_CHECK_SIZEOF(unsigned int, 4)
431
432 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
433                                  [disable zlib compression support]),
434             ac_zlib=$withval, ac_zlib=yes)
435 AC_MSG_CHECKING([whether to include zlib compression support])
436 if test x$ac_zlib != xno; then
437  AC_MSG_RESULT(yes)
438  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
439  if test x$ac_cv_libz != xyes; then
440    AC_MSG_WARN(
441 *** 
442 *** ZLIB was not found. You will not be able to use ZLIB compression.)
443  fi
444 else
445  AC_MSG_RESULT(no)
446 fi
447
448 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
449
450 if test x$ac_zlib != xno; then
451   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
452     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
453       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
454     else
455       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
456     fi
457   fi
458 fi
459 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
460
461
462
463 AC_ARG_WITH([default-trust-store-pkcs11],
464   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
465     [use the given pkcs11 uri as default trust store])])
466
467 if test "x$with_default_trust_store_pkcs11" != x; then
468   if test "x$with_p11_kit" = xno; then
469     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
470   fi
471   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
472     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
473 fi
474
475 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
476 AC_ARG_WITH([default-trust-store-file],
477   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
478     [use the given file default trust store])], with_default_trust_store_file="$withval",
479   [if test "$build" = "$host";then
480   for i in \
481     /etc/ssl/ca-bundle.pem \
482     /etc/ssl/certs/ca-certificates.crt \
483     /etc/pki/tls/cert.pem \
484     /usr/local/share/certs/ca-root-nss.crt \
485     /etc/ssl/cert.pem
486     do
487     if test -e $i; then
488       with_default_trust_store_file="$i"
489       break
490     fi
491   done
492   fi]
493 )
494
495 if test "$with_default_trust_store_file" = "no";then
496   with_default_trust_store_file=""
497 fi
498
499 AC_ARG_WITH([default-crl-file],
500   [AS_HELP_STRING([--with-default-crl-file=FILE],
501     [use the given CRL file as default])])
502
503 if test "x$with_default_trust_store_file" != x; then
504   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
505     ["$with_default_trust_store_file"], [use the given file default trust store])
506 fi
507
508 if test "x$with_default_crl_file" != x; then
509   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
510     ["$with_default_crl_file"], [use the given CRL file])
511 fi
512
513 dnl Guile bindings.
514 opt_guile_bindings=yes
515 AC_MSG_CHECKING([whether building Guile bindings])
516 AC_ARG_ENABLE(guile,
517         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
518 opt_guile_bindings=$enableval)
519 AC_MSG_RESULT($opt_guile_bindings)
520
521 AC_ARG_WITH([guile-site-dir],
522   [AS_HELP_STRING([--with-guile-site-dir],
523      [use the given directory as the Guile site (use with care)])])
524
525 if test "$opt_guile_bindings" = "yes"; then
526    AC_MSG_RESULT([***
527 *** Detecting GNU Guile...
528 ])
529
530    AC_PATH_PROG([guile_snarf], [guile-snarf])
531    if test "x$guile_snarf" = "x"; then
532       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
533       opt_guile_bindings=no
534    else
535       GUILE_PROGS
536       GUILE_FLAGS
537
538       save_CFLAGS="$CFLAGS"
539       save_LIBS="$LIBS"
540       CFLAGS="$CFLAGS $GUILE_CFLAGS"
541       LIBS="$LIBS $GUILE_LDFLAGS"
542       AC_MSG_CHECKING([whether GNU Guile is recent enough])
543       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
544         [], [opt_guile_bindings=no])
545       CFLAGS="$save_CFLAGS"
546       LIBS="$save_LIBS"
547
548       if test "$opt_guile_bindings" = "yes"; then
549         AC_MSG_RESULT([yes])
550         case "x$with_guile_site_dir" in 
551              xno)
552                 # Use the default $(GUILE_SITE).
553                 GUILE_SITE_DIR
554                 ;;
555              x|xyes)
556                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
557                 # hack is used to allow `distcheck' to work (see
558                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
559                 GUILE_SITE="\$(datadir)/guile/site"
560                 AC_SUBST(GUILE_SITE)
561                 ;;
562              *)
563                 # Use the user-specified directory as $(GUILE_SITE).
564                 GUILE_SITE="$with_guile_site_dir"
565                 AC_SUBST(GUILE_SITE)
566                 ;;
567         esac
568         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
569         _gcc_cflags_save="$CFLAGS"
570         CFLAGS="${CFLAGS} -fgnu89-inline"
571         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
572                           gnu89_inline=yes, gnu89_inline=no)
573         AC_MSG_RESULT($gnu89_inline)
574         CFLAGS="$_gcc_cflags_save"
575
576         # Optional Guile functions.
577         save_CFLAGS="$CFLAGS"
578         save_LIBS="$LIBS"
579         CFLAGS="$CFLAGS $GUILE_CFLAGS"
580         LIBS="$LIBS $GUILE_LDFLAGS"
581         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
582         CFLAGS="$save_CFLAGS"
583         LIBS="$save_LIBS"
584
585         # The place where guile-gnutls.la will go.
586         AC_MSG_CHECKING([the Guile effective version])
587         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
588         AC_MSG_RESULT([$guile_effective_version])
589         guileextensiondir="$libdir/guile/$guile_effective_version"
590         AC_SUBST([guileextensiondir])
591       else
592         AC_MSG_RESULT([no])
593         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
594         opt_guile_bindings=no
595       fi
596    fi
597 fi
598 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
599
600 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
601 LIBGNUTLS_CFLAGS="-I${includedir}"
602 AC_SUBST(LIBGNUTLS_LIBS)
603 AC_SUBST(LIBGNUTLS_CFLAGS)
604
605 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")
606
607 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
608 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
609
610 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
611 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
612 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
613
614 dnl Crywrap dependencies
615    AC_MSG_RESULT([***
616 *** Checking dependencies for crywrap...
617 ])
618
619 crywrap=no
620
621 if test "$have_win" != "yes"; then
622
623 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
624
625 dnl **********************
626 dnl * Typedefs & co
627 dnl **********************
628 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
629 [AC_LANG_PROGRAM([#include <sys/types.h>
630 #include <signal.h>
631 ],
632                  [return *(signal (0, 0)) (0) == 1;])],
633                    [ac_cv_type_signal=int],
634                    [ac_cv_type_signal=void])])
635 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
636                     (`int' or `void').])
637
638 AC_FUNC_SELECT_ARGTYPES
639 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
640                 putenv regcomp scandir select socket strcasecmp strchr \
641                 strdup strerror strncasecmp strrchr strstr strtoul uname])
642
643 AC_ARG_ENABLE(crywrap,
644         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
645
646  libidn=no
647
648  if test "x$enable_crywrap" != "xno" ; then
649         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
650         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
651  fi
652
653  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
654   crywrap=yes
655  fi
656
657 fi
658
659 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
660
661 dnl end of crywrap requirements
662
663 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
664 AC_CONFIG_FILES([
665   Makefile
666   doc/Makefile
667   doc/credentials/Makefile
668   doc/credentials/openpgp/Makefile
669   doc/credentials/srp/Makefile
670   doc/credentials/x509/Makefile
671   doc/cyclo/Makefile
672   doc/doxygen/Doxyfile
673   doc/examples/Makefile
674   doc/latex/Makefile
675   doc/manpages/Makefile
676   doc/reference/Makefile
677   doc/reference/version.xml
678   doc/scripts/Makefile
679   extra/Makefile
680   extra/includes/Makefile
681   libdane/Makefile
682   libdane/includes/Makefile
683   libdane/gnutls-dane.pc
684   gl/Makefile
685   gl/tests/Makefile
686   guile/Makefile
687   guile/modules/Makefile
688   guile/src/Makefile
689   guile/tests/Makefile
690   lib/Makefile
691   lib/accelerated/Makefile
692   lib/accelerated/x86/Makefile
693   lib/algorithms/Makefile
694   lib/auth/Makefile
695   lib/ext/Makefile
696   lib/extras/Makefile
697   lib/gnutls.pc
698   lib/includes/Makefile
699   lib/includes/gnutls/gnutls.h
700   lib/minitasn1/Makefile
701   lib/nettle/Makefile
702   lib/opencdk/Makefile
703   lib/openpgp/Makefile
704   lib/x509/Makefile
705   po/Makefile.in
706   src/Makefile
707   src/crywrap/Makefile
708   src/gl/Makefile
709   tests/Makefile
710   tests/cert-tests/Makefile
711   tests/dsa/Makefile
712   tests/dtls/Makefile
713   tests/srp/Makefile
714   tests/ecdsa/Makefile
715   tests/key-id/Makefile
716   tests/openpgp-certs/Makefile
717   tests/pkcs1-padding/Makefile
718   tests/pkcs12-decode/Makefile
719   tests/pkcs8-decode/Makefile
720   tests/rsa-md5-collision/Makefile
721   tests/safe-renegotiation/Makefile
722   tests/scripts/Makefile
723   tests/sha2/Makefile
724   tests/slow/Makefile
725   tests/suite/Makefile
726   tests/userid/Makefile
727 ])
728
729 AC_OUTPUT
730
731 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
732 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
733 AC_MSG_NOTICE([summary of build options:
734
735   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
736   Host/Target system:   ${host}
737   Build system:         ${build}
738   Install prefix:       ${prefix}
739   Compiler:             ${CC}
740   CFlags:               ${CFLAGS}
741   Library types:        Shared=${enable_shared}, Static=${enable_static}
742 ])
743
744 AC_MSG_NOTICE([External hardware support:
745
746   /dev/crypto:          $enable_cryptodev
747   Hardware accel:       $hw_accel
748   PKCS#11 support:      $with_p11_kit
749   TPM support:          $with_tpm
750 ])
751
752 AC_MSG_NOTICE([Optional features:
753 (note that included applications might not compile properly
754 if features are disabled)
755
756   DTLS-SRTP support:    $ac_enable_srtp
757   ALPN support:         $ac_enable_alpn
758   OCSP support:         $ac_enable_ocsp
759   OpenPGP support:      $ac_enable_openpgp
760   SRP support:          $ac_enable_srp
761   PSK support:          $ac_enable_psk
762   DHE support:          $ac_enable_dhe
763   ECDHE support:        $ac_enable_ecdhe
764   Anon auth support:    $ac_enable_anon
765   Heartbeat support:    $ac_enable_heartbeat
766   RSA-EXPORT compat:    $ac_enable_rsa_export
767   Unicode support:      $ac_have_unicode
768   Self checks:          $enable_self_checks
769   Non-SuiteB curves:    $enable_non_suiteb
770   FIPS140 mode:         $enable_fips
771 ])
772
773 AC_MSG_NOTICE([Optional applications:
774
775   crywrap app:          $libidn
776   local libopts:        ${enable_local_libopts}
777   local libtasn1:       ${included_libtasn1}
778 ])
779
780 AC_MSG_NOTICE([Optional libraries:
781
782   Guile wrappers:       $opt_guile_bindings
783   C++ library:          $use_cxx
784   DANE library:         $enable_dane
785   OpenSSL compat:       $enable_openssl
786 ])
787
788 AC_MSG_NOTICE([System files:
789
790   Trust store pkcs:     $with_default_trust_store_pkcs11
791   Trust store file:     $with_default_trust_store_file
792   CRL file:             $with_default_crl_file
793   DNSSEC root key file: $unbound_root_key_file
794 ])
795
796 if test ! -f "$unbound_root_key_file"; then
797 AC_MSG_WARN([[
798 *** 
799 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
800 *** This file is needed for the verification of DNSSEC responses.
801 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
802 *** to generate or update it.
803 *** ]])
804 fi