Support for TPM modules via trousers is now enabled by default.
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.2.5], [bug-gnutls@gnu.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 AM_PROG_AS
41 AM_PROG_AR
42 AC_PROG_CXX
43
44 # For includes/gnutls/gnutls.h.in.
45 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
46 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
47 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
48 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
49
50 touch suppressions.valgrind
51 dnl C and C++ capabilities
52 AC_C_INLINE
53 AC_HEADER_STDC
54
55 # For the C++ code
56 AC_ARG_ENABLE(cxx,
57   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
58     use_cxx=$enableval, use_cxx=yes)
59 if test "$use_cxx" != "no"; then
60   AC_LANG_PUSH(C++)
61   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
62   AC_LANG_POP(C++)
63 fi
64 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
65 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
66
67 dnl Detect windows build
68 case "$host" in
69   *mingw32* | *mingw64*)
70     have_win=yes
71   ;;
72   *darwin*)
73     have_macosx=yes
74   ;;
75   *)
76     have_elf=yes
77   ;;
78 esac
79
80 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
81 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
82 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
83
84 dnl Hardware Acceleration
85 AC_ARG_ENABLE(hardware-acceleration,
86   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
87     use_accel=$enableval, use_accel=yes)
88 hw_accel=none
89
90
91 if test "$use_accel" != "no"; then
92 case $host_cpu in
93   i?86 | x86_64 | amd64)
94       AC_CHECK_HEADERS(cpuid.h)
95       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
96         hw_accel="x86-64"
97       else
98         hw_accel="x86"
99       fi
100   ;;
101   *)
102   ;;
103 esac
104
105 fi
106
107 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
108 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
109 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
110 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
111 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
112
113 dnl Try the hooks.m4
114 LIBGNUTLS_HOOKS
115 LIBGNUTLS_EXTRA_HOOKS
116
117 AC_ARG_ENABLE(doc,
118   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
119     enable_doc=$enableval, enable_doc=yes)
120 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
121
122 AC_ARG_ENABLE(tests,
123   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
124     enable_tests=$enableval, enable_tests=yes)
125 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
126
127 GTK_DOC_CHECK(1.1)
128 AM_GNU_GETTEXT([external])
129 AM_GNU_GETTEXT_VERSION([0.18])
130
131 AC_C_BIGENDIAN
132
133 gl_INIT
134
135 dnl GCC warnings to enable
136
137 AC_ARG_ENABLE([gcc-warnings],
138   [AS_HELP_STRING([--enable-gcc-warnings],
139                   [turn on lots of GCC warnings (for developers)])],
140   [case $enableval in
141      yes|no) ;;
142      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
143    esac
144    gl_gcc_warnings=$enableval],
145   [gl_gcc_warnings=no]
146 )
147
148 if test "$gl_gcc_warnings" = yes; then
149   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
150
151   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
152   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
153   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
154   nw="$nw -Wtraditional"            # Warns on #elif which we use often
155   nw="$nw -Wlogical-op"             # Too many false positives
156   nw="$nw -Wold-style-definition"   # 
157   nw="$nw -Wpadded"                 # Our structs are not padded
158   nw="$nw -Wunreachable-code"       # Too many false positives
159   nw="$nw -Wtraditional-conversion" # Too many warnings for now
160   nw="$nw -Wcast-qual"              # Too many warnings for now
161   nw="$nw -Waggregate-return"       # Too many warnings for now
162   nw="$nw -Wshadow"                 # Too many warnings for now
163   nw="$nw -Wswitch-default"         # Too many warnings for now
164   nw="$nw -Wswitch-enum"            # Too many warnings for now
165   nw="$nw -Wconversion"             # Too many warnings for now
166   nw="$nw -Wsign-conversion"        # Too many warnings for now
167   nw="$nw -Wformat-y2k"             # Too many warnings for now
168   nw="$nw -Woverlength-strings"     # We use some in tests/
169   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
170   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
171   nw="$nw -Wunsafe-loop-optimizations"
172   nw="$nw -Wstrict-overflow"
173   nw="$nw -Wmissing-noreturn"
174   nw="$nw -Winline"                 # Too compiler dependent
175   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
176   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
177   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
178   nw="$nw -Wstack-protector"        # Some functions cannot be protected
179   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
180
181   gl_MANYWARN_ALL_GCC([ws])
182   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
183   for w in $ws; do
184     gl_WARN_ADD([$w])
185   done
186
187   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
188   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
189   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
190   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
191   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
192   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
193   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
194   gl_WARN_ADD([-fdiagnostics-show-option])
195 fi
196
197 AC_SUBST([WERROR_CFLAGS])
198 AC_SUBST([WSTACK_CFLAGS])
199 AC_SUBST([WARN_CFLAGS])
200
201 dnl Programs for compilation or development
202 AC_PROG_LN_S
203 AC_LIBTOOL_WIN32_DLL
204 AC_PROG_LIBTOOL
205
206
207 dnl No fork on MinGW, disable some self-tests until we fix them.
208 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
209 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)
210 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
211
212 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
213   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
214 fi
215
216 if test "$ac_cv_func_nanosleep" != "yes";then
217   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
218 fi
219
220 ac_have_unicode=no
221 if test "$ac_cv_func_iconv" != "yes";then
222   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
223   if test "$HAVE_LIBICONV" = "yes";then
224     ac_have_unicode=yes
225   fi
226 else
227   ac_have_unicode=yes
228 fi
229
230 if test "$ac_have_unicode" != "yes";then
231   if test "$have_win" = "yes";then
232     ac_have_unicode=yes
233   fi
234 fi
235
236 AC_MSG_CHECKING([whether to build libdane])
237 AC_ARG_ENABLE(libdane,
238     AS_HELP_STRING([--disable-libdane],
239                    [disable the built of libdane]),
240     enable_dane=$enableval, enable_dane=yes)
241 AC_MSG_RESULT($enable_dane)
242
243 if test "$enable_dane" != "no"; then
244     LIBS="$oldlibs -lunbound"
245     AC_MSG_CHECKING([for unbound library])
246     AC_LINK_IFELSE([AC_LANG_PROGRAM([
247                    #include <unbound.h>],[
248                    struct ub_ctx* ctx;
249                    ctx = ub_ctx_create();])],
250                   [AC_MSG_RESULT(yes)
251                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
252                    AC_SUBST([UNBOUND_CFLAGS], [])
253                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
254                    enable_dane=yes],
255                   [AC_MSG_RESULT(no)
256                    AC_MSG_WARN([[
257 *** 
258 *** libunbound was not found. Libdane will not be built.
259 *** ]])
260                   enable_dane=no])
261     LIBS="$oldlibs"
262 fi
263
264 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
265
266 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
267                                  [specify the unbound root key file]),
268             unbound_root_key_file="$withval", 
269 if test "$have_win" = yes; then
270     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
271 else
272     unbound_root_key_file="/etc/unbound/root.key"
273 fi
274 )
275
276 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
277   ["$unbound_root_key_file"], [The DNSSEC root key file])
278
279 dnl Check for p11-kit
280 AC_ARG_WITH(p11-kit,
281         AS_HELP_STRING([--without-p11-kit],
282                 [Build without p11-kit and PKCS#11 support]))
283 if test "$with_p11_kit" != "no"; then
284         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.11], [with_p11_kit=yes], [with_p11_kit=no])
285         if test "$with_p11_kit" != "no";then
286                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
287                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
288                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
289                 else
290                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
291                 fi
292         else
293                 with_p11_kit=no
294                 AC_MSG_WARN([[
295 *** 
296 *** p11-kit was not found. PKCS #11 support will be disabled.
297 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
298 *** ]])
299         fi
300 fi
301
302 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
303
304 AC_ARG_WITH(tpm,
305         AS_HELP_STRING([--without-tpm],
306                 [Disable TPM (trousers) support.]),
307                 [with_tpm=$withval], [with_tpm=yes])
308 if test "$with_tpm" != "no"; then
309     LIBS="$oldlibs -ltspi"
310     AC_MSG_CHECKING([for tss library])
311     AC_LINK_IFELSE([AC_LANG_PROGRAM([
312                    #include <trousers/tss.h>
313                    #include <trousers/trousers.h>],[
314                    int err = Tspi_Context_Create((void *)0);
315                    Trspi_Error_String(err);])],
316                   [AC_MSG_RESULT(yes)
317                    AC_SUBST([TSS_LIBS], [-ltspi])
318                    AC_SUBST([TSS_CFLAGS], [])
319                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
320                    with_tpm=yes],
321                   [AC_MSG_RESULT(no)
322                    AC_MSG_WARN([[
323 *** 
324 *** trousers was not found. TPM support will be disabled.
325 *** ]])
326                   with_tpm=no])
327     LIBS="$oldlibs"
328 fi
329
330 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
331
332 enable_local_libopts=yes
333 dnl PKG_CHECK_MODULES([autoopts], autoopts >= 36.2.11,, [enable_local_libopts=yes])
334
335 NEED_LIBOPTS_DIR=true
336 LIBOPTS_CHECK([src/libopts])
337
338 AC_CHECK_TYPE(ssize_t,
339   [
340     DEFINE_SSIZE_T="#include <sys/types.h>"
341     AC_SUBST(DEFINE_SSIZE_T)
342   ], [
343     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
344     DEFINE_SSIZE_T="typedef int ssize_t;"
345     AC_SUBST(DEFINE_SSIZE_T)
346   ], [
347     #include <sys/types.h>
348   ])
349
350 # For minitasn1.
351 AC_CHECK_SIZEOF(unsigned long int, 4)
352 AC_CHECK_SIZEOF(unsigned int, 4)
353
354 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
355                                  [disable zlib compression support]),
356             ac_zlib=$withval, ac_zlib=yes)
357 AC_MSG_CHECKING([whether to include zlib compression support])
358 if test x$ac_zlib != xno; then
359  AC_MSG_RESULT(yes)
360  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
361  if test x$ac_cv_libz != xyes; then
362    AC_MSG_WARN(
363 *** 
364 *** ZLIB was not found. You will not be able to use ZLIB compression.)
365  fi
366 else
367  AC_MSG_RESULT(no)
368 fi
369
370 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
371
372 if test x$ac_zlib != xno; then
373   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
374     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
375       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
376     else
377       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
378     fi
379   fi
380 fi
381 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
382
383
384
385 AC_ARG_WITH([default-trust-store-pkcs11],
386   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
387     [use the given pkcs11 uri as default trust store])])
388
389 if test "x$with_default_trust_store_pkcs11" != x; then
390   if test "x$with_p11_kit" = xno; then
391     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
392   fi
393   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
394     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
395 fi
396
397 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
398 AC_ARG_WITH([default-trust-store-file],
399   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
400     [use the given file default trust store])], with_default_trust_store_file="$withval",
401   [if test "$build" = "$host";then
402   for i in \
403     /etc/ssl/ca-bundle.pem \
404     /etc/ssl/certs/ca-certificates.crt \
405     /etc/pki/tls/cert.pem \
406     /usr/local/share/certs/ca-root-nss.crt \
407     /etc/ssl/cert.pem
408     do
409     if test -e $i; then
410       with_default_trust_store_file="$i"
411       break
412     fi
413   done
414   fi]
415 )
416
417 if test "$with_default_trust_store_file" = "no";then
418   with_default_trust_store_file=""
419 fi
420
421 AC_ARG_WITH([default-crl-file],
422   [AS_HELP_STRING([--with-default-crl-file=FILE],
423     [use the given CRL file as default])])
424
425 if test "x$with_default_trust_store_file" != x; then
426   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
427     ["$with_default_trust_store_file"], [use the given file default trust store])
428 fi
429
430 if test "x$with_default_crl_file" != x; then
431   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
432     ["$with_default_crl_file"], [use the given CRL file])
433 fi
434
435 dnl Guile bindings.
436 opt_guile_bindings=yes
437 AC_MSG_CHECKING([whether building Guile bindings])
438 AC_ARG_ENABLE(guile,
439         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
440 opt_guile_bindings=$enableval)
441 AC_MSG_RESULT($opt_guile_bindings)
442
443 AC_ARG_WITH([guile-site-dir],
444   [AS_HELP_STRING([--with-guile-site-dir],
445      [use the given directory as the Guile site (use with care)])])
446
447 if test "$opt_guile_bindings" = "yes"; then
448    AC_MSG_RESULT([***
449 *** Detecting GNU Guile...
450 ])
451
452    AC_PATH_PROG([guile_snarf], [guile-snarf])
453    if test "x$guile_snarf" = "x"; then
454       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
455       opt_guile_bindings=no
456    else
457       GUILE_PROGS
458       GUILE_FLAGS
459
460       save_CFLAGS="$CFLAGS"
461       save_LIBS="$LIBS"
462       CFLAGS="$CFLAGS $GUILE_CFLAGS"
463       LIBS="$LIBS $GUILE_LDFLAGS"
464       AC_MSG_CHECKING([whether GNU Guile is recent enough])
465       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
466         [], [opt_guile_bindings=no])
467       CFLAGS="$save_CFLAGS"
468       LIBS="$save_LIBS"
469
470       if test "$opt_guile_bindings" = "yes"; then
471         AC_MSG_RESULT([yes])
472         case "x$with_guile_site_dir" in 
473              xno)
474                 # Use the default $(GUILE_SITE).
475                 GUILE_SITE_DIR
476                 ;;
477              x|xyes)
478                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
479                 # hack is used to allow `distcheck' to work (see
480                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
481                 GUILE_SITE="\$(datadir)/guile/site"
482                 AC_SUBST(GUILE_SITE)
483                 ;;
484              *)
485                 # Use the user-specified directory as $(GUILE_SITE).
486                 GUILE_SITE="$with_guile_site_dir"
487                 AC_SUBST(GUILE_SITE)
488                 ;;
489         esac
490         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
491         _gcc_cflags_save="$CFLAGS"
492         CFLAGS="${CFLAGS} -fgnu89-inline"
493         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
494                           gnu89_inline=yes, gnu89_inline=no)
495         AC_MSG_RESULT($gnu89_inline)
496         CFLAGS="$_gcc_cflags_save"
497
498         # Optional Guile functions.
499         save_CFLAGS="$CFLAGS"
500         save_LIBS="$LIBS"
501         CFLAGS="$CFLAGS $GUILE_CFLAGS"
502         LIBS="$LIBS $GUILE_LDFLAGS"
503         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
504         CFLAGS="$save_CFLAGS"
505         LIBS="$save_LIBS"
506
507         # The place where guile-gnutls.la will go.
508         AC_MSG_CHECKING([the Guile effective version])
509         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
510         AC_MSG_RESULT([$guile_effective_version])
511         guileextensiondir="$libdir/guile/$guile_effective_version"
512         AC_SUBST([guileextensiondir])
513       else
514         AC_MSG_RESULT([no])
515         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
516         opt_guile_bindings=no
517       fi
518    fi
519 fi
520 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
521
522 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
523 LIBGNUTLS_CFLAGS="-I${includedir}"
524 AC_SUBST(LIBGNUTLS_LIBS)
525 AC_SUBST(LIBGNUTLS_CFLAGS)
526
527
528 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
529 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
530
531 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
532 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
533 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
534
535 dnl Crywrap dependencies
536    AC_MSG_RESULT([***
537 *** Checking dependencies for crywrap...
538 ])
539
540 crywrap=no
541
542 if test "$have_win" != "yes"; then
543
544 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
545
546 dnl **********************
547 dnl * Typedefs & co
548 dnl **********************
549 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
550 [AC_LANG_PROGRAM([#include <sys/types.h>
551 #include <signal.h>
552 ],
553                  [return *(signal (0, 0)) (0) == 1;])],
554                    [ac_cv_type_signal=int],
555                    [ac_cv_type_signal=void])])
556 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
557                     (`int' or `void').])
558
559 AC_FUNC_SELECT_ARGTYPES
560 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
561                 putenv regcomp scandir select socket strcasecmp strchr \
562                 strdup strerror strncasecmp strrchr strstr strtoul uname])
563
564 AC_ARG_ENABLE(crywrap,
565         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
566
567  libidn=no
568
569  if test "x$enable_crywrap" != "xno" ; then
570         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
571         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
572  fi
573
574  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
575   crywrap=yes
576  fi
577
578 fi
579
580 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
581 rm -f suppressions.valgrind
582 dnl end of crywrap requirements
583
584 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
585 AC_CONFIG_FILES([
586   Makefile
587   doc/Makefile
588   doc/credentials/Makefile
589   doc/credentials/openpgp/Makefile
590   doc/credentials/srp/Makefile
591   doc/credentials/x509/Makefile
592   doc/cyclo/Makefile
593   doc/doxygen/Doxyfile
594   doc/examples/Makefile
595   doc/latex/Makefile
596   doc/manpages/Makefile
597   doc/reference/Makefile
598   doc/reference/version.xml
599   doc/scripts/Makefile
600   extra/Makefile
601   extra/includes/Makefile
602   libdane/Makefile
603   libdane/includes/Makefile
604   libdane/gnutls-dane.pc
605   gl/Makefile
606   gl/tests/Makefile
607   guile/Makefile
608   guile/modules/Makefile
609   guile/src/Makefile
610   guile/tests/Makefile
611   lib/Makefile
612   lib/accelerated/Makefile
613   lib/accelerated/x86/Makefile
614   lib/algorithms/Makefile
615   lib/auth/Makefile
616   lib/ext/Makefile
617   lib/extras/Makefile
618   lib/gnutls.pc
619   lib/includes/Makefile
620   lib/includes/gnutls/gnutls.h
621   lib/minitasn1/Makefile
622   lib/nettle/Makefile
623   lib/opencdk/Makefile
624   lib/openpgp/Makefile
625   lib/x509/Makefile
626   po/Makefile.in
627   src/Makefile
628   src/crywrap/Makefile
629   tests/Makefile
630   tests/cert-tests/Makefile
631   tests/dsa/Makefile
632   tests/dtls/Makefile
633   tests/srp/Makefile
634   tests/ecdsa/Makefile
635   tests/key-id/Makefile
636   tests/openpgp-certs/Makefile
637   tests/pkcs1-padding/Makefile
638   tests/pkcs12-decode/Makefile
639   tests/pkcs8-decode/Makefile
640   tests/rsa-md5-collision/Makefile
641   tests/safe-renegotiation/Makefile
642   tests/scripts/Makefile
643   tests/sha2/Makefile
644   tests/slow/Makefile
645   tests/suite/Makefile
646   tests/userid/Makefile
647 ])
648
649 AC_OUTPUT
650
651 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
652 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
653 AC_MSG_NOTICE([summary of build options:
654
655   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
656   Host/Target system:   ${host}
657   Build system:         ${build}
658   Install prefix:       ${prefix}
659   Compiler:             ${CC}
660   CFlags:               ${CFLAGS}
661   Library types:        Shared=${enable_shared}, Static=${enable_static}
662 ])
663
664 AC_MSG_NOTICE([External hardware support:
665
666   /dev/crypto:          $enable_cryptodev
667   Hardware accel:       $hw_accel
668   PKCS#11 support:      $with_p11_kit
669   TPM support:          $with_tpm
670 ])
671
672 AC_MSG_NOTICE([Optional features:
673 (note that included applications might not compile properly
674 if features are disabled)
675
676   DTLS-SRTP support:    $ac_enable_srtp
677   ALPN support:         $ac_enable_alpn
678   OCSP support:         $ac_enable_ocsp
679   OpenPGP support:      $ac_enable_openpgp
680   SRP support:          $ac_enable_srp
681   PSK support:          $ac_enable_psk
682   DHE support:          $ac_enable_dhe
683   ECDHE support:        $ac_enable_ecdhe
684   Anon auth support:    $ac_enable_anon
685   Heartbeat support:    $ac_enable_heartbeat
686   RSA-EXPORT compat:    $ac_enable_rsa_export
687   Unicode support:      $ac_have_unicode
688 ])
689
690 AC_MSG_NOTICE([Optional applications:
691
692   crywrap app:          $libidn
693   local libopts:        $enable_local_libopts
694 ])
695
696 AC_MSG_NOTICE([Optional libraries:
697
698   Guile wrappers:       $opt_guile_bindings
699   C++ library:          $use_cxx
700   DANE library:         $enable_dane
701   OpenSSL compat:       $enable_openssl
702 ])
703
704 AC_MSG_NOTICE([System files:
705
706   Trust store pkcs:     $with_default_trust_store_pkcs11
707   Trust store file:     $with_default_trust_store_file
708   CRL file:             $with_default_crl_file
709   DNSSEC root key file: $unbound_root_key_file
710 ])
711
712 if test ! -f "$unbound_root_key_file"; then
713 AC_MSG_WARN([[
714 *** 
715 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
716 *** This file is needed for the verification of DNSSEC responses.
717 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
718 *** to generate or update it.
719 *** ]])
720 fi