checks FIPS-140 lib requirements, moved after clock_gettime() is checked for.
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.3.0], [bugs@gnutls.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 subdir-objects no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 ggl_EARLY
41 AM_PROG_AS
42 AM_PROG_AR
43 AC_PROG_CXX
44 AM_PROG_CC_C_O
45 AC_PROG_YACC
46 AC_CHECK_PROG([AUTOGEN], [autogen], [autogen], [/bin/true])
47
48 if test x"$AUTOGEN" = "x/bin/true"; then
49   AC_MSG_WARN([[
50 ***
51 *** autogen not found. Will not link against libopts.
52 *** ]])
53 enable_local_libopts=yes
54 fi
55
56 # For includes/gnutls/gnutls.h.in.
57 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
58 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
59 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
60 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
61
62 touch suppressions.valgrind
63 dnl C and C++ capabilities
64 AC_C_INLINE
65 AC_HEADER_STDC
66
67 # For the C++ code
68 AC_ARG_ENABLE(cxx,
69   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
70     use_cxx=$enableval, use_cxx=yes)
71 if test "$use_cxx" != "no"; then
72   AC_LANG_PUSH(C++)
73   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
74   AC_LANG_POP(C++)
75 fi
76 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
77 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
78
79 dnl Detect windows build
80 case "$host" in
81   *mingw32* | *mingw64*)
82     have_win=yes
83   ;;
84   *darwin*)
85     have_macosx=yes
86   ;;
87   *)
88     have_elf=yes
89   ;;
90 esac
91
92 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
93 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
94 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
95
96 dnl Hardware Acceleration
97 AC_ARG_ENABLE(hardware-acceleration,
98   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
99     use_accel=$enableval, use_accel=yes)
100 hw_accel=none
101
102
103 if test "$use_accel" != "no"; then
104 case $host_cpu in
105   i?86 | x86_64 | amd64)
106       AC_CHECK_HEADERS(cpuid.h)
107       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
108         hw_accel="x86-64"
109       else
110         hw_accel="x86"
111       fi
112   ;;
113   *)
114   ;;
115 esac
116
117 fi
118
119 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
120 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
121 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
122 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
123 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
124
125
126 dnl Try the hooks.m4
127 LIBGNUTLS_HOOKS
128 LIBGNUTLS_EXTRA_HOOKS
129
130 AC_ARG_ENABLE(doc,
131   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
132     enable_doc=$enableval, enable_doc=yes)
133 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
134
135 AC_ARG_ENABLE(tests,
136   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
137     enable_tests=$enableval, enable_tests=yes)
138 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
139
140 GTK_DOC_CHECK(1.1)
141 AM_GNU_GETTEXT([external])
142 AM_GNU_GETTEXT_VERSION([0.18])
143
144 AC_C_BIGENDIAN
145
146 gl_INIT
147 ggl_INIT
148
149 dnl GCC warnings to enable
150
151 AC_ARG_ENABLE([gcc-warnings],
152   [AS_HELP_STRING([--enable-gcc-warnings],
153                   [turn on lots of GCC warnings (for developers)])],
154   [case $enableval in
155      yes|no) ;;
156      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
157    esac
158    gl_gcc_warnings=$enableval],
159   [gl_gcc_warnings=no]
160 )
161
162 if test "$gl_gcc_warnings" = yes; then
163   gl_WARN_ADD([-Wframe-larger-than=1024], [WSTACK_CFLAGS])
164
165   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
166   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
167   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
168   nw="$nw -Wtraditional"            # Warns on #elif which we use often
169   nw="$nw -Wlogical-op"             # Too many false positives
170   nw="$nw -Wold-style-definition"   # 
171   nw="$nw -Wpadded"                 # Our structs are not padded
172   nw="$nw -Wunreachable-code"       # Too many false positives
173   nw="$nw -Wtraditional-conversion" # Too many warnings for now
174   nw="$nw -Wcast-qual"              # Too many warnings for now
175   nw="$nw -Waggregate-return"       # Too many warnings for now
176   nw="$nw -Wshadow"                 # Too many warnings for now
177   nw="$nw -Wswitch-default"         # Too many warnings for now
178   nw="$nw -Wswitch-enum"            # Too many warnings for now
179   nw="$nw -Wconversion"             # Too many warnings for now
180   nw="$nw -Wsign-conversion"        # Too many warnings for now
181   nw="$nw -Wformat-y2k"             # Too many warnings for now
182   nw="$nw -Woverlength-strings"     # We use some in tests/
183   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
184   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
185   nw="$nw -Wunsafe-loop-optimizations"
186   nw="$nw -Wstrict-overflow"
187   nw="$nw -Wmissing-noreturn"
188   nw="$nw -Winline"                 # Too compiler dependent
189   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
190   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
191   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
192   nw="$nw -Wstack-protector"        # Some functions cannot be protected
193   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
194
195   gl_MANYWARN_ALL_GCC([ws])
196   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
197   for w in $ws; do
198     gl_WARN_ADD([$w])
199   done
200
201   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
202   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
203   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
204   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
205   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
206   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
207   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
208   gl_WARN_ADD([-fdiagnostics-show-option])
209 fi
210
211 AC_SUBST([WERROR_CFLAGS])
212 AC_SUBST([WSTACK_CFLAGS])
213 AC_SUBST([WARN_CFLAGS])
214
215 dnl Programs for compilation or development
216 AC_PROG_LN_S
217 AC_LIBTOOL_WIN32_DLL
218 AC_PROG_LIBTOOL
219
220
221 dnl No fork on MinGW, disable some self-tests until we fix them.
222 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
223 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock iconv localtime vasprintf],,)
224 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
225
226 AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>
227 #include <signal.h>
228 ], [timer_create (0,0,0);])
229
230 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
231   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
232 fi
233
234 if test "$ac_cv_func_nanosleep" != "yes";then
235   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
236   gnutls_needs_librt=yes
237 fi
238
239 ac_have_unicode=no
240 if test "$ac_cv_func_iconv" != "yes";then
241   AC_LIB_HAVE_LINKFLAGS(iconv,, [#include <iconv.h>], [iconv (0, 0, 0, 0, 0);])
242   if test "$HAVE_LIBICONV" = "yes";then
243     ac_have_unicode=yes
244   fi
245 else
246   ac_have_unicode=yes
247 fi
248
249 if test "$ac_have_unicode" != "yes";then
250   if test "$have_win" = "yes";then
251     ac_have_unicode=yes
252   fi
253 fi
254
255 AC_ARG_ENABLE(self-checks,
256   AS_HELP_STRING([--enable-self-checks], [enable self checking functionality]),
257     enable_self_checks=$enableval, enable_self_checks=no)
258
259 AC_ARG_ENABLE(fips140-mode,
260   AS_HELP_STRING([--enable-fips140-mode], [enable FIPS140-2 mode (implies self checks)]),
261     enable_fips=$enableval, enable_fips=no)
262 AM_CONDITIONAL(ENABLE_FIPS140, test "$enable_fips" = "yes")
263 if [ test "$enable_fips" = "yes" ];then
264   AC_LIB_HAVE_LINKFLAGS(dl,, [#include <dlfcn.h>], [dladdr (0, 0);])
265   if test "x$HAVE_LIBDL" = "xyes";then
266     enable_self_checks=yes
267
268     dnl clock_gettime precision is needed on the FIPS140 DRBG.
269     if test "$ac_cv_func_clock_gettime" != "yes";then
270       AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [clock_gettime (0, 0);])
271     fi
272
273     AC_DEFINE([ENABLE_FIPS140], 1, [Enable FIPS140-2 mode])
274
275     AC_SUBST([FIPS140_LIBS], $LIBDL)
276   else
277     enable_fips=no
278     AC_MSG_WARN([[
279 *** 
280 *** This system is not supported in FIPS140 mode.
281 *** libdl and dladdr() are required.
282 *** ]])
283   fi
284 fi
285
286 AC_ARG_ENABLE(non-suiteb-curves,
287   AS_HELP_STRING([--disable-non-suiteb-curves], [disable curves not in SuiteB]),
288     enable_non_suiteb=$enableval, enable_non_suiteb=yes)
289 if [ test "$enable_non_suiteb" = "yes" ];then
290   AC_DEFINE([ENABLE_NON_SUITEB_CURVES], 1, [Enable all curves])
291 fi
292
293 AM_CONDITIONAL(ENABLE_SELF_CHECKS, test "$enable_self_checks" = "yes")
294 if [ test "$enable_self_checks" = "yes" ];then
295    AC_DEFINE([ENABLE_SELF_CHECKS], 1, [Self checks are included in the library])
296 fi
297
298 AC_MSG_CHECKING([whether to build libdane])
299 AC_ARG_ENABLE(libdane,
300     AS_HELP_STRING([--disable-libdane],
301                    [disable the built of libdane]),
302     enable_dane=$enableval, enable_dane=yes)
303 AC_MSG_RESULT($enable_dane)
304
305 if test "$enable_dane" != "no"; then
306     LIBS="$oldlibs -lunbound"
307     AC_MSG_CHECKING([for unbound library])
308     AC_LINK_IFELSE([AC_LANG_PROGRAM([
309                    #include <unbound.h>],[
310                    struct ub_ctx* ctx;
311                    ctx = ub_ctx_create();])],
312                   [AC_MSG_RESULT(yes)
313                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
314                    AC_SUBST([UNBOUND_CFLAGS], [])
315                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
316                    enable_dane=yes],
317                   [AC_MSG_RESULT(no)
318                    AC_MSG_WARN([[
319 *** 
320 *** libunbound was not found. Libdane will not be built.
321 *** ]])
322                   enable_dane=no])
323     LIBS="$oldlibs"
324 fi
325
326 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
327
328 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
329                                  [specify the unbound root key file]),
330             unbound_root_key_file="$withval", 
331 if test "$have_win" = yes; then
332     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
333 else
334     if test -f /var/lib/unbound/root.key;then
335         unbound_root_key_file="/var/lib/unbound/root.key"
336     else
337         unbound_root_key_file="/etc/unbound/root.key"
338     fi
339 fi
340 )
341
342 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
343   ["$unbound_root_key_file"], [The DNSSEC root key file])
344
345 dnl Check for p11-kit
346 P11_KIT_MINIMUM=0.19.1
347 AC_ARG_WITH(p11-kit,
348         AS_HELP_STRING([--without-p11-kit],
349                 [Build without p11-kit and PKCS#11 support]))
350 if test "$with_p11_kit" != "no"; then
351         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= $P11_KIT_MINIMUM], [with_p11_kit=yes], [with_p11_kit=no])
352         if test "$with_p11_kit" != "no";then
353                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
354                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
355                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
356                 else
357                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
358                 fi
359         else
360                 with_p11_kit=no
361                 AC_MSG_WARN([[
362 *** 
363 *** p11-kit >= $P11_KIT_MINIMUM was not found. PKCS #11 support will be disabled.
364 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
365 *** ]])
366         fi
367 fi
368
369 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
370
371 AC_ARG_WITH(tpm,
372         AS_HELP_STRING([--without-tpm],
373                 [Disable TPM (trousers) support.]),
374                 [with_tpm=$withval], [with_tpm=yes])
375 if test "$with_tpm" != "no"; then
376     LIBS="$oldlibs -ltspi"
377     AC_MSG_CHECKING([for tss library])
378     AC_LINK_IFELSE([AC_LANG_PROGRAM([
379                    #include <trousers/tss.h>
380                    #include <trousers/trousers.h>],[
381                    int err = Tspi_Context_Create((void *)0);
382                    Trspi_Error_String(err);])],
383                   [AC_MSG_RESULT(yes)
384                    AC_SUBST([TSS_LIBS], [-ltspi])
385                    AC_SUBST([TSS_CFLAGS], [])
386                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
387                    with_tpm=yes],
388                   [AC_MSG_RESULT(no)
389                    AC_MSG_WARN([[
390 *** 
391 *** trousers was not found. TPM support will be disabled.
392 *** ]])
393                   with_tpm=no])
394     LIBS="$oldlibs"
395 fi
396
397 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
398
399 LIBOPTS_CHECK([src/libopts])
400 if test "$NEED_LIBOPTS_DIR" == "true";then
401         dnl delete libopts-generated files
402         for i in ${srcdir}/src/*-args.c.bak ${srcdir}/src/*-args.h.bak; do
403                 nam=`echo $i|sed 's/.bak//g'`
404                 if test -f $i;then
405                         cp -f $i $nam
406                 fi
407         done
408         AC_SUBST([AUTOGEN], [/bin/true])
409         enable_local_libopts=yes
410 else
411         enable_local_libopts=no
412 fi
413 AM_CONDITIONAL(NEED_LIBOPTS, test "$enable_local_libopts" = "yes")
414
415 AC_CHECK_TYPE(ssize_t,
416   [
417     DEFINE_SSIZE_T="#include <sys/types.h>"
418     AC_SUBST(DEFINE_SSIZE_T)
419   ], [
420     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
421     DEFINE_SSIZE_T="typedef int ssize_t;"
422     AC_SUBST(DEFINE_SSIZE_T)
423   ], [
424     #include <sys/types.h>
425   ])
426
427 # For minitasn1.
428 AC_CHECK_SIZEOF(unsigned long int, 4)
429 AC_CHECK_SIZEOF(unsigned int, 4)
430
431 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
432                                  [disable zlib compression support]),
433             ac_zlib=$withval, ac_zlib=yes)
434 AC_MSG_CHECKING([whether to include zlib compression support])
435 if test x$ac_zlib != xno; then
436  AC_MSG_RESULT(yes)
437  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
438  if test x$ac_cv_libz != xyes; then
439    AC_MSG_WARN(
440 *** 
441 *** ZLIB was not found. You will not be able to use ZLIB compression.)
442  fi
443 else
444  AC_MSG_RESULT(no)
445 fi
446
447 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
448
449 if test x$ac_zlib != xno; then
450   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
451     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
452       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
453     else
454       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
455     fi
456   fi
457 fi
458 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
459
460
461
462 AC_ARG_WITH([default-trust-store-pkcs11],
463   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
464     [use the given pkcs11 uri as default trust store])])
465
466 if test "x$with_default_trust_store_pkcs11" != x; then
467   if test "x$with_p11_kit" = xno; then
468     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
469   fi
470   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
471     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
472 fi
473
474 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
475 AC_ARG_WITH([default-trust-store-file],
476   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
477     [use the given file default trust store])], with_default_trust_store_file="$withval",
478   [if test "$build" = "$host";then
479   for i in \
480     /etc/ssl/ca-bundle.pem \
481     /etc/ssl/certs/ca-certificates.crt \
482     /etc/pki/tls/cert.pem \
483     /usr/local/share/certs/ca-root-nss.crt \
484     /etc/ssl/cert.pem
485     do
486     if test -e $i; then
487       with_default_trust_store_file="$i"
488       break
489     fi
490   done
491   fi]
492 )
493
494 if test "$with_default_trust_store_file" = "no";then
495   with_default_trust_store_file=""
496 fi
497
498 AC_ARG_WITH([default-crl-file],
499   [AS_HELP_STRING([--with-default-crl-file=FILE],
500     [use the given CRL file as default])])
501
502 if test "x$with_default_trust_store_file" != x; then
503   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
504     ["$with_default_trust_store_file"], [use the given file default trust store])
505 fi
506
507 if test "x$with_default_crl_file" != x; then
508   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
509     ["$with_default_crl_file"], [use the given CRL file])
510 fi
511
512 dnl Guile bindings.
513 opt_guile_bindings=yes
514 AC_MSG_CHECKING([whether building Guile bindings])
515 AC_ARG_ENABLE(guile,
516         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
517 opt_guile_bindings=$enableval)
518 AC_MSG_RESULT($opt_guile_bindings)
519
520 AC_ARG_WITH([guile-site-dir],
521   [AS_HELP_STRING([--with-guile-site-dir],
522      [use the given directory as the Guile site (use with care)])])
523
524 if test "$opt_guile_bindings" = "yes"; then
525    AC_MSG_RESULT([***
526 *** Detecting GNU Guile...
527 ])
528
529    AC_PATH_PROG([guile_snarf], [guile-snarf])
530    if test "x$guile_snarf" = "x"; then
531       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
532       opt_guile_bindings=no
533    else
534       GUILE_PROGS
535       GUILE_FLAGS
536
537       save_CFLAGS="$CFLAGS"
538       save_LIBS="$LIBS"
539       CFLAGS="$CFLAGS $GUILE_CFLAGS"
540       LIBS="$LIBS $GUILE_LDFLAGS"
541       AC_MSG_CHECKING([whether GNU Guile is recent enough])
542       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
543         [], [opt_guile_bindings=no])
544       CFLAGS="$save_CFLAGS"
545       LIBS="$save_LIBS"
546
547       if test "$opt_guile_bindings" = "yes"; then
548         AC_MSG_RESULT([yes])
549         case "x$with_guile_site_dir" in 
550              xno)
551                 # Use the default $(GUILE_SITE).
552                 GUILE_SITE_DIR
553                 ;;
554              x|xyes)
555                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
556                 # hack is used to allow `distcheck' to work (see
557                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
558                 GUILE_SITE="\$(datadir)/guile/site"
559                 AC_SUBST(GUILE_SITE)
560                 ;;
561              *)
562                 # Use the user-specified directory as $(GUILE_SITE).
563                 GUILE_SITE="$with_guile_site_dir"
564                 AC_SUBST(GUILE_SITE)
565                 ;;
566         esac
567         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
568         _gcc_cflags_save="$CFLAGS"
569         CFLAGS="${CFLAGS} -fgnu89-inline"
570         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
571                           gnu89_inline=yes, gnu89_inline=no)
572         AC_MSG_RESULT($gnu89_inline)
573         CFLAGS="$_gcc_cflags_save"
574
575         # Optional Guile functions.
576         save_CFLAGS="$CFLAGS"
577         save_LIBS="$LIBS"
578         CFLAGS="$CFLAGS $GUILE_CFLAGS"
579         LIBS="$LIBS $GUILE_LDFLAGS"
580         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
581         CFLAGS="$save_CFLAGS"
582         LIBS="$save_LIBS"
583
584         # The place where guile-gnutls.la will go.
585         AC_MSG_CHECKING([the Guile effective version])
586         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
587         AC_MSG_RESULT([$guile_effective_version])
588         guileextensiondir="$libdir/guile/$guile_effective_version"
589         AC_SUBST([guileextensiondir])
590       else
591         AC_MSG_RESULT([no])
592         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
593         opt_guile_bindings=no
594       fi
595    fi
596 fi
597 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
598
599 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
600 LIBGNUTLS_CFLAGS="-I${includedir}"
601 AC_SUBST(LIBGNUTLS_LIBS)
602 AC_SUBST(LIBGNUTLS_CFLAGS)
603
604 AM_CONDITIONAL(NEEDS_LIBRT, test "$gnutls_needs_librt" = "yes")
605
606 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
607 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
608
609 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
610 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
611 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
612
613 dnl Crywrap dependencies
614    AC_MSG_RESULT([***
615 *** Checking dependencies for crywrap...
616 ])
617
618 crywrap=no
619
620 if test "$have_win" != "yes"; then
621
622 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
623
624 dnl **********************
625 dnl * Typedefs & co
626 dnl **********************
627 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
628 [AC_LANG_PROGRAM([#include <sys/types.h>
629 #include <signal.h>
630 ],
631                  [return *(signal (0, 0)) (0) == 1;])],
632                    [ac_cv_type_signal=int],
633                    [ac_cv_type_signal=void])])
634 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
635                     (`int' or `void').])
636
637 AC_FUNC_SELECT_ARGTYPES
638 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
639                 putenv regcomp scandir select socket strcasecmp strchr \
640                 strdup strerror strncasecmp strrchr strstr strtoul uname])
641
642 AC_ARG_ENABLE(crywrap,
643         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
644
645  libidn=no
646
647  if test "x$enable_crywrap" != "xno" ; then
648         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
649         AC_CHECK_FUNCS([argp_usage],[ac_argp=yes],[ac_argp=no])
650  fi
651
652  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no" && test "$ac_argp" != "no";then
653   crywrap=yes
654  fi
655
656 fi
657
658 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
659
660 dnl end of crywrap requirements
661
662 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
663 AC_CONFIG_FILES([
664   Makefile
665   doc/Makefile
666   doc/credentials/Makefile
667   doc/credentials/openpgp/Makefile
668   doc/credentials/srp/Makefile
669   doc/credentials/x509/Makefile
670   doc/cyclo/Makefile
671   doc/doxygen/Doxyfile
672   doc/examples/Makefile
673   doc/latex/Makefile
674   doc/manpages/Makefile
675   doc/reference/Makefile
676   doc/reference/version.xml
677   doc/scripts/Makefile
678   extra/Makefile
679   extra/includes/Makefile
680   libdane/Makefile
681   libdane/includes/Makefile
682   libdane/gnutls-dane.pc
683   gl/Makefile
684   gl/tests/Makefile
685   guile/Makefile
686   guile/modules/Makefile
687   guile/src/Makefile
688   guile/tests/Makefile
689   lib/Makefile
690   lib/accelerated/Makefile
691   lib/accelerated/x86/Makefile
692   lib/algorithms/Makefile
693   lib/auth/Makefile
694   lib/ext/Makefile
695   lib/extras/Makefile
696   lib/gnutls.pc
697   lib/includes/Makefile
698   lib/includes/gnutls/gnutls.h
699   lib/minitasn1/Makefile
700   lib/nettle/Makefile
701   lib/opencdk/Makefile
702   lib/openpgp/Makefile
703   lib/x509/Makefile
704   po/Makefile.in
705   src/Makefile
706   src/crywrap/Makefile
707   src/gl/Makefile
708   tests/Makefile
709   tests/cert-tests/Makefile
710   tests/dsa/Makefile
711   tests/dtls/Makefile
712   tests/srp/Makefile
713   tests/ecdsa/Makefile
714   tests/key-id/Makefile
715   tests/openpgp-certs/Makefile
716   tests/pkcs1-padding/Makefile
717   tests/pkcs12-decode/Makefile
718   tests/pkcs8-decode/Makefile
719   tests/rsa-md5-collision/Makefile
720   tests/safe-renegotiation/Makefile
721   tests/scripts/Makefile
722   tests/sha2/Makefile
723   tests/slow/Makefile
724   tests/suite/Makefile
725   tests/userid/Makefile
726 ])
727
728 AC_OUTPUT
729
730 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
731 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
732 AC_MSG_NOTICE([summary of build options:
733
734   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
735   Host/Target system:   ${host}
736   Build system:         ${build}
737   Install prefix:       ${prefix}
738   Compiler:             ${CC}
739   CFlags:               ${CFLAGS}
740   Library types:        Shared=${enable_shared}, Static=${enable_static}
741 ])
742
743 AC_MSG_NOTICE([External hardware support:
744
745   /dev/crypto:          $enable_cryptodev
746   Hardware accel:       $hw_accel
747   PKCS#11 support:      $with_p11_kit
748   TPM support:          $with_tpm
749 ])
750
751 AC_MSG_NOTICE([Optional features:
752 (note that included applications might not compile properly
753 if features are disabled)
754
755   DTLS-SRTP support:    $ac_enable_srtp
756   ALPN support:         $ac_enable_alpn
757   OCSP support:         $ac_enable_ocsp
758   OpenPGP support:      $ac_enable_openpgp
759   SRP support:          $ac_enable_srp
760   PSK support:          $ac_enable_psk
761   DHE support:          $ac_enable_dhe
762   ECDHE support:        $ac_enable_ecdhe
763   Anon auth support:    $ac_enable_anon
764   Heartbeat support:    $ac_enable_heartbeat
765   RSA-EXPORT compat:    $ac_enable_rsa_export
766   Unicode support:      $ac_have_unicode
767   Self checks:          $enable_self_checks
768   Non-SuiteB curves:    $enable_non_suiteb
769   FIPS140 mode:         $enable_fips
770 ])
771
772 AC_MSG_NOTICE([Optional applications:
773
774   crywrap app:          $libidn
775   local libopts:        ${enable_local_libopts}
776   local libtasn1:       ${included_libtasn1}
777 ])
778
779 AC_MSG_NOTICE([Optional libraries:
780
781   Guile wrappers:       $opt_guile_bindings
782   C++ library:          $use_cxx
783   DANE library:         $enable_dane
784   OpenSSL compat:       $enable_openssl
785 ])
786
787 AC_MSG_NOTICE([System files:
788
789   Trust store pkcs:     $with_default_trust_store_pkcs11
790   Trust store file:     $with_default_trust_store_file
791   CRL file:             $with_default_crl_file
792   DNSSEC root key file: $unbound_root_key_file
793 ])
794
795 if test ! -f "$unbound_root_key_file"; then
796 AC_MSG_WARN([[
797 *** 
798 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
799 *** This file is needed for the verification of DNSSEC responses.
800 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
801 *** to generate or update it.
802 *** ]])
803 fi