corrected guile-site-dir option. Patch by Steve Erhart.
[gnutls:gnutls.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
3 #
4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
5 #
6 # This file is part of GnuTLS.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
21 # USA
22
23 AC_PREREQ(2.61)
24 AC_INIT([GnuTLS], [3.2.2], [bug-gnutls@gnu.org])
25 AC_CONFIG_AUX_DIR([build-aux])
26 AC_CONFIG_MACRO_DIR([m4])
27 AC_CANONICAL_HOST
28
29 AM_INIT_AUTOMAKE([1.12.2 no-dist-gzip dist-xz dist-lzip -Wall -Wno-override])
30 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
31 AC_CONFIG_HEADERS([config.h])
32
33 AC_MSG_RESULT([***
34 *** Checking for compilation programs...
35 ])
36
37 dnl Checks for programs.
38 AC_PROG_CC
39 gl_EARLY
40 AM_PROG_AS
41 AM_PROG_AR
42 AC_PROG_CXX
43
44 # For includes/gnutls/gnutls.h.in.
45 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
46 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
47 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
48 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
49
50 touch suppressions.valgrind
51 dnl C and C++ capabilities
52 AC_C_INLINE
53 AC_HEADER_STDC
54
55 # For the C++ code
56 AC_ARG_ENABLE(cxx,
57   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
58     use_cxx=$enableval, use_cxx=yes)
59 if test "$use_cxx" != "no"; then
60   AC_LANG_PUSH(C++)
61   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
62   AC_LANG_POP(C++)
63 fi
64 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
65 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
66
67 dnl Detect windows build
68 case "$host" in
69   *mingw32* | *mingw64*)
70     have_win=yes
71   ;;
72   *darwin*)
73     have_macosx=yes
74   ;;
75   *)
76     have_elf=yes
77   ;;
78 esac
79
80 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
81 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
82 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
83
84 dnl Hardware Acceleration
85 AC_ARG_ENABLE(hardware-acceleration,
86   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
87     use_accel=$enableval, use_accel=yes)
88 hw_accel=none
89
90
91 if test "$use_accel" != "no"; then
92 case $host_cpu in
93   i?86 | x86_64 | amd64)
94       AC_CHECK_HEADERS(cpuid.h)
95       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
96         hw_accel="x86-64"
97       else
98         hw_accel="x86"
99       fi
100   ;;
101   *)
102   ;;
103 esac
104
105 fi
106
107 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
108 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
109 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
110 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
111 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
112
113 dnl Try the hooks.m4
114 LIBGNUTLS_HOOKS
115 LIBGNUTLS_EXTRA_HOOKS
116
117 AC_ARG_ENABLE(doc,
118   AS_HELP_STRING([--disable-doc], [don't generate any documentation]),
119     enable_doc=$enableval, enable_doc=yes)
120 AM_CONDITIONAL(ENABLE_DOC, test "$enable_doc" != "no")
121
122 AC_ARG_ENABLE(tests,
123   AS_HELP_STRING([--disable-tests], [don't compile or run any tests]),
124     enable_tests=$enableval, enable_tests=yes)
125 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" != "no")
126
127 GTK_DOC_CHECK(1.1)
128 AM_GNU_GETTEXT([external])
129 AM_GNU_GETTEXT_VERSION([0.18])
130
131 AC_C_BIGENDIAN
132
133 gl_INIT
134
135 dnl GCC warnings to enable
136
137 AC_ARG_ENABLE([gcc-warnings],
138   [AS_HELP_STRING([--enable-gcc-warnings],
139                   [turn on lots of GCC warnings (for developers)])],
140   [case $enableval in
141      yes|no) ;;
142      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
143    esac
144    gl_gcc_warnings=$enableval],
145   [gl_gcc_warnings=no]
146 )
147
148 if test "$gl_gcc_warnings" = yes; then
149   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
150
151   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
152   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
153   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
154   nw="$nw -Wtraditional"            # Warns on #elif which we use often
155   nw="$nw -Wlogical-op"             # Too many false positives
156   nw="$nw -Wold-style-definition"   # 
157   nw="$nw -Wpadded"                 # Our structs are not padded
158   nw="$nw -Wunreachable-code"       # Too many false positives
159   nw="$nw -Wtraditional-conversion" # Too many warnings for now
160   nw="$nw -Wcast-qual"              # Too many warnings for now
161   nw="$nw -Waggregate-return"       # Too many warnings for now
162   nw="$nw -Wshadow"                 # Too many warnings for now
163   nw="$nw -Wswitch-default"         # Too many warnings for now
164   nw="$nw -Wswitch-enum"            # Too many warnings for now
165   nw="$nw -Wconversion"             # Too many warnings for now
166   nw="$nw -Wsign-conversion"        # Too many warnings for now
167   nw="$nw -Wformat-y2k"             # Too many warnings for now
168   nw="$nw -Woverlength-strings"     # We use some in tests/
169   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
170   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
171   nw="$nw -Wunsafe-loop-optimizations"
172   nw="$nw -Wstrict-overflow"
173   nw="$nw -Wmissing-noreturn"
174   nw="$nw -Winline"                 # Too compiler dependent
175   nw="$nw -Wsuggest-attribute=pure" # Is it worth using attributes?
176   nw="$nw -Wsuggest-attribute=const" # Is it worth using attributes?
177   nw="$nw -Wsuggest-attribute=noreturn" # Is it worth using attributes?
178   nw="$nw -Wstack-protector"        # Some functions cannot be protected
179   nw="$nw -Wredundant-decls"        # Some files cannot be compiled with that (gl_fd_to_handle)
180
181   gl_MANYWARN_ALL_GCC([ws])
182   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
183   for w in $ws; do
184     gl_WARN_ADD([$w])
185   done
186
187   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
188   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
189   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
190   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
191   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
192   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
193   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
194   gl_WARN_ADD([-fdiagnostics-show-option])
195 fi
196
197 AC_SUBST([WERROR_CFLAGS])
198 AC_SUBST([WSTACK_CFLAGS])
199 AC_SUBST([WARN_CFLAGS])
200
201 dnl Programs for compilation or development
202 AC_PROG_LN_S
203 AC_LIBTOOL_WIN32_DLL
204 AC_PROG_LIBTOOL
205
206
207 dnl No fork on MinGW, disable some self-tests until we fix them.
208 dnl Check clock_gettime and pthread_mutex_lock in libc (avoid linking to other libs)
209 AC_CHECK_FUNCS([fork getrusage getpwuid_r nanosleep daemon getpid clock_gettime pthread_mutex_lock],,)
210 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
211
212 if test "$ac_cv_func_pthread_mutex_lock" != "yes";then
213   AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
214 fi
215
216 if test "$ac_cv_func_nanosleep" != "yes";then
217   AC_LIB_HAVE_LINKFLAGS(rt,, [#include <time.h>], [nanosleep (0, 0);])
218 fi
219
220 AC_MSG_CHECKING([whether to build libdane])
221 AC_ARG_ENABLE(libdane,
222     AS_HELP_STRING([--disable-libdane],
223                    [disable the built of libdane]),
224     enable_dane=$enableval, enable_dane=yes)
225 AC_MSG_RESULT($enable_dane)
226
227 if test "$enable_dane" != "no"; then
228     LIBS="$oldlibs -lunbound"
229     AC_MSG_CHECKING([for unbound library])
230     AC_LINK_IFELSE([AC_LANG_PROGRAM([
231                    #include <unbound.h>],[
232                    struct ub_ctx* ctx;
233                    ctx = ub_ctx_create();])],
234                   [AC_MSG_RESULT(yes)
235                    AC_SUBST([UNBOUND_LIBS], [-lunbound])
236                    AC_SUBST([UNBOUND_CFLAGS], [])
237                    AC_DEFINE([HAVE_DANE], 1, [Enable the DANE library])
238                    enable_dane=yes],
239                   [AC_MSG_RESULT(no)
240                    AC_MSG_WARN([[
241 *** 
242 *** libunbound was not found. Libdane will not be built.
243 *** ]])
244                   enable_dane=no])
245     LIBS="$oldlibs"
246 fi
247
248 AM_CONDITIONAL(ENABLE_DANE, test "$enable_dane" = "yes")
249
250 AC_ARG_WITH(unbound-root-key-file, AS_HELP_STRING([--with-unbound-root-key-file],
251                                  [specify the unbound root key file]),
252             unbound_root_key_file="$withval", 
253 if test "$have_win" = yes; then
254     unbound_root_key_file="C:\\Program Files\\Unbound\\root.key"
255 else
256     unbound_root_key_file="/etc/unbound/root.key"
257 fi
258 )
259
260 AC_DEFINE_UNQUOTED([UNBOUND_ROOT_KEY_FILE],
261   ["$unbound_root_key_file"], [The DNSSEC root key file])
262
263 dnl Check for p11-kit
264 AC_ARG_WITH(p11-kit,
265         AS_HELP_STRING([--without-p11-kit],
266                 [Build without p11-kit and PKCS#11 support]))
267 if test "$with_p11_kit" != "no"; then
268         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.11], [with_p11_kit=yes], [with_p11_kit=no])
269         if test "$with_p11_kit" != "no";then
270                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
271                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
272                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
273                 else
274                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
275                 fi
276         else
277                 with_p11_kit=no
278                 AC_MSG_WARN([[
279 *** 
280 *** p11-kit was not found. PKCS #11 support will be disabled.
281 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
282 *** ]])
283         fi
284 fi
285
286 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
287
288 AC_ARG_WITH(tpm,
289         AS_HELP_STRING([--with-tpm],
290                 [Build with TPM (trousers) support. Note that trousers is under the Common Public License and incompatible with GPL programs.]),
291                 [with_tpm=$withval], [with_tpm=no])
292 if test "$with_tpm" != "no"; then
293     LIBS="$oldlibs -ltspi"
294     AC_MSG_CHECKING([for tss library])
295     AC_LINK_IFELSE([AC_LANG_PROGRAM([
296                    #include <trousers/tss.h>
297                    #include <trousers/trousers.h>],[
298                    int err = Tspi_Context_Create((void *)0);
299                    Trspi_Error_String(err);])],
300                   [AC_MSG_RESULT(yes)
301                    AC_SUBST([TSS_LIBS], [-ltspi])
302                    AC_SUBST([TSS_CFLAGS], [])
303                    AC_DEFINE([HAVE_TROUSERS], 1, [Enable TPM])
304                    with_tpm=yes],
305                   [AC_MSG_RESULT(no)
306                    AC_MSG_WARN([[
307 *** 
308 *** trousers was not found. TPM support will be disabled.
309 *** ]])
310                   with_tpm=no])
311     LIBS="$oldlibs"
312 fi
313
314 AM_CONDITIONAL(ENABLE_TROUSERS, test "$with_tpm" != "no")
315
316 enable_local_libopts=yes
317 dnl PKG_CHECK_MODULES([autoopts], autoopts >= 36.2.11,, [enable_local_libopts=yes])
318
319 NEED_LIBOPTS_DIR=true
320 LIBOPTS_CHECK([src/libopts])
321
322 AC_CHECK_TYPE(ssize_t,
323   [
324     DEFINE_SSIZE_T="#include <sys/types.h>"
325     AC_SUBST(DEFINE_SSIZE_T)
326   ], [
327     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
328     DEFINE_SSIZE_T="typedef int ssize_t;"
329     AC_SUBST(DEFINE_SSIZE_T)
330   ], [
331     #include <sys/types.h>
332   ])
333
334 # For minitasn1.
335 AC_CHECK_SIZEOF(unsigned long int, 4)
336 AC_CHECK_SIZEOF(unsigned int, 4)
337
338 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
339                                  [disable zlib compression support]),
340             ac_zlib=$withval, ac_zlib=yes)
341 AC_MSG_CHECKING([whether to include zlib compression support])
342 if test x$ac_zlib != xno; then
343  AC_MSG_RESULT(yes)
344  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
345  if test x$ac_cv_libz != xyes; then
346    AC_MSG_WARN(
347 *** 
348 *** ZLIB was not found. You will not be able to use ZLIB compression.)
349  fi
350 else
351  AC_MSG_RESULT(no)
352 fi
353
354 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
355
356 if test x$ac_zlib != xno; then
357   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
358     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
359       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
360     else
361       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
362     fi
363   fi
364 fi
365 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
366
367
368
369 AC_ARG_WITH([default-trust-store-pkcs11],
370   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
371     [use the given pkcs11 uri as default trust store])])
372
373 if test "x$with_default_trust_store_pkcs11" != x; then
374   if test "x$with_p11_kit" = xno; then
375     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
376   fi
377   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
378     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
379 fi
380
381 dnl auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
382 AC_ARG_WITH([default-trust-store-file],
383   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
384     [use the given file default trust store])], with_default_trust_store_file="$withval",
385   [if test "$build" = "$host";then
386   for i in \
387     /etc/ssl/ca-bundle.pem \
388     /etc/ssl/certs/ca-certificates.crt \
389     /etc/pki/tls/cert.pem \
390     /usr/local/share/certs/ca-root-nss.crt \
391     /etc/ssl/cert.pem
392     do
393     if test -e $i; then
394       with_default_trust_store_file="$i"
395       break
396     fi
397   done
398   fi]
399 )
400
401 if test "$with_default_trust_store_file" = "no";then
402   with_default_trust_store_file=""
403 fi
404
405 AC_ARG_WITH([default-crl-file],
406   [AS_HELP_STRING([--with-default-crl-file=FILE],
407     [use the given CRL file as default])])
408
409 if test "x$with_default_trust_store_file" != x; then
410   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
411     ["$with_default_trust_store_file"], [use the given file default trust store])
412 fi
413
414 if test "x$with_default_crl_file" != x; then
415   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
416     ["$with_default_crl_file"], [use the given CRL file])
417 fi
418
419 dnl Guile bindings.
420 opt_guile_bindings=yes
421 AC_MSG_CHECKING([whether building Guile bindings])
422 AC_ARG_ENABLE(guile,
423         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
424 opt_guile_bindings=$enableval)
425 AC_MSG_RESULT($opt_guile_bindings)
426
427 AC_ARG_WITH([guile-site-dir],
428   [AS_HELP_STRING([--with-guile-site-dir],
429      [use the given directory as the Guile site (use with care)])])
430
431 if test "$opt_guile_bindings" = "yes"; then
432    AC_MSG_RESULT([***
433 *** Detecting GNU Guile...
434 ])
435
436    AC_PATH_PROG([guile_snarf], [guile-snarf])
437    if test "x$guile_snarf" = "x"; then
438       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
439       opt_guile_bindings=no
440    else
441       GUILE_PROGS
442       GUILE_FLAGS
443
444       save_CFLAGS="$CFLAGS"
445       save_LIBS="$LIBS"
446       CFLAGS="$CFLAGS $GUILE_CFLAGS"
447       LIBS="$LIBS $GUILE_LDFLAGS"
448       AC_MSG_CHECKING([whether GNU Guile is recent enough])
449       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [scm_from_locale_string ("")])],
450         [], [opt_guile_bindings=no])
451       CFLAGS="$save_CFLAGS"
452       LIBS="$save_LIBS"
453
454       if test "$opt_guile_bindings" = "yes"; then
455         AC_MSG_RESULT([yes])
456         case "x$with_guile_site_dir" in 
457              xno)
458                 # Use the default $(GUILE_SITE).
459                 GUILE_SITE_DIR
460                 ;;
461              x|xyes)
462                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
463                 # hack is used to allow `distcheck' to work (see
464                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
465                 GUILE_SITE="\$(datadir)/guile/site"
466                 AC_SUBST(GUILE_SITE)
467                 ;;
468              *)
469                 # Use the user-specified directory as $(GUILE_SITE).
470                 GUILE_SITE="$with_guile_site_dir"
471                 AC_SUBST(GUILE_SITE)
472                 ;;
473         esac
474         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
475         _gcc_cflags_save="$CFLAGS"
476         CFLAGS="${CFLAGS} -fgnu89-inline"
477         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
478                           gnu89_inline=yes, gnu89_inline=no)
479         AC_MSG_RESULT($gnu89_inline)
480         CFLAGS="$_gcc_cflags_save"
481
482         # Optional Guile functions.
483         save_CFLAGS="$CFLAGS"
484         save_LIBS="$LIBS"
485         CFLAGS="$CFLAGS $GUILE_CFLAGS"
486         LIBS="$LIBS $GUILE_LDFLAGS"
487         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
488         CFLAGS="$save_CFLAGS"
489         LIBS="$save_LIBS"
490
491         # The place where guile-gnutls.la will go.
492         AC_MSG_CHECKING([the Guile effective version])
493         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
494         AC_MSG_RESULT([$guile_effective_version])
495         guileextensiondir="$libdir/guile/$guile_effective_version"
496         AC_SUBST([guileextensiondir])
497       else
498         AC_MSG_RESULT([no])
499         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
500         opt_guile_bindings=no
501       fi
502    fi
503 fi
504 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
505
506 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
507 LIBGNUTLS_CFLAGS="-I${includedir}"
508 AC_SUBST(LIBGNUTLS_LIBS)
509 AC_SUBST(LIBGNUTLS_CFLAGS)
510
511
512 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
513 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
514
515 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
516 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
517 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
518
519 dnl Crywrap dependencies
520    AC_MSG_RESULT([***
521 *** Checking dependencies for crywrap...
522 ])
523
524 crywrap=no
525
526 if test "$have_win" != "yes"; then
527
528 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
529
530 dnl **********************
531 dnl * Typedefs & co
532 dnl **********************
533 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
534 [AC_LANG_PROGRAM([#include <sys/types.h>
535 #include <signal.h>
536 ],
537                  [return *(signal (0, 0)) (0) == 1;])],
538                    [ac_cv_type_signal=int],
539                    [ac_cv_type_signal=void])])
540 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
541                     (`int' or `void').])
542
543 AC_FUNC_SELECT_ARGTYPES
544 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
545                 putenv regcomp scandir select socket strcasecmp strchr \
546                 strdup strerror strncasecmp strrchr strstr strtoul uname])
547
548 AC_ARG_ENABLE(crywrap,
549         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
550
551  libidn=no
552
553  if test "x$enable_crywrap" != "xno" ; then
554         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
555  fi
556
557  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no";then
558   crywrap=yes
559  fi
560
561 fi
562
563 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
564 rm -f suppressions.valgrind
565 dnl end of crywrap requirements
566
567 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
568 AC_CONFIG_FILES([
569   Makefile
570   doc/Makefile
571   doc/credentials/Makefile
572   doc/credentials/openpgp/Makefile
573   doc/credentials/srp/Makefile
574   doc/credentials/x509/Makefile
575   doc/cyclo/Makefile
576   doc/doxygen/Doxyfile
577   doc/examples/Makefile
578   doc/latex/Makefile
579   doc/manpages/Makefile
580   doc/reference/Makefile
581   doc/reference/version.xml
582   doc/scripts/Makefile
583   extra/Makefile
584   extra/includes/Makefile
585   libdane/Makefile
586   libdane/includes/Makefile
587   libdane/gnutls-dane.pc
588   gl/Makefile
589   gl/tests/Makefile
590   guile/Makefile
591   guile/modules/Makefile
592   guile/src/Makefile
593   guile/tests/Makefile
594   lib/Makefile
595   lib/accelerated/Makefile
596   lib/accelerated/x86/Makefile
597   lib/algorithms/Makefile
598   lib/auth/Makefile
599   lib/ext/Makefile
600   lib/extras/Makefile
601   lib/gnutls.pc
602   lib/includes/Makefile
603   lib/includes/gnutls/gnutls.h
604   lib/minitasn1/Makefile
605   lib/nettle/Makefile
606   lib/opencdk/Makefile
607   lib/openpgp/Makefile
608   lib/x509/Makefile
609   po/Makefile.in
610   src/Makefile
611   src/crywrap/Makefile
612   tests/Makefile
613   tests/cert-tests/Makefile
614   tests/dsa/Makefile
615   tests/dtls/Makefile
616   tests/srp/Makefile
617   tests/ecdsa/Makefile
618   tests/key-id/Makefile
619   tests/openpgp-certs/Makefile
620   tests/pkcs1-padding/Makefile
621   tests/pkcs12-decode/Makefile
622   tests/pkcs8-decode/Makefile
623   tests/rsa-md5-collision/Makefile
624   tests/safe-renegotiation/Makefile
625   tests/scripts/Makefile
626   tests/sha2/Makefile
627   tests/slow/Makefile
628   tests/suite/Makefile
629   tests/userid/Makefile
630 ])
631
632 AC_OUTPUT
633
634 dnl  Warning flags:        errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
635 dnl  Valgrind:             $opt_valgrind_tests ${VALGRIND}
636 AC_MSG_NOTICE([summary of build options:
637
638   version:              ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
639   Host/Target system:   ${host}
640   Build system:         ${build}
641   Install prefix:       ${prefix}
642   Compiler:             ${CC}
643   CFlags:               ${CFLAGS}
644   Library types:        Shared=${enable_shared}, Static=${enable_static}
645 ])
646
647 AC_MSG_NOTICE([External hardware support:
648
649   /dev/crypto:          $enable_cryptodev
650   Hardware accel:       $hw_accel
651   PKCS#11 support:      $with_p11_kit
652   TPM support:          $with_tpm
653 ])
654
655 AC_MSG_NOTICE([Optional features:
656 (note that included applications might not compile properly
657 if features are disabled)
658
659   DTLS-SRTP support:    $ac_enable_srtp
660   ALPN support:         $ac_enable_alpn
661   OCSP support:         $ac_enable_ocsp
662   OpenPGP support:      $ac_enable_openpgp
663   SRP support:          $ac_enable_srp
664   PSK support:          $ac_enable_psk
665   DHE support:          $ac_enable_dhe
666   ECDHE support:        $ac_enable_ecdhe
667   Anon auth support:    $ac_enable_anon
668   Heartbeat support:    $ac_enable_heartbeat
669   RSA-EXPORT compat:    $ac_enable_rsa_export
670 ])
671
672 AC_MSG_NOTICE([Optional applications:
673
674   crywrap app:          $libidn
675   local libopts:        $enable_local_libopts
676 ])
677
678 AC_MSG_NOTICE([Optional libraries:
679
680   Guile wrappers:       $opt_guile_bindings
681   C++ library:          $use_cxx
682   DANE library:         $enable_dane
683   OpenSSL compat:       $enable_openssl
684 ])
685
686 AC_MSG_NOTICE([System files:
687
688   Trust store pkcs:     $with_default_trust_store_pkcs11
689   Trust store file:     $with_default_trust_store_file
690   CRL file:             $with_default_crl_file
691   DNSSEC root key file: $unbound_root_key_file
692 ])
693
694 if test ! -f "$unbound_root_key_file"; then
695 AC_MSG_WARN([[
696 *** 
697 *** The DNSSEC root key file in $unbound_root_key_file was not found. 
698 *** This file is needed for the verification of DNSSEC responses.
699 *** Use the command: unbound-anchor -a "$unbound_root_key_file"
700 *** to generate or update it.
701 *** ]])
702 fi