Added a gnulib with GPL components for use by applications.
[gnutls:gnutls.git] / src / gl / m4 / stddef_h.m4
1 dnl A placeholder for POSIX 2008 <stddef.h>, for platforms that have issues.
2 # stddef_h.m4 serial 4
3 dnl Copyright (C) 2009-2013 Free Software Foundation, Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7
8 AC_DEFUN([gl_STDDEF_H],
9 [
10   AC_REQUIRE([gl_STDDEF_H_DEFAULTS])
11   AC_REQUIRE([gt_TYPE_WCHAR_T])
12   STDDEF_H=
13   if test $gt_cv_c_wchar_t = no; then
14     HAVE_WCHAR_T=0
15     STDDEF_H=stddef.h
16   fi
17   AC_CACHE_CHECK([whether NULL can be used in arbitrary expressions],
18     [gl_cv_decl_null_works],
19     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
20       int test[2 * (sizeof NULL == sizeof (void *)) -1];
21 ]])],
22       [gl_cv_decl_null_works=yes],
23       [gl_cv_decl_null_works=no])])
24   if test $gl_cv_decl_null_works = no; then
25     REPLACE_NULL=1
26     STDDEF_H=stddef.h
27   fi
28   AC_SUBST([STDDEF_H])
29   AM_CONDITIONAL([GL_GENERATE_STDDEF_H], [test -n "$STDDEF_H"])
30   if test -n "$STDDEF_H"; then
31     gl_NEXT_HEADERS([stddef.h])
32   fi
33 ])
34
35 AC_DEFUN([gl_STDDEF_MODULE_INDICATOR],
36 [
37   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
38   AC_REQUIRE([gl_STDDEF_H_DEFAULTS])
39   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
40 ])
41
42 AC_DEFUN([gl_STDDEF_H_DEFAULTS],
43 [
44   dnl Assume proper GNU behavior unless another module says otherwise.
45   REPLACE_NULL=0;                AC_SUBST([REPLACE_NULL])
46   HAVE_WCHAR_T=1;                AC_SUBST([HAVE_WCHAR_T])
47 ])