Fixes: NB#275842 - Legal bug - license header change in libqtcontacts-telepathy.
[qtcontacts-tracker:qtcontacts-telepathy.git] / libqtcontacts-telepathy.pro
1 CONFIG += ordered
2 TEMPLATE = subdirs
3
4 SUBDIRS = src tools
5
6 OTHER_FILES = configure debian/changelog Doxyfile FUTURE HACKING EXPECTFAIL
7
8 # =================================================================================================
9 # Pretend to build API documentation
10 # =================================================================================================
11
12 apidocs.target = docs/html/index.html
13 apidocs.commands = doxygen $$PWD/Doxyfile
14 apidocs.depends = Doxyfile src/*/*.cpp src/*/*.h
15 docs.depends = apidocs
16
17 QMAKE_EXTRA_TARGETS += apidocs docs
18
19 # =================================================================================================
20 # Generate HTML reports from a previous gcov run
21 # =================================================================================================
22
23 coverage-html.commands = $$PWD/tests/gcov-summary.sh lcov docs/coverage
24
25 QMAKE_EXTRA_TARGETS += coverage-html
26 QMAKE_CLEAN += gcov.analysis gcov.analysis.summary
27
28 # =================================================================================================
29 # Remove output of configure script on "make distclean"
30 # =================================================================================================
31
32 confclean.commands = $(DEL_FILE) $$TOP_BUILDDIR/.qmake.cache
33 distclean.depends = confclean
34
35 QMAKE_EXTRA_TARGETS += confclean distclean
36
37 # =================================================================================================
38 # Run configure script when building the project from tools like QtCreator
39 # =================================================================================================
40
41 isEmpty(CONFIGURED):system('$$PWD/configure')
42
43 confstamp.target = configure-stamp .qmake.cache
44 confstamp.commands = $$PWD/configure $$CONFIGURE_FLAGS
45 confstamp.depends = $$PWD/configure
46
47 QMAKE_EXTRA_TARGETS += confstamp